AW: Logisch...
21.12.2021 08:32:42
Burkhard
Hallo Karl-Heinz,
danke für deinen Code. Allerdings habe ich da noch einen Fehler, den ich selber nicht beheben kann.
Das mit dem Einfügen funktioniert nur dann, wenn vorher eine Mail händisch geöffnet wurde.
Dann sind die kopierten Zellen in der geöffneten Mail und der Text in einer zweiten Mail, die sich dann öffnet.
Aber schön kurz ist dein Code auf alle Fälle!
Danke.
Hallo Boris,
Dein Code funktioniert gut.
Ist zwar deutlich länger, aber das stört mich gerade nicht. ;-)
In dem Code verstehe ich pauschal nicht mal die Hälfte ;-) aber er funktioniert.
Auch dir danke.
Gruß Burkhard
Für alle die es auch nutzen möchten, es funktioniert, indem beide Codes in einem Modul sitze.
Sub Email_generieren()
'Tabellenbereich einfügen'
Dim rng As Range
Set rng = Range("a9:f13")
Set objOutlook = CreateObject("Outlook.Application")
Set objMail = objOutlook.CreateItem(0)
With objMail
.GetInspector.Display
.To = Range("b1").Value
.CC = Range("b6").Value
.Subject = "Text " & Range("b7").Value
.HTMLBody = "Guten Morgen " & Range("b1").Value & "," & _
RangetoHTML(rng)
.Display
End With
End Sub
Function RangetoHTML(rng As Range)
' Changed by Ron de Bruin 28-Oct-2006
' Working in Office 2000-2016
Dim fso As Object
Dim ts As Object
Dim TempFile As String
Dim TempWB As Workbook
TempFile = Environ$("temp") & "\" & Format(Now, "dd-mm-yy h-mm-ss") & ".htm"
'Copy the range and create a new workbook to past the data in
rng.Copy
Set TempWB = Workbooks.Add(1)
With TempWB.Sheets(1)
.Cells(1).PasteSpecial Paste:=8
.Cells(1).PasteSpecial xlPasteValues, , False, False
.Cells(1).PasteSpecial xlPasteFormats, , False, False
.Cells(1).Select
Application.CutCopyMode = False
On Error Resume Next
.DrawingObjects.Visible = True
.DrawingObjects.Delete
On Error GoTo 0
End With
'Publish the sheet to a htm file
With TempWB.PublishObjects.Add( _
SourceType:=xlSourceRange, _
Filename:=TempFile, _
Sheet:=TempWB.Sheets(1).Name, _
Source:=TempWB.Sheets(1).UsedRange.Address, _
HtmlType:=xlHtmlStatic)
.Publish (True)
End With
'Read all data from the htm file into RangetoHTML
Set fso = CreateObject("Scripting.FileSystemObject")
Set ts = fso.GetFile(TempFile).OpenAsTextStream(1, -2)
RangetoHTML = ts.readall
ts.Close
RangetoHTML = Replace(RangetoHTML, "align=center x:publishsource=", _
"align=left x:publishsource=")
'Close TempWB
TempWB.Close savechanges:=False
'Delete the htm file we used in this function
Kill TempFile
Set ts = Nothing
Set fso = Nothing
Set TempWB = Nothing
End Function