AW: excel vba mail
14.12.2020 15:41:54
Beverly
In dem Fall solltest du den Zellinhalt in HTML-Text umwandeln:
Sub MailSenden()
Dim objNachricht As Object
Dim objMail As Object
Dim rngBereich As Range
Dim strHTML As String
Set rngBereich = Range("B2")
Set objMail = CreateObject("Outlook.Application")
Set objNachricht = objMail.CreateItem(0)
With objNachricht
.to = Range("B3")
.Subject = Range("B4")
' HTML-Text erstellen
strHTML = RangetoHTML(rngBereich)
' HTML-Body eintragen
.HTMLBody = strHTML
.ReadReceiptRequested = False
' Mail anzeigen
.display
'.send
End With
Set objNachricht = Nothing
Set objMail = Nothing
Set rngBereich = Nothing
End Sub
Function RangetoHTML(rng As Range)
' Changed by Ron de Bruin 28-Oct-2006
' Working in Office 2000-2007
On Error Resume Next
Dim fso As Object
Dim ts As Object
Dim TempFile As String
Dim TempWB As Workbook
TempFile = Environ$("temp") & "/" & Format(Now, "dd-mm-yy h-mm-ss") & ".htm"
Set TempWB = Workbooks.Add(1)
TempFile = Environ$("temp") & "/" & Format(Now, "dd-mm-yy h-mm-ss") & ".htm"
Set TempWB = Workbooks.Add(1)
rng.Copy
With TempWB.Sheets(1)
.Cells(1).PasteSpecial Paste:=8
.Cells(1).PasteSpecial xlPasteValues, , False, False
.Cells(1).PasteSpecial xlPasteFormats, , False, False
.Cells(1).Select
Application.CutCopyMode = False
' .DrawingObjects.Visible = True
'.DrawingObjects.Delete
On Error GoTo 0
End With
'Publish the sheet to a htm file
With TempWB.PublishObjects.Add( _
SourceType:=xlSourceRange, _
Filename:=TempFile, _
Sheet:=TempWB.Sheets(1).Name, _
Source:=TempWB.Sheets(1).UsedRange.Address, _
HtmlType:=xlHtmlStatic)
.Publish (True)
End With
'Read all data from the htm file into RangetoHTML
Set fso = CreateObject("Scripting.FileSystemObject")
Set ts = fso.GetFile(TempFile).OpenAsTextStream(1, -2)
RangetoHTML = ts.readall
ts.Close
RangetoHTML = Replace(RangetoHTML, "align=center x:publishsource=", _
"align=left x:publishsource=")
'Close TempWB
TempWB.Close savechanges:=False
'Delete the htm file we used in this function
Kill TempFile
Set ts = Nothing
Set fso = Nothing
Set TempWB = Nothing
End Function