String überprüfen und Stellen ersetzen?

#Meine Kommentare #$FK5.0$ 11.05.2018 19:04:00 #301,dialog toolsettings;help Model_Zeichen=45 Platzhalter=# Sachdatensatzname=Projekt_Plannummer Referenz=test Phase=04_Phase;2;12 Status=10_Status;1;33 Index=11_Index;2;35

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Hallo Sergej,
teste mal:

Option Explicit

Public Sub Test()

    Const STRING_VALUE As String = "DLH-DZA-PG-##-H001-GU-EG0-00-01-#-##-FREIGABE"
    Const FILE_PATH As String = "P:\Einstellungen\tag_read.txt"

    Dim intFreeFile As Integer
    Dim lngLength As Long, lngStart As Long
    Dim strInput As String, strPlaceholder As String
    Dim blnFound As Boolean
    Dim vntTemp As Variant

    If Dir$(FILE_PATH) <> vbNullString Then

        Reset
        intFreeFile = FreeFile

        Open FILE_PATH For Input As #intFreeFile

        Do Until EOF(intFreeFile)

            Line Input #intFreeFile, strInput

            Select Case True

                Case InStr(1, strInput, "Model_Zeichen") > 0

                    lngLength = Clng(Split(strInput, "=")(1))

                    If lngLength <> Len(STRING_VALUE) Then _
                        Call MsgBox("Länge passt nicht.", vbExclamation, "Hinweis")

                Case InStr(1, strInput, "Platzhalter") > 0

                    blnFound = True

                    strPlaceholder = Split(strInput, "=")(1)

                Case blnFound And InStr(1, strInput, "Phase") > 0

                    If Len(strInput) - 2 = Len(Replace(strInput, ";", vbNullString)) Then

                        vntTemp = Split(strInput, ";")

                        lngStart = Clng(vntTemp(UBound(vntTemp)))

                        lngLength = Clng(vntTemp(UBound(vntTemp) - 1))

                        If Mid$(STRING_VALUE, lngStart, lngLength) <> String$(lngLength, strPlaceholder) Then _
                            Call MsgBox("Phase stimmt nicht", vbExclamation, "Hinweis")

                    End If

                Case blnFound And InStr(1, strInput, "Status") > 0

                    If Len(strInput) - 2 = Len(Replace(strInput, ";", vbNullString)) Then

                        lngStart = Clng(vntTemp(UBound(vntTemp)))

                        lngLength = Clng(vntTemp(UBound(vntTemp) - 1))

                        If Mid$(STRING_VALUE, lngStart, lngLength) <> String$(lngLength, strPlaceholder) Then _
                            Call MsgBox("Status stimmt nicht", vbExclamation, "Hinweis")

                    End If

                Case blnFound And InStr(1, strInput, "Index") > 0

                    If Len(strInput) - 2 = Len(Replace(strInput, ";", vbNullString)) Then

                        lngStart = Clng(vntTemp(UBound(vntTemp)))

                        lngLength = Clng(vntTemp(UBound(vntTemp) - 1))

                        If Mid$(STRING_VALUE, lngStart, lngLength) <> String$(lngLength, strPlaceholder) Then _
                            Call MsgBox("Index stimmt nicht", vbExclamation, "Hinweis")

                    End If
            End Select
        Loop

        Close #intFreeFile

    Else
        Call MsgBox("Datei nicht vorhanden.", vbExclamation, "Hinweis")
    End If
End Sub

Gruß
Nepumuk

Hallo Sergej,
so besser?

Option Explicit

Public Sub Test()

    Const STRING_VALUE As String = "DLH-DZA-PG-##-H001-GU-EG0-00-01-#-##-FREIGABE"
    Const FILE_PATH As String = "H:\Einstellungen\tag_read.txt"

    Dim intFreeFile As Integer
    Dim lngLength As Long, lngStart As Long
    Dim strInput As String, strPlaceholder As String
    Dim blnFound As Boolean, blnError As Boolean
    Dim vntTemp As Variant

    If Dir$(FILE_PATH) <> vbNullString Then

        Reset
        intFreeFile = FreeFile

        Open FILE_PATH For Input As #intFreeFile

        Do Until EOF(intFreeFile)

            Line Input #intFreeFile, strInput

            Select Case True

                Case InStr(1, strInput, "Model_Zeichen") > 0

                    vntTemp = Split(strInput, "=")

                    If IsNumeric(vntTemp(1)) Then

                        lngLength = Clng(vntTemp(1))

                        If lngLength <> Len(STRING_VALUE) Then

                            Call MsgBox("Länge passt nicht.", vbExclamation, "Hinweis")

                            blnError = True

                        End If
                    Else

                        Call MsgBox("Keine Länge gefunden.", vbExclamation, "Hinweis")

                        blnError = True

                    End If

                Case InStr(1, strInput, "Platzhalter") > 0

                    strPlaceholder = Split(strInput, "=")(1)

                    If strPlaceholder <> vbNullString Then blnFound = True


                Case blnFound And InStr(1, strInput, "Phase") > 0

                    If Len(strInput) - 2 = Len(Replace(strInput, ";", vbNullString)) Then

                        vntTemp = Split(strInput, ";")

                        lngStart = Clng(vntTemp(UBound(vntTemp)))

                        lngLength = Clng(vntTemp(UBound(vntTemp) - 1))

                        If Mid$(STRING_VALUE, lngStart, lngLength) <> String$(lngLength, strPlaceholder) Then

                            Call MsgBox("Phase stimmt nicht", vbExclamation, "Hinweis")

                            blnError = True

                        End If
                    End If

                Case blnFound And InStr(1, strInput, "Status") > 0

                    If Len(strInput) - 2 = Len(Replace(strInput, ";", vbNullString)) Then

                        vntTemp = Split(strInput, ";")

                        lngStart = Clng(vntTemp(UBound(vntTemp)))

                        lngLength = Clng(vntTemp(UBound(vntTemp) - 1))

                        If Mid$(STRING_VALUE, lngStart, lngLength) <> String$(lngLength, strPlaceholder) Then

                            Call MsgBox("Status stimmt nicht", vbExclamation, "Hinweis")

                            blnError = True

                        End If
                    End If

                Case blnFound And InStr(1, strInput, "Index") > 0

                    If Len(strInput) - 2 = Len(Replace(strInput, ";", vbNullString)) Then

                        vntTemp = Split(strInput, ";")

                        lngStart = Clng(vntTemp(UBound(vntTemp)))

                        lngLength = Clng(vntTemp(UBound(vntTemp) - 1))

                        If Mid$(STRING_VALUE, lngStart, lngLength) <> String$(lngLength, strPlaceholder) Then

                            Call MsgBox("Index stimmt nicht", vbExclamation, "Hinweis")

                            blnError = True

                        End If
                    End If
            End Select
        Loop

        Close #intFreeFile

        If Not blnError Then Call MsgBox("Alles in Ordnung.", vbInformation, "Information")

    Else
        Call MsgBox("Datei nicht vorhanden.", vbExclamation, "Hinweis")
    End If
End Sub

Gruß
Nepumuk

Beliebteste Forumthreads (12 Monate)

String überprüfen und Stellen ersetzen?

5 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

5
Beiträge zum Forumthread

Beiträge zu diesem Forumthread