Trennung von Text via Formel?

Bild

Betrifft: Trennung von Text via Formel?
von: Joerschi
Geschrieben am: 05.10.2015 15:34:13

Hallo liebes Forum,
es sollen per Formel Daten getrennt werden, welche bislang stets mit einen Unterstrich "_" in einer Zelle miteinander verbunden sind.
Skizze (Beispiellösung für die ersten drei Namen in kursiv):
Userbild
Musterdatei: https://www.herber.de/bbs/user/100597.xlsx
Hätte jemand einen Tip für eine Formellösung von C3:C5?
Danke im Voraus und Liebe Grüße
joerschi

Bild

Betrifft: Text mit _ trennen
von: WF
Geschrieben am: 05.10.2015 15:51:38
Hi,
=LINKS(A1;FINDEN("_";A1)-1)
=TEIL(A1;FINDEN("_";A1)+1;FINDEN("_";A1;FINDEN("_";A1)+1)-FINDEN("_";A1)-1)
=TEIL(A1;VERWEIS(9^9;FINDEN("_";A1;ZEILE(1:999)))+1;9^9)
siehe auch unsere:
http://excelformeln.de/formeln.html?welcher=301
für komplizierteres
WF

Bild

Betrifft: AW: Text mit _ trennen
von: Joerschi
Geschrieben am: 05.10.2015 15:57:49
Dank Dir, WF.
Funktioniert, aber werde ich mich mal einlesen.
Liebe Grüße
joerschi

Bild

Betrifft: wenn es immer so einfach aufgebaut ist
von: WF
Geschrieben am: 05.10.2015 16:05:49
also:
ein Buchstabe_unbekannte Zahlenzahl_ein Buchstabe
langt:
=LINKS(A1)
=LINKS(TEIL(A1;3;99);FINDEN("_";TEIL(A1;3;99))-1)
=RECHTS(A1)
WF

Bild

Betrifft: AW: mit TEILergebnis Index/Vergleich nicht mgl?
von: Joerschi
Geschrieben am: 05.10.2015 16:28:54
Hi WF,
ich weiß nicht, ob man für die Nachfrage einen Extra-thema eröffnen sollte, aber ich packe es gleich hier mit rein.
Skizze unten...
Und zwar soll auf die Trennung 2 (ist eine Zahl) als Vergleichszeile C4:L4 von der Indexzeile C7:L7 der dortige Wert ausgelesen werden. Also ein simpler Index/Vergleich.
Im nachstehenden Beispiel müsste in C10 eigentlich ein "N" aus C7 ausgegeben werden, stattdessen #NV.
Userbild
https://www.herber.de/bbs/user/100601.xlsx
Hast Du eine Idee, warum die Zahlen der vierten Zeile (aus TEIL) nicht im Index/Vergleich erkannt werden?
(für einfachste Berechnungen wie Multiplikationen funktieren die Ergebnisse der Zeile 4 wiederum...)
Danke vorab und liebe Grüße
Joerschi

Bild

Betrifft: Zahl sucht Zahl, findet aber Text
von: WF
Geschrieben am: 05.10.2015 16:39:26
das Ergebnis der Teil-Formel ist Text - also musst Du mit 1 multiplizieren
=TEIL(A1;FINDEN("_";A1)+1;FINDEN("_";A1;FINDEN("_";A1)+1)-FINDEN("_";A1)-1)*1
WF

Bild

Betrifft: AW: Zahl sucht Zahl, findet aber Text
von: Joerschi
Geschrieben am: 05.10.2015 16:46:36
Danke Dir.
An was man alles denken muss :-))
Liebe Grüße, Joerschi

Bild

Betrifft: AW: mit TEILergebnis Index/Vergleich nicht mgl?
von: Michael
Geschrieben am: 05.10.2015 16:45:40
Hi zusammen,
es handelt sich trotz allem nicht um Zahlen, sondern um Texthäppchen, während Deine Eingabe eine Zahl ist.
Gib mal nur =VERGLEICH(C9;C4:L4;0) ein, bereits da kommt die Fehlermeldung.
Ich habe C9 als "Text" formatiert, aber das hat noch nicht funktioniert, dann habe ich *einmal* 1128 mit führendem Hochkomma "'" eingegeben (das ist für Excel ein Indiz für Text), dann ging es - und komischerweise dann auch bei anderen Zahlen *ohne* das Hochkomma.
Schöne Grüße,
Michael

Bild

Betrifft: AW: mit TEILergebnis Index/Vergleich nicht mgl?
von: Daniel
Geschrieben am: 05.10.2015 16:52:22
HI
die Vergleichsfunktion sucht nach einer genauen Übereinstimmung.
diese ist aber nicht gegeben, weil dein gesuchter Text 1128 im suchbereich nicht direkt vorkommt, weil hier ja immer noch ein "M_" davor und ein "_0" dahinter steht.
wenns immer "M_" und "_0" sind, könntest du diese einfach dem Suchbegriff anfügen:
Vergleich("M_"&C9&"_0";C4:L4;0)
wenn diese führenden und folgenden Zeichenketten variabel sind, kannst du auch mit den Jokerzeichen * (beliebige Zeichen, auch keines) und ? (genau ein Zeichen) arbeiten:
Vergleich("*"&C9&"*";C4:L4;0)
Gruß Daniel

Bild

Betrifft: AW: mit TEILergebnis Index/Vergleich nicht mgl?
von: Daniel
Geschrieben am: 05.10.2015 16:55:33
Ok, hab übersehen das du in Zeile 4 suchst.
aber mit meiner Methode kannst du direkt in Zeile 2 suchen und damit wird dann vielleicht das Aufteilen der Ausgangsdaten unnötig.
Gruss Daniel

Bild

Betrifft: Nach dem, was du zuletzt geschrieben hast, ...
von: Luc:-?
Geschrieben am: 05.10.2015 18:16:06
…Joerschi,
scheint die ganze Trennerei unnötig zu sein. Hier reicht ein simpler WVERWEIS, wenn du den Wert, oder ein VERGLEICH, falls du die Position in den Ausgangsdaten finden willst:
=WVERWEIS("*_"&C9&"_*";C2:L2;1;0)
=VERGLEICH("*_"&C9&"_*";C2:L2;0)
Voraussetzung ist dabei natürlich, dass die Zahlen im Mittelteil eindeutig sind, d.h. sich nicht wiederholen.
Falls trotzdem getrennt wdn soll, würdest du mit folgender MatrixFml auch gleich echte Zahlen erhalten:
C3:C5[;D3:L5]: {=MTRANS(VSplit(C2:C2;"_";1))}
Gruß, Luc :-?

Besser informiert mit …

Bild

Betrifft: AW: Nach dem, was du zuletzt geschrieben hast, ...
von: Joerschi
Geschrieben am: 05.10.2015 21:33:36
Dank Dir für die Ergäzung, Luc :-)
Mit Deiner Variante kann ich die Lösung noch flexibler machen.
Beste Grüße, Joerschi

Bild

Betrifft: Bitte sehr, gern geschehen! ;-) owT
von: Luc:-?
Geschrieben am: 05.10.2015 21:43:18
:-?

 Bild

Beiträge aus den Excel-Beispielen zum Thema "Trennung von Text via Formel?"