Daten aus div. Dateien zusammenfassen

Hallo zusammen,
bin neu in dem Forum, hab es aber schon öfters für Recherchen genutzt und bin auch meist fündig geworden. Nun habe ich aber ein Problem, bei dem ich leider nicht weiter komme. Wahrschinlich kommt es dem einen oder anderen bekannt vor, da auch hier die Problematik schon des Öfteren Thema war, aber mit den bisher bereitgestellten Codes kam ich leider nicht weiter, bzw. konnte sie für meine Zwecke leider nicht passend umschreiben. Meine Vorkenntnisse in VBA sind noch eher dürftig. Bisher konnte ich mit einfachen Makroaufzeichnungen und kleineren Anpassung durchgekommen. Aber ich weiß zumindest wo man die Codes einfügt;-)
Hier meine Aufgabenstellung.
In einem bestimmten Ordner sind bzw. werden unterschiedlich benannten .xlsx Dateien abgelegt. Sie sind alle gleich aufgebaut. In jeder Datei ist ein Tabellenblatt mit dem Namen "Export" enthalten. Die Erste Zeile dieses Tabellenblattes enthält Überschirften und in der Zweiten Zeile sind die dazugehörigen Daten enthalten die ich gerne in einer Gesamtdatei (per Knopfdruck) untereinander auflisten lassen möchte.
Der Pfad wird immer der gleiche sein auf dem dem die zusammenzufassenden Dateien abgelegt werden.
Nach dem Zusammenfassen sollen die ursünglichen Dateien bestehen bleiben.
Hier ist ein einfaches Beispiel der Gesamtdatei:
https://www.herber.de/bbs/user/142585.xlsx
Hier sind zwei Beispieldateien für die Datenherkunft (Export) abgelegt:
https://www.herber.de/bbs/user/142586.xlsx
https://www.herber.de/bbs/user/142587.xlsx
Wäre prima, wenn mir jemand helfen könnte.
Viele Grüße
Suchender_MM

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Hallo Manuel,
na dann so:

Option Explicit

Public Sub Import_Data()

    Const FOLDER_PATH As String = "H:\1227\" ' Anpassen, Backslash am Ende nicht löschen !!!

    Dim strFileName As String
    Dim lngRow As Long
    Dim objWorkbook As Workbook, objWorksheet As Worksheet

    lngRow = 2

    Call Range("C2:H" & CStr(Rows.Count)).ClearContents

    strFileName = Dir$(FOLDER_PATH & "*.xlsx")

    Do Until strFileName = vbNullString

        Set objWorkbook = GetObject(PathName:=FOLDER_PATH & strFileName)

        For Each objWorksheet In objWorkbook.Worksheets

            If objWorksheet.Name = "Export" Then Exit For

        Next

        If Not objWorksheet Is Nothing Then

            With objWorksheet

                Call .Range(.Cells(2, 1), .Cells(.Rows.Count, 6).End(xlUp)).Copy

            End With

            Call Cells(lngRow, 3).PasteSpecial(Paste:=xlPasteValuesAndNumberFormats)

        End If

        Call objWorkbook.Close(SaveChanges:=False)

        lngRow = Cells(Rows.Count, 3).End(xlUp).Offset(1, 0).Row

        strFileName = Dir$

    Loop

    Set objWorksheet = Nothing
    Set objWorkbook = Nothing

End Sub

Gruß
Nepumuk

Beliebteste Forumthreads (12 Monate)

Daten aus div. Dateien zusammenfassen

11 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

11
Beiträge zum Forumthread

Beiträge zu diesem Forumthread