Auto. Mail, bei erreichen des Datums

Hallo Zusammen
Da ich mit VBA nicht sehr gewannt bin, wollte ich nun Euch um Hilfe bitten.
Wisst Ihr wie ich folgende Aufgabe lösen kann?
Ich möchte gerne ein Macro schreiben der mir automatisch ein Reminder Email versendet, wenn das in einer bestimmten Zelle eingegebener Datum erreicht bzw. überschritten ist .
 Ich habe eine Tabelle mit den Spalten/Zeilen A1:K1000
 In der Spalten/Zeilen B1:B1000 ist der Name des Unternehmens eingetragen
 In der Spalten/Zeilen H1:H1000 ist das Datum des Reminders eingetragen
Sobald nun das Datum des Reminders in der Spalten/Zeilen H1:H1000 mit dem heutigen Datum übereinstimmt, muss ein automatisches Email versendet werden, dass den Wert in der Spalten/Zeilen B1:B1000 enthält.
Bsp:
Heute 20.04.2020
Reminder Datum in Zelle H35 = 20.04.2020
Wert in Zelle B35 = «Muster AG»
Da heute dasselbe Datum wie das in Zelle H35 ist, soll ein automatisches Email generiert werden mit dem Betreff «Reminder ! Firma Muster AG (B35) Kontaktieren».
Vielen Dank
MfG
Ricardo

Beitrag zum Forumthread

Beitrag zu diesem Forumthread

Betreff

Datum

Anwender

Hallo Ricardo,
in ein Standardmodul (Menüleiste im VBA-Editor - Einfügen - Modul):

Option Explicit

Public Sub Reminder()

    Dim lngDate As Long, ialngIndex As Long
    Dim avntDate As Variant
    Dim objOutlook As Object, objMail As Object
    Dim objWorksheet As Worksheet

    lngDate = Clng(Date)

    Set objWorksheet = Worksheets("Tabelle1") 'Anpassen !!!

    With objWorksheet

        avntDate = .Range(.Cells(1, 8), .Cells(.Rows.Count, 8).End(xlUp)).Value2

    End With

    For ialngIndex = LBound(avntDate, 1) To UBound(avntDate, 1)

        If avntDate(ialngIndex, 1) = lngDate Then

            If objOutlook Is Nothing Then Set objOutlook = CreateObject(Class:="Outlook.Application")
            Set objMail = objOutlook.CreateItem(0)

            With objMail
                .To = "mailadresse@provider.de" 'Anpassen !!!
                .Subject = "«Reminder ! Firma " & objWorksheet.Cells(ialngIndex, 2).Text & "Kontaktieren»"
                Call .Display 'zum testen Mail anzeigen
                ' Call .Send 'Mail direkt senden
            End With

            Set objMail = Nothing

        End If
    Next

    If Not objOutlook Is Nothing Then Set objOutlook = Nothing
    Set objWorksheet = Nothing

End Sub

Gruß
Nepumuk

Beliebteste Forumthreads (12 Monate)

Auto. Mail, bei erreichen des Datums

1 Beitrag zum Forumthread Beitrag zu diesem Forumthread

VBA Beispiele zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

1
Beitrag zum Forumthread

Beitrag zu diesem Forumthread