Live-Forum - Die aktuellen Beiträge
Datum
Titel
28.03.2024 21:12:36
28.03.2024 18:31:49
Anzeige
Archiv - Navigation
1792to1796
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Inhaltsverzeichnis

Zeilen Auslesen

Zeilen Auslesen
10.11.2020 16:37:47
Mauricio
Hallo zusammen,
Ich bin neu in diesem Forum und auch noch recht neu im Umgang mit VBA, konnte mir bis jetzt aber soweit alles im Selbststudium beibringen.
Nun komm ich aber absolut nicht weiter und Google hilft auch nicht so richtig.
Unsere Excel Liste dient uns als Arbeitsvorrat bzw. ToDo Liste, sortiert nach Jahren.
Sprich wir arbeiten zurzeit in Tabellenblatt 2020.
in Spalte E ist immer eine Status Nummer vergeben (26 heißt abarbeiten, 61 heißt Fertig)
über ein Makro wird die Aktuelle liste Sortiert damit alles was abzuarbeiten ist untereinander steht.
Ändert sich jetzt in einem Jahr ein Material, sprich es bekommt wieder Status 26 steht es wieder alleine da.
Nun müssen aber meine Kollegen und Ich, jeden Tag alle Listen Durchsuchen und schauen ob sich ein Status geändert hat.
Meine Idee wäre ein extra Tabellen Blatt, wo per Makro alle Blätter Durchsucht werden und alle Zeilen wo in Spalte E 26 steht komplett Zusammen aufgeführt werden.
Sozusagen wie eine eine Aktuelle ToDo liste aus allen Blättern.
kann mir da jemand weiterhelfen?

8
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: Zeilen Auslesen
10.11.2020 16:47:35
Hajo_Zi
E26 ist keine Spalte.
frage jemand der neben Dir sitzt der sieht die Datei.
Die meisten hier sehen Sie nicht.
Da Sie nicht auf Deinen Rechner schauen.
Vielleicht sollte die Datei verlinkt werden?
Benutze hier im Forum die Funktion zum hochladen. Falls Du die nicht benutzen möchtest beachte, von unsicheren Servern wie z.B. www.file-upload.net lade ich keine Datei runter. (lt. Einschätzung meines Virenprogramms)
Wenn du an Stelle einer Demomappe deine Originalmappe hochladen willst, diese aber sensible Daten enthält, kannst du diese Daten ändern. Schaue Datei
http://hajo-excel.de/gepackt/fremd/Datei_verschluesseln.zip
Das ist nur meine Meinung zu dem Thema.

Anzeige
AW: Zeilen Auslesen
10.11.2020 17:15:14
Nepumuk
Hallo Mauricio,
Rechtsklick auf den Reiter der Tabelle "Aktuelle ToDo" - Code anzeigen. Folgende Prozedur einfügen:
Option Explicit

Private Sub Worksheet_Activate()
    Dim objWorksheet As Worksheet
    Dim objCell As Range
    Dim lngRow As Long
    Dim strFirstAddress As String
    With Application
        .Calculation = xlCalculationManual
        .EnableEvents = False
        .ScreenUpdating = False
    End With
    Call Range(Cells(2, 1), Cells(Rows.Count, Columns.Count)).ClearContents
    lngRow = 1
    For Each objWorksheet In ThisWorkbook.Worksheets
        If objWorksheet.Name Like "####" Then
            Set objCell = objWorksheet.Columns(5).Find(What:=26, LookIn:=xlValues, LookAt:=xlWhole)
            If Not objCell Is Nothing Then
                strFirstAddress = objCell.Address
                Do
                    lngRow = lngRow + 1
                    Call objCell.EntireRow.Copy(Destination:=Cells(lngRow, 1))
                    Set objCell = objWorksheet.Columns(5).FindNext(After:=objCell)
                Loop Until objCell.Address = strFirstAddress
                Set objCell = Nothing
            End If
        End If
    Next
    With Application
        .Calculation = xlCalculationAutomatic
        .EnableEvents = True
        .ScreenUpdating = True
    End With
End Sub

Ich bin davon ausgegangen dass sich in Zeile 1 Überschriften befinden.
Gruß
Nepumuk
Anzeige
AW: Zeilen Auslesen
10.11.2020 17:41:56
Mauricio
Hallo Nepumuk,
Soweit ist es genau das was ich gesucht habe, Danke!
Ich habe jetzt nur das Problem das in Spalte T ein Hyperlink steht der auf einen Ordner verweist, dieser lässt sich danach weder in der ToDo noch in dem normalen Blatt mehr öffnen.
was muss ich Ändern damit er in der ToDo liste erst in Zeile 5 anfängt mit Aufzählen?
viele Grüße
AW: Zeilen Auslesen
10.11.2020 17:53:05
Nepumuk
Hallo Mauricio,
das mit dem Hyperlink habe ich soeben getestet. Der funktioniert im Original als auch in der Kopie einwandfrei. Bist du dir sicher dass er jemals funktioniert hat? Denn kopieren ändert in der Ursprungszelle nichts.
Ab Zeile 5 so:
Option Explicit

Private Sub Worksheet_Activate()
    Dim objWorksheet As Worksheet
    Dim objCell As Range
    Dim lngRow As Long
    Dim strFirstAddress As String
    With Application
        .Calculation = xlCalculationManual
        .EnableEvents = False
        .ScreenUpdating = False
    End With
    Call Range(Cells(5, 1), Cells(Rows.Count, Columns.Count)).ClearContents
    lngRow = 4
    For Each objWorksheet In ThisWorkbook.Worksheets
        If objWorksheet.Name Like "####" Then
            Set objCell = objWorksheet.Columns(5).Find(What:=26, LookIn:=xlValues, LookAt:=xlWhole)
            If Not objCell Is Nothing Then
                strFirstAddress = objCell.Address
                Do
                    lngRow = lngRow + 1
                    Call objCell.EntireRow.Copy(Destination:=Cells(lngRow, 1))
                    Set objCell = objWorksheet.Columns(5).FindNext(After:=objCell)
                Loop Until objCell.Address = strFirstAddress
                Set objCell = Nothing
            End If
        End If
    Next
    With Application
        .Calculation = xlCalculationAutomatic
        .EnableEvents = True
        .ScreenUpdating = True
    End With
End Sub

Gruß
Nepumuk
Anzeige
AW: Zeilen Auslesen
11.11.2020 12:40:00
Mauricio
Hallo Nepumuk,
Ja, dass mit dem Link war mein Fehler.
Habe die Hauptdatei vom Server auf den Desktop kopiert um da erstmal zu Probieren, wahrscheinlich hat er da Unterwegs was verloren. :)
wie bekomme ich noch die weiteren verweise auf die anderen Tabellenblätter hin?
If objWorksheet.Name Like "2019","2020",2021 Then
kommt immer "erwartet Then oder GoTo"
viele Grüße
AW: Zeilen Auslesen
11.11.2020 12:42:46
Nepumuk
Hallo Mauricio,
ich prüfe doch schon hier:
If objWorksheet.Name Like "####" Then
ob der Tabellenname eine vierstellige Zahl ist.
Gruß
Nepumuk
AW: Zeilen Auslesen
11.11.2020 12:57:34
Mauricio
Hallo Nepumuk,
ok ok das hab ich so nicht gewusst, doch noch ziemlich viel zu Lernen was VBA angeht :D
Funktioniert alle wie gewünscht!
vielen vielen Dank !
Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige