Bestimmte Werte per VBA übertragen

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

HI
wenn in der Spalte I schon Werte stehen, die bei 1 oder "" in Spalte M nicht geändert werden sollen, dann gehts auch nur über VBA.
es gibt mindestens vier Möglichkeiten.
a) per Schleife über alle Zellen:
dim Zelle as Range

dim Zelle as range

for each Zelle in Range("M2:M501")

    if Zelle.value = 0 Then Zelle.Offset(0, -4).value = Zelle.Value

Next

b) Autofilter

With Range("M1:M501")

    .Autofilter Field:=1, criteria1:="0"

    .Offset(1, -4).Resize(.Rows.Count - 1, 1).SpecialCells(xlcelltypevisible).Value = 0

    .Autofilter

end with

c) Formel mit Hilfsspalte, setzt voraus, dass in I Konstanten stehen und keine Formeln:

With Range("N2:N501")

    .FormulaR1C1 = "=IF(RC13=0,0,RC9)"

    .offset(0, -5).value = .value

    .Clearcontents

end with

d) per Array, auch hier dürfen in Spalte I keine Formeln stehen.

Dim arrI, arrM

Dim z As Long

With Range("I2:I501")

    arrI = .Value

    arrM = .Offset(0, 4).Value

    For z = 1 To UBound(arrI, 1)

        If arrM(z, 1) = 0 Then arrI(z, 1) = 0

    Next

    .Value = arrI

End With

Variante a) ist bei großen Datenmengen langsam
Variante b) kann bei sehr großen Datenmengen unzuverlässig werden (braucht aber +10.000 Zeilen) und falls es vorkommen kann, dass 0 nicht vorkommt, müsste man das noch prüfen, weil es sonst zu einem Fehler kommt.
Varianten c) und d) sind sehr schnell auch bei großen Datenmengen.
c) braucht halt die Hilfsspalte (was aber kein Problem sein sollte), kommt dafür aber ohne Schleifen und ohne zusätzliche Variablen aus, was den "Komfort" für den Programmierer erhöhen kann.
a) und b) hätten noch den Vorteil, dass die anderen Zellen nicht verändern, so dass hier auch Formeln stehen dürfen (wobei man dann überlegen sollte, ob man dann das ganze nicht nicht schon in die Formel einbaut, also: =Wenn(M2=0;0;bisherige Formel für I2)

Gruß Daniel

Jetzt habe ich verstanden, dass ich "Werte in die Zelle kopieren" und "Werte in der Zelle kopieren" durcheinandergebracht habe (bin eben ausländischer ;-)
Und ich fragte mich ständig: wohin will er dann die Werte kopieren?

Aber Fritz, hättest Du meinen Code gelesen, in Deutsch und laut gesprochen, wärst Du sehr schnell von

Sub Wert_festreinschreiben()

Dim i

    For i = 2 To 501

        If Cells(i, "M") = "0" Then Cells(i, "I").Value = Cells(i, "I").Value

    Next

End Sub

auf

Sub Wert_festreinschreiben()

Dim i

    For i = 2 To 501

        If Cells(i, "M") = "0" Then Cells(i, "I").Value = 0

    Next

End Sub

gekommen.

Eine Lösung zu haben, ist gut. Sie zu verstehen, besser. Daraus soviel wissen rausnehmen, dass die nächste Frage selber gelöst wird, der Jackpot.

VG
Yal

Beliebteste Forumthreads (12 Monate)

Bestimmte Werte per VBA übertragen

17 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

17
Beiträge zum Forumthread

Beiträge zu diesem Forumthread