Internetseite mit Anmeldung öffnen

Harald · 2020-04-20T14:51:27+00:00

Hallo, In einem Datenblatt habe ich mehrere Buttons, mit denen ich beim Anklicken verschiedene Internetseiten (z.B. Online-Banking) über Firefox oder Chrome öffnen möchte, dort automatisch den Benutzernamen und das Passwort eintragen lasse und die Seite dann starte. Leider habe ich keine Ahnung, wie ich das umsetzen kann. Kann mir hier jemand helfen? Im voraus schon vielen Dank

Hallo Harald,
hier ist ein Beispiel, wie man sich auf der Seite einloggen kann. Es ist allerdings nicht möglich zu prüfen, ob noch etwas zusätzliches gemacht werden muss, weil der Zugang nach 3 Versuchen gesperrt wird. Zwar habe ich keinen Zugang, aber wenn die meine IP-Adresse sperren gehts auch nicht mehr.
Was evtl. zusätzlich auf der angegebenen Seite gemacht werden muss, ist das Auslösen eines Keypress-Events für die beiden Eingabefelder. Es ist für beide Felder hinterlegt, aber ich habe das Auslösen jetzt (noch) nicht eingebaut.
Damit Du verstehst, was das Makro macht, müsste ich jetzt etwas ausholen. Dazu habe ich aber keine Zeit im Moment. Deshalb nur kurz grob dazu:
Wie Du sehen kannst, werden die beiden Eingabefelder über getElementByID() angesprochen. Eine ID ist (soll es sein) im HTML-Code einer Seite einmalig. Konnte ein Element nicht über seine ID selektiert werden, wirft VBA zur Laufzeit einen Fehler. Deshalb habe ich das in die Fehlerroutine gekapselt und prüfe hinterher, ob das Objekt vorhanden ist.
Der Button hingegen wird über getElementsByClassName() angesprochen. Das bezieht sich auf eine CSS-Klasse, die beliebig vielen Elementen auf einer Seite zugewiesen worden sein kann. CSS steht für Cascading Style Sheet, womit das Design der Elemente einer Seite festgelegt wird.
Bei getElementsByClassName() ergibt sich also eine Sammlung von Elementen, eine sogenannte Node Collection, während über getElementByID() gezielt auf ein ganz bestimmtes Element der Seite zugegriffen wird. Um nun auf ein bestimmtes Element einer Node Collection zuzugreifen, muss das entsprechende Element über seinen Index in der Sammlung angesprochen werden.
Alle nach dem verwendeten Kriterium gefundenen Elemente werden der Reihenfolge des Auffindens nach in die Sammlung aufgenommen. Die Zählung der Indizes beginnt dabei immer bei 0 (Null). Der Button ist auf der vorliegenden Anmeldeseite das einzige Element mit der CSS-Klasse button-right. Deshalb kann es der Objektvariablen knotenSubmit direkt über die Angabe des Index in der Sammlung ganz am Ende der Zeile übergeben werden. Das passiert über die runden Klammern (0).
Es gibt noch die Methode getElementsByTagName(), über die ebenfalls eine Node Collection aufgebaut wird. In dem Fall aus allen HTML-Elementen, die dem angegebenen HTML-Tag entsprechen. Dabei wird die gesamte HTML-Struktur zwischen dem öffnenden und dem schließenden Tag als ein HTML-Element betrachtet. Das können also auch ganze Strukturen sein, wenn z.B. innerhalb eines div-Tags weitere HTML-Elemente untergebracht sind.
Hier ist nun das Makro. Das kann man auch anders schreiben. Sowohl besser, als auch schlechter. Ich habe es aber ganz bewußt genau so gemacht, weil Du die 3 angesprochenen Elemente auf jeder Seite zum Einloggen ansprechen musst. Du musst halt "nur" rausfinden wie, bzw. über welche Kriterien.


Sub UnionInvestEinloggen()
Dim browser As Object
Dim url As String
Dim knotenBenutzername As Object
Dim knotenPasswort As Object
Dim knotenSubmit As Object
Dim benutzerName As String
Dim passWort As String
benutzerName = "Dein Benutzername"
passWort = "Dein Passwort"
url = "https://www.union-investment.de/process?action=showLogin"
'Internet Explorer initialisieren, Sichtbarkeit festlegen,
'URL aufrufen und warten bis Seite vollständig geladen wurde
Set browser = CreateObject("internetexplorer.application")
browser.Visible = True
browser.Navigate url
Do Until browser.ReadyState = 4: DoEvents: Loop
'Eingabefeld für den Benutzernamen selektieren
On Error Resume Next
Set knotenBenutzername = browser.document.getElementByID("user")
On Error GoTo 0
'Prüfen, ob das Feld selektiert werden konnte
If Not knotenBenutzername Is Nothing Then
'Wenn ja, den Benutzernamen eintragen
knotenBenutzername.Value = benutzerName
Else
'Wenn nicht, Hinweis ausgeben und Makro beenden
MsgBox "Eingabefeld für den Benutzernamen wurde nicht gefunden"
Exit Sub
End If
'Eingabefeld für das Passwort selektieren
On Error Resume Next
Set knotenPasswort = browser.document.getElementByID("pin")
On Error GoTo 0
'Prüfen, ob das Feld selektiert werden konnte
If Not knotenPasswort Is Nothing Then
'Wenn ja, den Passwort eintragen
knotenPasswort.Value = passWort
Else
'Wenn nicht, Hinweis ausgeben und Makro beenden
MsgBox "Eingabefeld für das Passwort wurde nicht gefunden"
Exit Sub
End If
'Submit-Button selektieren
Set knotenSubmit = browser.document.getElementsByClassName("button-right")(0)
'Prüfen, ob der Submit-Button selektiert werden konnte
If Not knotenSubmit Is Nothing Then
knotenSubmit.Click
Else
'Wenn nicht, Hinweis ausgeben und Makro beenden
MsgBox "Der Submit-Button wurde nicht gefunden"
Exit Sub
End If
End Sub

