Dialogfenster für die Auswahl von Arbeit

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Oh, welch Freude. Lauter kompetente Antworten. Danke Euch allen, danke.
Jetzt habe ich noch eine Zusatzfrage:
Kann man das aufrufenden Makro, also da, wo "Userform1.show" steht, so gestalten, dass der Userformaufruf das Ergebnis der Userformbefragung, also die getroffene Sheets-Auswahl, zurückgibt, sodass man dann im nächsten Schritt das "Sub Eintrag(Arbeitsblatt As Worksheet)" in einer Schleife aufruft?
Der alte Drescher zB ruft das Sub Eintrag direkt in der Userform auf. Ich hätte aber gerne, dass das im Aufrufprogramm, und nicht in der Userform geschieht.
Etwa so:

a=UserForm1.Show
if a= wasweissich then exit sub
for each b in a
Eintrag b
next b

Ich finde das übersichtlicher, weil man gleich sieht, was von der Userform erwartet wird.
Liebe Grüße von TW

Hallo,
Du könntest Dir eine eigene Function oder Eigenschafts-Proc in der Form schreiben, damit könnte es auch gehen...

' ********************************************************************** 
' Modul: Modul1 Typ: Standardmodul 
' ********************************************************************** 

Option Explicit

Public Sub Aufruf()
Dim objWorkSheet As Worksheet
Dim objSheetCollection As Collection
Set objSheetCollection = UserForm1.Form_Show

For Each objWorkSheet In objSheetCollection
    Call Eintrag(objWorkSheet)
Next
Set objSheetCollection = Nothing
End Sub

Public Sub Eintrag(ByRef Arbeitsblatt As Worksheet)
Debug.Print Arbeitsblatt.Name
'''    With Arbeitsblatt 
'''        .Range("B2").Value = "Guten Morgen" 
'''    End With 
End Sub

' ********************************************************************** 
' Modul: UserForm1 Typ: Userform 
' ********************************************************************** 

Option Explicit

Private mobjSheetCollection As Collection

Private Sub CommandButton1_Click()
Dim lngIndex As Long
With ListBox1
    For lngIndex = 0 To .ListCount - 1
        If .Selected(pvargIndex:=lngIndex) Then _
           Call mobjSheetCollection.Add(Item:=Worksheets(.List(pvargIndex:=lngIndex)))
    Next
End With
Call Unload(Object:=Me)
End Sub

Private Sub CommandButton2_Click()
Call Unload(Object:=Me)
End Sub

Private Sub UserForm_Activate()
Dim objWorkSheet As Worksheet
For Each objWorkSheet In Worksheets
    Call ListBox1.AddItem(pvargItem:=objWorkSheet.Name)
Next
End Sub

Private Sub UserForm_Terminate()
Set mobjSheetCollection = Nothing
End Sub

Public Function Form_Show() As Collection
Dim objSheetCollection As Collection
Set objSheetCollection = New Collection
Set mobjSheetCollection = objSheetCollection
Call Show
Set Form_Show = objSheetCollection
Set objSheetCollection = Nothing
End Function



VBA/HTML - CodeConverter für Office-Foren

AddIn für Excel/Word 2000-2010 - komplett in VBA geschrieben von Lukas Mosimann
Projektbetreuung durch mumpel


Code erstellt und getestet in Office 14

Gruß, Mullit

Beliebteste Forumthreads (12 Monate)

Dialogfenster für die Auswahl von Arbeit

10
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

Dialogfenster für die Auswahl von Arbeit

10 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu verwandten Themen

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

10
Beiträge zum Forumthread

Beiträge zu diesem Forumthread