Cells.Find

Informationen und Beispiele zu den hier genannten Dialog-Elementen:
MsgBox
Bild

Betrifft: Cells.Find
von: Thomas
Geschrieben am: 24.02.2005 18:38:44
Hallo liebes Forum
Ich bin in der Recherche nicht fündig geworden. Folgende, ich möchte in der Tabelle Default den UserName suchen, dann die Telefon, Mail, Funktion und Nr ausschreiben. Funktioniert auch gut so. Nur wenn der UserName nicht in der Liste vorhanden ist, soll etwas anderes gemacht werden!
Ich möchte eine Abfrage nach Cells.Find(Waht:=.....
If UserName nicht vorhanden, Then etwas anderes
UserName = Application.UserName
Sheets("Default").Select
Worksheets("Default").Range("U3").Activate
Cells.Find(What:=UserName, After:=ActiveCell, LookIn:=xlFormulas, _
LookAt:=xlWhole, SearchOrder:=xlByRows, SearchDirection:=xlNext, _
MatchCase:=False).Activate ' SearchFormat:=False (Version 2000 Fehler)
Telefon = ActiveCell.Offset(0, 1).Value
Mail = ActiveCell.Offset(0, 2).Value
Funktion = ActiveCell.Offset(0, 3).Value
Nr = ActiveCell.Offset(0, 4).Value
Danke für eure Mühe.
Gruss Thomas

Bild

Betrifft: AW: Cells.Find
von: Josef Ehrensberger
Geschrieben am: 24.02.2005 18:52:10
Hallo Thomas!
Das sollte es tun!

Sub UserSuche()
Dim rng As Range
Dim UserName As String, Telefon As String, Mail As String
Dim Funktion As String, Nr As String
UserName = Application.UserName
   With Sheets("Default")
   Set rng = .Cells.Find(What:=UserName, LookIn:=xlFormulas, LookAt:=xlWhole)
   
      If Not rng Is Nothing Then
         Telefon = rng.Offset(0, 1).Value
         Mail = rng.Offset(0, 2).Value
         Funktion = rng.Offset(0, 3).Value
         Nr = rng.Offset(0, 4).Value
      Else
         MsgBox "Nicht gefunden!"
      End If
      
   End With
End Sub


Gruß Sepp
P.S.: Rückmeldung nicht vergessen!
Bild

Betrifft: Sepp, das tut es auch! Danke o.T
von: Thomas
Geschrieben am: 24.02.2005 19:07:41
.
 Bild

Beiträge aus den Excel-Beispielen zum Thema "Minimum mit versch. Kriterien"