Die Kurzversion davon ist folgende. Allerdings ohne jegliches Abfangen von Fehlern und ohne Variablen auch nicht ohne weiteres verwendbar, wenn Events ins Spiel kommen. Du kannst hier aber die Kernfunktionalität besser nachvollziehen:


Sub UnionInvestEinloggen()
Dim browser As Object
'Internet Explorer initialisieren, Sichtbarkeit festlegen,
'URL aufrufen und warten bis Seite vollständig geladen wurde
Set browser = CreateObject("internetexplorer.application")
browser.Visible = True
browser.Navigate "https://www.union-investment.de/process?action=showLogin"
Do Until browser.ReadyState = 4: DoEvents: Loop
'Benutzernamen eingeben
browser.document.getElementByID("user").Value = "Benutzername"
'Passwort eingeben
browser.document.getElementByID("pin").Value = "Passwort"
'Submit-Button anklicken
browser.document.getElementsByClassName("button-right")(0).Click
End Sub

Viele Grüße,
Zwenn

Hallo Harald,
ich habe für die beiden Eingabefelder jetzt eingebaut, dass das Keypress Event ausgelöst wird, bevor die Eingaben stattfinden. Probiere das mal aus. Wenn das nicht klappt, dann weiß ich nicht warum nicht, denn der Button selbst hat kein Event und die Eingabefelder haben jeweils nur das Keypress Event.
Bei meinen Versuchen wird im IE einfach das Feld für das Passwort wieder geleert und es kommt auch kein Hinweistext, dass die Eingegeben Daten falsch sind. Wie gesagt, probiere es mal aus:
Das um das Auslösen der Keypress-Events erweiterte Makro:


Sub UnionInvestEinloggen()
Dim browser As Object
Dim url As String
Dim knotenBenutzername As Object
Dim knotenPasswort As Object
Dim knotenSubmit As Object
Dim benutzerName As String
Dim passWort As String
benutzerName = "DeinBenutzername"
passWort = "DeinPasswort"
url = "https://www.union-investment.de/process?action=showLogin"
'Internet Explorer initialisieren, Sichtbarkeit festlegen,
'URL aufrufen und warten bis Seite vollständig geladen wurde
Set browser = CreateObject("internetexplorer.application")
browser.Visible = True
browser.navigate url
Do Until browser.readyState = 4: DoEvents: Loop
'Eingabefeld für den Benutzernamen selektieren
On Error Resume Next
Set knotenBenutzername = browser.document.getElementByID("user")
On Error GoTo 0
'Prüfen, ob das Feld selektiert werden konnte
If Not knotenBenutzername Is Nothing Then
'Wenn ja, keypress Event auslösen und den Benutzernamen eintragen
Call TriggerEvent(browser.document, knotenBenutzername, "onkeypress")
knotenBenutzername.Value = benutzerName
Else
'Wenn nicht, Hinweis ausgeben und Makro beenden
MsgBox "Eingabefeld für den Benutzernamen wurde nicht gefunden"
Exit Sub
End If
'Eingabefeld für das Passwort selektieren
On Error Resume Next
Set knotenPasswort = browser.document.getElementByID("pin")
On Error GoTo 0
'Prüfen, ob das Feld selektiert werden konnte
If Not knotenPasswort Is Nothing Then
'Wenn ja, keypress Event auslösen und das Passwort eintragen
Call TriggerEvent(browser.document, knotenPasswort, "onkeypress")
knotenPasswort.Value = passWort
Else
'Wenn nicht, Hinweis ausgeben und Makro beenden
MsgBox "Eingabefeld für das Passwort wurde nicht gefunden"
Exit Sub
End If
'Submit-Button selektieren
Set knotenSubmit = browser.document.getElementsByClassName("button-right")(0)
'Prüfen, ob der Submit-Button selektiert werden konnte
If Not knotenSubmit Is Nothing Then
knotenSubmit.Click
Else
'Wenn nicht, Hinweis ausgeben und Makro beenden
MsgBox "Der Submit-Button wurde nicht gefunden"
Exit Sub
End If
End Sub

Die folgende Sub löst ein übergebenes HTML-Event aus:


Private Sub TriggerEvent _
(htmlDocument As Object, htmlElementWithEvent As Object, eventType As String)
Dim theEvent As Object
htmlElementWithEvent.Focus
Set theEvent = htmlDocument.createEvent("HTMLEvents")
theEvent.initEvent eventType, True, False
htmlElementWithEvent.dispatchEvent theEvent
End Sub

Viele Grüße,
Zwenn

Internetseite mit Anmeldung öffnen

Forumthread: Internetseite mit Anmeldung öffnen

14
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Infobox / Tutorial