Herbers Excel-Forum - das Archiv

Eingabeformular

Bild

Betrifft: Eingabeformular
von: Jürgen

Geschrieben am: 19.02.2005 20:43:48
Hallo Excelfreunde
Habe eine Kundendatei erstellt.
Wie kann man Daten aus nicht benachbarten Zellen von einem TB in ein anderes TB auf eine nächst leere Zeile kopieren.?
Kann da jemand helfen?
Ich wäre sehr dankbar
Gruß Jürgen
Bild

Betrifft: AW: Eingabeformular
von: Josef Ehrensberger

Geschrieben am: 19.02.2005 22:25:50
Hallo Jürgen!
Das hängt vom Aufbau deiner Tabelle ab!
Eine Möglichkeit währe z.B. so.
Option Explicit
Option Base 1
Sub Uebertrag()
Dim eingabe As Worksheet, TB As Worksheet
Dim lastRow As Long, i As Integer
Dim arr() As Variant
Dim rng As Range
Dim zellen As String
'hier alle Zellen des Eingabebereiches angeben
zellen = "B10,D11,E15,F4:F6,I3"
Set eingabe = Sheets("Eingabe")  'Tabellenname anpassen!
Set TB = Sheets("TB")            'Tabellenname anpassen!
'ermitteln der ersten leeren Zeile in "TB"
lastRow = IIf(TB.Range("A65536") <> "", _
65536, TB.Range("A65536").End(xlUp).Row) + 1
'Array mit Daten füllen
With eingabe
For Each rng In .Range(zellen)
i = i + 1
ReDim Preserve arr(1, i)
arr(1, i) = rng.Value
Next
End With
'Array an "TB" übergeben
With TB
.Range(.Cells(lastRow, 1), .Cells(lastRow, UBound(arr, 2))) = arr
End With
End Sub


Gruß Sepp
P.S.: Rückmeldung nicht vergessen!
 Bild