Den Status einer Aufgabe im Outlook verändern

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Hi Bernd
Zuerstmal merci für Deine Antwort, aber ich merke dass ich nicht wirklich schlau werde aus der "F1" Hilfe ;-(
Hier ist mal der Code mit dem ich die Aufgabe versende.
Um allgemein den Status einer Aufgabe verändern zu könnnen muss ich doch zuerst mal die betreffende Aufgabe identifizieren können.... WIe mache ich das?
So ein Beispiel-Code wäre wohl für mich "VB-DAU" am schönsten ;-)
Set app = CreateObject("Outlook.Application")
Set taskOutLook = app.CreateItem(3)
With taskOutLook
.Assign
.Recipients.Add Adresse
.Subject = Betreff & Pfad
.Body = Notiz2

' olImportanceNormal - Normal
' olImportanceLow - Niedrig
' olImportanceHigh - Hoch
.Importance = olImportanceNormal
.DueDate = EndTermin
.StartDate = StartTermin
.Send
End With
Set taskOutLook = Nothing
Set app = Nothing

Hallo M,
ich würde Dir folgendes empfehlen:
- Benutze immer (!) Option Explizit, d.h. Du mußt alle Deine Variable deklarieren
- Nimm - zumindestens am Anfang - immer frühe Bindung und deklariere die Outlookvariablen
'richtig', nicht nur als Object.
- Schreibe ein Outlook-Macro vielleicht zuerst in Outlook, nicht gleich in Excel
In Outlook sieht das dann in etwa so aus:

Option Explicit

Sub SendTask()
   Dim taskOutLook As TaskItem

   Set taskOutLook = Application.CreateItem(olTaskItem)

   With taskOutLook
      .Assign
      .Recipients.Add "me@home.de"
      .Subject = "Hallöchen..."
      .Body = "Hallo" & vbCrLf & "Bye"
      .Importance = olImportanceNormal
      .DueDate = DateSerial(2005, 12, 31)
      .StartDate = DateSerial(2005, 7, 1)
      .Status = olTaskInProgress
      .PercentComplete = 10
      .Send
   End With
   Set taskOutLook = Nothing
End Sub
Ins Excel umgesetzt in etwa so:

Option Explicit

' Benötigt im VBA einen Verweis auf M$ Outlook x.y Library

Sub SendTask()
   Dim outApp As Outlook.Application
   Dim taskOutLook As Outlook.TaskItem

   Set outApp = New Outlook.Application
   Set taskOutLook = outApp.CreateItem(olTaskItem)

   With taskOutLook
      .Assign
      .Recipients.Add "me@home.de"
      .Subject = "Hallöchen..."
      .Body = "Hallo" & vbCrLf & "Bye"
      .Importance = olImportanceNormal
      .DueDate = DateSerial(2005, 12, 31)
      .StartDate = DateSerial(2005, 7, 1)
      .Status = olTaskInProgress
      .PercentComplete = 10
      .Send
   End With
   Set taskOutLook = Nothing
   Set outApp = Nothing
End Sub
Erst wenn Du soweit bist solltest Du bei Bedarf auf "Late Binding" umstellen.
Das gibt dann vielleicht sowas, der Verweis auf die Outlook-Lib wird dann auch nicht mehr benötigt.

Option Explicit

Sub SendTask()
   Dim outApp As Object ' Outlook.Application
   Dim taskOutLook As Object ' Outlook.TaskItem

   'Set outApp = New Outlook.Application
   Set outApp = CreateObject("outlook.application")
   Set taskOutLook = outApp.CreateItem(3) ' 3 = olTaskItem

   With taskOutLook
      .Assign
      .Recipients.Add "me@home.de"
      .Subject = "Hallöchen..."
      .Body = "Hallo" & vbCrLf & "Bye"
      .Importance = 1 ' 1 = olImportanceNormal
      .DueDate = DateSerial(2005, 12, 31)
      .StartDate = DateSerial(2005, 7, 1)
      .Status = 1 ' 1 = olTaskInProgress
      .PercentComplete = 10
      .Send
   End With
   Set taskOutLook = Nothing
   Set outApp = Nothing
End Sub
HTH, Bernd

Beliebteste Forumthreads (12 Monate)

Den Status einer Aufgabe im Outlook verändern

3
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

44 Forumthreads zu ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

Den Status einer Aufgabe im Outlook verändern

3 Beiträge zum Forumthread Beiträge zu diesem Forumthread

44 Forumthreads zu ähnlichen Themen

VBA Beispiele zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

3
Beiträge zum Forumthread

Beiträge zu diesem Forumthread