Bild einfügen ohne Verknüpfung

Hallo zusammen,
ich verwende diesen Code zum Einfügen beliebiger Bilder an beliebiger Stelle, wobei die Größe des Bildes an Zellhöhe angepasst wird:

Sub PictureInsertAndResize()
Dim sPicture As String, pic As Picture
sPicture = Application.GetOpenFilename _
("Pictures (*.gif; *.jpg; *.bmp; *.tif; *.jxr), *.gif; *.jpg; *.bmp; *.tif; *.jxr", _
, "Select Picture to Import")
If sPicture = "False" Then Exit Sub
Set pic = ActiveSheet.Pictures.Insert(sPicture)
With pic
.ShapeRange.LockAspectRatio = msoTrue
.Height = .TopLeftCell.Height
.Placement = xlMoveAndSize
End With
Set pic = Nothing
End Sub

Wie muss der Code angepasst werden, damit das Bild nicht als Verknüpfung eingefügt wird?
In den Foren lese ich, dass dies mit dem Befehl "ActiveSheet.Shapes.AddPicture" geht, aber ich weiß es nicht umzusetzen.
Kann bitte jemand helfen?
Viele Grüße
Kisska

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

' Einfügen ohne Select von Bert Körn ' Ausdruck.AddPicture(FileName, Verknüpfung, in Mappe speichern, ' Pos. Links, Pos. Oben, Breite, Höhe) ' erstes Offset Pos. Links 0 Zeilen und eine Spalte nach rechts ' zweites Offset Pos. Oben 0 Zeilen tiefer und 0 Spalten nach rechts With ActiveSheet.Shapes.AddPicture(StBild, True, True, _ Target.Offset(0, 1).Left, _ Target.Offset(0, 0).Top, DoBreite * DoBildhoehe / DoHohe, DoBildhoehe) ' Makro das bei Klick auf das Bild ausgeführt wird, Makro im mdl_BeiKlick .OnAction = "Bild_BeiKlick" .Name = "Pic" & Target ' Bildname festlegen End With

Hallo Kisska,
teste mal:

Public Sub PictureInsertAndResize()
    Dim sPicture As Variant, pic As Shape

    sPicture = Application.GetOpenFilename _
        ("Pictures (*.gif; *.jpg; *.bmp; *.tif; *.jxr), *.gif; *.jpg; *.bmp; *.tif; *.jxr", _
        , "Select Picture to Import")

    If sPicture <> False Then

        Set pic = ActiveSheet.Shapes.AddPicture(Filename:=sPicture, LinkToFile:=msoFalse, _
            SaveWithDocument:=msoTrue, Left:=Selection.Left, _
            Top:=Selection.Top, Width:=-1, Height:=-1)
        With pic
            .LockAspectRatio = msoTrue
            .Height = .TopLeftCell.Height
            .Placement = xlMoveAndSize
        End With
        Set pic = Nothing
    End If
End Sub

Gruß
Nepumuk

Beliebteste Forumthreads (12 Monate)

4
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

141 Forumthreads zu ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

Bild einfügen ohne Verknüpfung

4 Beiträge zum Forumthread Beiträge zu diesem Forumthread

141 Forumthreads zu ähnlichen Themen

VBA Beispiele zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

4
Beiträge zum Forumthread

Beiträge zu diesem Forumthread