Ich Krieg die Krise !!! Fehler nur bei mir?

Hallo Freunde,
Letzter versuch das Ding zu retten...:-)
Nachfolgende Tabelle geht bei mir beim Druck auf den Button "Auftrag drucken" im Makro "ZellinhaltTrennen" auf einen Fehler. Bei einem zweiten PC, mit identischem Excel läuft es....eigentlich eine ganz einfach Prozedur, aber ich krieg Sie seit stunden nicht zum laufen.....
Wer kann bitte helfen......
https://www.herber.de/bbs/user/116629.xlsm
Das "böse" Script wo bei "manchen PC´s" nicht läuft....


Private Sub Zellinhalt_trennen()
'** Trennen von Zellinhalten an einem vorgegebenen Trennzeichen
Dim strTeilstring()   As String
Dim strTrennzeichen As String
Dim LngY As Long
Dim wsakt As Object
ThisWorkbook.Sheets("Adressetikett").Range("A3:A9").ClearContents
ThisWorkbook.Sheets("Adressetikett").Range("A1").ClearContents
If Sheets("Adressetikett").Cells(14, 2).Value = True Then Sheets("Adressetikett").Cells(1, 1).  _
_
Value = "Postversand"
If Sheets("Adressetikett").Cells(13, 2).Value = True Then Sheets("Adressetikett").Cells(1, 1).  _
_
Value = "Hauspost"
If Sheets("Adressetikett").Cells(12, 2).Value = True Then Sheets("Adressetikett").Cells(1, 1).  _
_
Value = "Selbstabholung"
If Sheets("Adressetikett").Cells(1, 1).Value = "" Then Exit Sub
Set wsakt = ThisWorkbook.Sheets("Auftrag_Kopierzentrale")
Set wsZiel = ThisWorkbook.Sheets("Adressetikett")
strTrennzeichen = "," 'Trennzeichen festlegen z.B. Komma(,) Semikollon(;) Bindestrich(-) etc.
strTeilstring = Split(Trim(wsakt.Cells(13, 8).Value), strTrennzeichen)
LngY = 3
For A = LBound(strTeilstring) To UBound(strTeilstring)
wsZiel.Cells(LngY, 1).Value = Trim(strTeilstring(A))
LngY = LngY + 1
Next A
Application.ScreenUpdating = False
With Sheets("Adressetikett")
.Visible = True
.PrintOut
.Visible = False
End With
Application.ScreenUpdating = True
Worksheets("Auftrag_Kopierzentrale").Activate
End Sub

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Hallo Christian,
du hast in deiner Mappe ein paar Überflüssige und einen gebrochenen Verweis. Daher die Fehlermeldung.
Geh im VBA-Editor - Menüleiste Extras - Verweise in die Liste und löschen die letzten 3. Die werden nicht benötigt (siehe Bild).
Userbild

Ich war so frei deinen Code etwas zu bereinigen:

Private Sub Zellinhalt_trennen()
    '** Trennen von Zellinhalten an einem vorgegebenen Trennzeichen

    Dim strTeilstring() As String
    Dim strTrennzeichen As String
    Dim LngY As Long, A As Long

    With ThisWorkbook.Worksheets("Adressetikett")
        .Range("A1,A3:A9").ClearContents

        If .Cells(14, 2).Value Then
            .Cells(1, 1).Value = "Postversand"
        ElseIf .Cells(13, 2).Value Then
            .Cells(1, 1).Value = "Hauspost"
        ElseIf .Cells(12, 2).Value Then
            .Cells(1, 1).Value = "Selbstabholung"
        End If

        If Not IsEmpty(.Cells(1, 1).Value) Then

            strTrennzeichen = "," 'Trennzeichen festlegen z.B. Komma(,) Semikollon(;) Bindestrich(-) etc.

            strTeilstring = Split(ThisWorkbook.Worksheets("Auftrag_Kopierzentrale") _
                .Cells(13, 8).Value, strTrennzeichen)

            LngY = 3

            For A = LBound(strTeilstring) To UBound(strTeilstring)

                .Cells(LngY, 1).Value = Trim$(strTeilstring(A))

                LngY = LngY + 1

            Next A

            Application.ScreenUpdating = False

            .Visible = xlSheetVisible
            .PrintOut
            .Visible = xlSheetVeryHidden

            Application.ScreenUpdating = True

            Worksheets("Auftrag_Kopierzentrale").Activate

        End If
    End With
End Sub

Gruß
Nepumuk

Beliebteste Forumthreads (12 Monate)

Ich Krieg die Krise !!! Fehler nur bei mir?

10 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

10
Beiträge zum Forumthread

Beiträge zu diesem Forumthread