Live-Forum - Die aktuellen Beiträge
Anzeige
Archiv - Navigation
1560to1564
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Inhaltsverzeichnis

DataLabels löschen

DataLabels löschen
06.06.2017 11:56:52
Daniel
Hallo zusammen,
gibt es die Möglichkeit für alle Charts in einem Workbook
alle leeren DataLabels mittels Makro zu löschen?
Gruß Daniel

4
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: DataLabels löschen
06.06.2017 14:01:07
fcs
Hallo Daniel,
hier ein entsprechendes Makro
Gruß
Franz
Sub prcDiagramm_Datalabels_delete()
Dim wkb As Workbook
Dim wks As Worksheet
Dim objChart As Chart
Dim ChartObject As ChartObject
Set wkb = ActiveWorkbook
'in Diagrammblättern
For Each objChart In wkb.Charts
Call prcDataPoint_Datalabel_delte(objChart)
Next
'in eingebetteten Diagrammen
For Each wks In wkb.Worksheets
For Each ChartObject In wks.ChartObjects
Call prcDataPoint_Datalabel_delte(ChartObject.Chart)
Next
Next
End Sub
Sub prcDataPoint_Datalabel_delte(objChart As Chart)
Dim objSeries As Series
Dim objPoint As Point
For Each objSeries In objChart.SeriesCollection
If objSeries.HasDataLabels Then
objSeries.DataLabels.Delete
End If
For Each objPoint In objSeries.Points
If objPoint.HasDataLabel Then objPoint.DataLabel.Delete
Next
Next
End Sub

Anzeige
AW: DataLabels löschen
06.06.2017 14:09:36
Daniel
Hi Franz,
vielen Dank für deine Antwort bzw. Makro.
Ich habe es gerade getestet. Leider löscht mir das Makro alle Datalabels.
Anbei eine kleine Beispieldatei:
https://www.herber.de/bbs/user/113936.xlsx
Die bestehenden Datalabels mit Kommentaren sollen nicht gelöscht werden.
Nur die, die keinen Eintag haben im Sheet Kommentare haben.
Danke und Gruß,
Daniel
AW: DataLabels löschen
06.06.2017 15:40:12
Daniel
Hi Franz,
könnte man irgendwie mittels DataLabel.Text abfragen welche Felder leer sind
und diese anschließend löschen?
Gruß Daniel
AW: DataLabels löschen
07.06.2017 06:52:09
fcs
Hallo Daniel,
da hatte ich in deiner Frage das Wort "leeren" überlesen.
Hier das Makro angepasst mit Prüfung des Label-Textes.
Gruß
Franz
Sub prcDiagramm_Datalabels_leer_delete()
Dim wkb As Workbook
Dim wks As Worksheet
Dim objChart As Chart
Dim ChartObject As ChartObject
Set wkb = ActiveWorkbook
'in Diagrammblättern
For Each objChart In wkb.Charts
Call prcPoint_Datalabel_leer_delete(objChart)
Next
'in eingebetteten Diagrammen
For Each wks In wkb.Worksheets
For Each ChartObject In wks.ChartObjects
Call prcPoint_Datalabel_leer_delete(ChartObject.Chart)
Next
Next
End Sub
Sub prcPoint_Datalabel_leer_delete(objChart As Chart)
'leere Datenbeschriftungen löschen
Dim objSeries As Series
Dim objPoint As Point
Dim strText As String
For Each objSeries In objChart.SeriesCollection
For Each objPoint In objSeries.Points
With objPoint
If .HasDataLabel Then
With .DataLabel
strText = Trim(.Text)
If strText = "" Then
.Delete
End If
End With
End If
End With
Next
Next
End Sub

Anzeige

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige