Suchergebnis in mehrsp. Listbox Nachfrage

Informationen und Beispiele zu den hier genannten Dialog-Elementen:
ListBox MsgBox
Bild

Betrifft: Suchergebnis in mehrsp. Listbox Nachfrage von: Peter
Geschrieben am: 16.02.2005 23:31:38

Hallo,
muß doch nochmal fragen.
Ich hatte heute Hilfe erhalten komme jedoch nicht klar.
Wie man die gefundenen Werte in die mehrsp. Listbox verteilt?
(siehe Markierung ">>>>" )
Peter


Private Sub CmdSuchen_Click()
   Dim rngFind As Range, rngFirst As Range
   Dim rngAuswahl
   Dim i
  ListBox1.Clear
    
    rngAuswahl = ActiveCell.Value
   Set rngFind = Worksheets("Tabelle2").Columns(2).Find(rngAuswahl, lookat:=xlPart, LookIn:=xlValues)
   If rngFind Is Nothing Then
      MsgBox "Kein Suchbegriff gefunden!"
      Exit Sub
   End If
   Set rngFirst = rngFind
   Do
    ListBox1.AddItem rngFind.Offset(0, 1)
     
      '>>>>With ListBox1
       '>>>>For i = 1 To ????
       '>>>>  .AddItem
       '>>>>  .List(i, 0) = rngFind.Offset(0, 0)
       '>>>>  .List(i, 1) = rngFind.Offset(0, 1)
       '>>>>  .List(i, 2) = rngFind.Offset(0, 2)
      '>>>> Next
     '>>>>End With
      Set rngFind = Worksheets("Tabelle2").Columns(2).FindNext(rngFind)
   Loop While Not rngFind Is Nothing And rngFind.Address <> rngFirst.Address
End Sub

Bild


Betrifft: AW: Suchergebnis in mehrsp. Listbox Nachfrage von: Josef Ehrensberger
Geschrieben am: 16.02.2005 23:53:51

Hallo Peter!

Einmal .AddItem genügt!
Ausserdem musst du den Spaltenindex angeben.

Ungetestet:


Private Sub CmdSuchen_Click()
   Dim rngFind As Range, rngFirst As Range
   Dim rngAuswahl
   Dim i As Integer, n As Integer
  ListBox1.Clear
    
    rngAuswahl = ActiveCell.Value
   Set rngFind = Worksheets("Tabelle2").Columns(2).Find(rngAuswahl, lookat:=xlPart, LookIn:=xlValues)
   If rngFind Is Nothing Then
      MsgBox "Kein Suchbegriff gefunden!"
      Exit Sub
   End If
   Set rngFirst = rngFind
   Do
     
         With ListBox1
            .AddItem rngFind
            .List(n, 1) = rngFind.Offset(0, 1)
            .List(n, 2) = rngFind.Offset(0, 2)
            n = n + 1
         End With
     
      Set rngFind = Worksheets("Tabelle2").Columns(2).FindNext(rngFind)
   Loop While Not rngFind Is Nothing And rngFind.Address <> rngFirst.Address
End Sub



Gruß Sepp

P.S.: Rückmeldung nicht vergessen!


Bild


Betrifft: AW: Danke -jetzt funktioniert es von: Peter
Geschrieben am: 17.02.2005 00:04:59

Danke für die schnelle Hilfe.
Peter


 Bild

Beiträge aus den Excel-Beispielen zum Thema "Suchergebnis in mehrsp. Listbox Nachfrage"