Herbers Excel-Forum - das Archiv

Bewerten Sie hier bitte das Excel-Portal

Komplizierte WENN-Formel

Bild

Betrifft: Komplizierte WENN-Formel
von: tobias

Geschrieben am: 26.03.2005 12:51:39
Hallo,
ich benötige mal wieder ganz dringend Eure Hilfe, ich habe nämlich irgendwie den Überblick verloren.
Ich brauche eine komplizierte (wenigstens für mich kompliziert) WENN-Formel.
Also, die Einzelteile habe ich, es muss nur noch irgendwie zusammengefügt werden.
1. Wenn a1=b1 und c1=d1 und die Summe a1+c1 <= 4 dann e1
2. Wenn a1=b1 und c1=d1 und die Summe a1+c1 > 4 dann ((a1+c1)-4 * 0,5)+e1
3. Ansonsten 0

Puuuh...geschafft.
Wer kann mir die Teile zusammenfügen...
Danke im voraus
tobias
Bild

Betrifft: AW: Komplizierte WENN-Formel
von: Worti
Geschrieben am: 26.03.2005 13:04:43
Hallo tobias,
so sollte es gehen, wenn du dies ((a1+c1)-4 * 0,5)+ e1 wirklich so haben willst, denn das ist dasselbe wie ((a1+c1)- 2)+ e1
=WENN(UND(A1=B1;C1=D1;A1+C1<=4);E1;WENN(UND(A1=B1;C1=D1;A1+C1>4);((A1+C1)-4 * 0,5)+E1;0))
Gruß Worti
Bild

Betrifft: AW: dann aber so...
von: FP
Geschrieben am: 26.03.2005 13:25:35
Hallo Worti,
=E1+UND(A1=B1;C1:D1;A1+C1>4)*(A1+C1-2)
Servus aus dem Salzkammergut
Franz
Bild

Betrifft: AW: dann aber so... Nöö...
von: Worti
Geschrieben am: 26.03.2005 13:30:49
Hallo Franz,
bei dir kommt ja zumindest immer E1 raus, auch wenn 0 rauskommen soll!
Gruß aus dem Münsterland
Worti
Bild

Betrifft: wer lesen kann...
von: FP
Geschrieben am: 26.03.2005 13:39:32
Hallo Worti,
... ist immer im Vorteil ;-)
dann so: =(A1=B1)*(C1=D1)*(E1+MAX(0;A1+C1-4)/2)
Servus aus dem Salzkammergut
Franz
Bild

Betrifft: AW: wer lesen kann...
von: Worti
Geschrieben am: 26.03.2005 13:43:44
Hallo Franz,
gilt genau dasselbe wie für WF: Schöne Lösung ;-)
Gruß Worti
Bild

Betrifft: AW: Komplizierte WENN-Formel
von: tobias
Geschrieben am: 26.03.2005 13:30:44
Danke...hat geklappt...
tobias
Bild

Betrifft: aber ich hoffe...
von: FP
Geschrieben am: 26.03.2005 13:43:42
Hallo Tobias,
Du nimmst dann die Formel von WF, die ist dann eindeutig kürzer ...
Servus aus dem Salzkammergut
Franz
Bild

Betrifft: AW: Komplizierte WENN-Formel
von: Peter W
Geschrieben am: 26.03.2005 13:07:14
Servus,
so müsste es ungetestet klappen, wenn nicht Bsp. hochladen.
=WENN(UND(A1=B1;C1=D1;A1+C1<=4);E1;WENN(UND(A1=B1;C1=D1;A1+C1>4);((A1+C1)-4*0,5)+E1;0))
MfG
Peter
Bild

Betrifft: AW: Komplizierte WENN-Formel
von: =Peter=

Geschrieben am: 26.03.2005 13:08:43
Hallo Tobias,
so müsste es funktionieren:
Tabelle1
 ABCDE
133335
29    
Formeln der Tabelle
A2 : =WENN(UND(A1=B1;C1=D1;A1+C1<=4);E1;WENN(UND(A1=B1;C1=D1;A1+C1>4);((A1+C1)-4*0,5+E1);0))
 
Diagramm - Grafik - Excel Tabellen einfach im Web darstellen    Excel Jeanie HTML  3.0    Download  
HTH
Gruss
Peter
Bild

Betrifft: =(A1=B1)*(C1=D1)*E1+(A1+C1>4)*(A1+C1-2)
von: WF
Geschrieben am: 26.03.2005 13:17:15
Bild

Betrifft: =(A1=B1)*(C1=D1)*(E1+(A1+C1>4)*(A1+C1-2))
von: eine Klammer fehlte
Geschrieben am: 26.03.2005 13:21:32
Bild

Betrifft: AW: =(A1=B1)*(C1=D1)*E1+(A1+C1>4)*(A1+C1-2)
von: Worti
Geschrieben am: 26.03.2005 13:25:55
Hallo WF,
schöne Lösung, ich befürchte aber, er wollte statt((A1-C1)-4*0,5+E1) wie folgt Klammern:
(A1-C1-4)*0,5 + E1 und dann sähe der hintere Teil bei der Formel wohl so aus:
(A1+C1>4)*(A1+C1-4)*0,5
Gruß Worti
Bild

Betrifft: ich fürchte...
von: FP
Geschrieben am: 26.03.2005 13:32:07
Hallo Worti,
er wollte die Hälfte des 4 übersteigenden Wertes addieren ;-)
Lösung: https://www.herber.de/forum/messages/590754.html
Servus aus dem Salzkammergut
Franz
Bild

Betrifft: AW: ich fürchte...
von: tobias
Geschrieben am: 26.03.2005 13:47:53
Stimmt...das war meine Absicht...
Bild

Betrifft: dann mußt Du...
von: FP
Geschrieben am: 26.03.2005 13:58:27
Hallo Tobias,
... aber diese Formel verwenden:
=(A1=B1)*(C1=D1)*(E1+MAX(0;A1+C1-4)/2)
Servus aus dem Salzkammergut
Franz
Bild

Betrifft: AW: Komplizierte WENN-Formel
von: Reinhard
Geschrieben am: 26.03.2005 13:21:31
Hallo Tobias,
biste sicher mit ((a1+c1)-4 * 0,5)+e1 ?
ungetestet: =WENN((A1=B1)*(C1=D1);WENN(A1+C1<=4;E1;E1+0,5*(A1+C1-4));0)
Gruß
Reinhard

Bild

Betrifft: AW: Komplizierte WENN-Formel
von: tobstein
Geschrieben am: 26.03.2005 13:49:37
Hallo Reinhard,
ich bin mir sicher, hatte allerdings da eine Klammer vergessen.
So sollte es sein
(((a1+c1)-4) * 0,5)+e1

tobias
Bild

Betrifft: AW: falls Du...
von: FP
Geschrieben am: 26.03.2005 13:29:23
Tobias,
... eigentlich nur die Hälfte des Wertes der 4 übersteigt addieren möchtest:
=E1+(A1=B1)*(C1=D1)*MAX(0;A1+C1-4)/2
Servus aus dem Salzkammergut
Franz
 Bild
Excel-Beispiele zum Thema "Komplizierte WENN-Formel"
Beispiel für die Anwendung der SUMMEWENN-FORMEL Eine WENN-Formel nur bei der ersten Werteänderung berechnen