variablen einen zellwert geben

Forumthread: variablen einen zellwert geben

17.08.2005 22:15:01

tina

hallo,
ich möchte der variablen const Max = ? den zellwert A1 aus dem blatt tabelle 2 zuweisen.
ich habe es so versucht:
Const MAX = Worksheet("Tabelle2").Range("A1")
das klappt aber nicht.
kann mir da jemand helfen?
danke im voraus
gruss tina

8
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Das geht nicht...

17.08.2005 22:17:47

Ramses
AW: Das geht nicht...

17.08.2005 22:24:12

tina
AW: Das geht nicht...

17.08.2005 22:41:02

Nepumuk
AW: Das geht nicht...

17.08.2005 23:07:52

Fred
AW: Das geht nicht...

17.08.2005 23:12:20

Nepumuk
AW: Das geht nicht...

17.08.2005 23:17:02

Fred
AW: Das geht nicht...

17.08.2005 23:12:23

Ramses
AW: Das geht nicht...

17.08.2005 23:10:58

Ramses

Das geht nicht...

17.08.2005 22:17:47

Ramses

Hallo
Eine Constante ist nun mal ein konstanter Wert.
Wenn du einen Zellwert zuweist, wäre dies ein variabler Wert, und das geht nicht
Const Max As Integer = 100
Das würde akzeptiert werden.
Gruss Rainer

AW: Das geht nicht...

17.08.2005 22:24:12

tina

hi rainer,
schade. ich bastel gerade ein sportquiz und habe da die const max = 190
weil 190 fragen und über zufallsprinzip wird eine der fragen gestellt.
wollte nun eine abgespeckte version ausgeben, wo die const max eben den wert der zelle haben sollte. nämlich 15. und bei freischaltung von mir, die vollen 190.
wie kann ich das am besten umsetzen?
gruss tina

AW: Das geht nicht...

17.08.2005 22:41:02

Nepumuk

Hi Tina,
lies beim öffnen der Mappe die Zelle aus. Wenn nichts drin steht setze die eine öffentliche Variable auf deinen Maximalwert, ansonsten auf den Wert der Zelle. Ich würde empfehlen den Variablennamen Max nicht zu verwenden. Das ist ein Schlüsselwort in VBA und kann zu Fehlern führen.
Gruß
Nepumuk
Excel & VBA Beispiele

AW: Das geht nicht...

17.08.2005 23:07:52

Fred

Hi,
Max ist ein Schlüsselwort? In der VBA-Hilfe ist das nicht zu finden.
mfg Fred

AW: Das geht nicht...

17.08.2005 23:12:20

Nepumuk

Hi Fred,
schau mal in den Objektkatalog. Findest du WorksheetFunction und ControlFormat.
Gruß
Nepumuk
Excel & VBA Beispiele

AW: Das geht nicht...

17.08.2005 23:17:02

Fred

Hi,
ich hatte bei Schlüsselwörtern nachgesehen, wie du geschrieben hast.
mfg Fred

AW: Das geht nicht...

17.08.2005 23:12:23

Ramses

Hallo
MAX ist eine EXCEL Funktion und als Methode des "Application.WorksheetFunction" Objectes zu finden
Gruss Rainer

AW: Das geht nicht...

17.08.2005 23:10:58

Ramses

Hallo
via VBA und die Registry liesse sich das Problem lösen
Das gehört in das Workbook_Open-Ereignis deiner Mappe
Option Explicit

Private Sub Workbook_Open()
primCheck
End Sub
... und das gehört in ein Modul
Option Explicit

Const RegAppName As String = "Sportquiz"
Const RegKeySection As String = "Einstellungen"
Const minTest As Integer = 15
Const maxTest As Integer = 190

'Deine Variable für die Anzahl der Fragen
Public countQuestion As Integer

Sub primCheck()
'Primärer Check der Einstellungen
Dim primCheckValue As Variant
primCheckValue = GetSetting(AppName:=RegAppName, section:=RegKeySection, key:="Fragen")
If primCheckValue = "" Then
    Reg_Key_setzen
End If
countQuestion = GetSetting(AppName:=RegAppName, section:=RegKeySection, key:="Fragen")
End Sub

Sub Reg_Key_setzen()
'Für den ersten Aufruf der Datei
'Dann werden die Settings in die Registry eingetragen
SaveSetting AppName:=RegAppName, section:=RegKeySection, key:="Fragen", setting:=minTest
SaveSetting AppName:=RegAppName, section:=RegKeySection, key:="Password", setting:=""
End Sub

Sub EnterLicenceCode()
'Zum freischalten der vollen Nutzungsmöglichkeit
Dim licCode As String
licCode = Application.InputBox("Bitte den Licence-Code eingeben", "Lizenz freischalten", Type:=2)
If licCode = False Then Exit Sub
If licCode <> "DeinLicenceCode" Then
    MsgBox "Falscher Lizenzcode"
    Exit Sub
End If
SaveSetting AppName:=RegAppName, section:=RegKeySection, key:="Password", setting:=licCode
SaveSetting AppName:=RegAppName, section:=RegKeySection, key:="Fragen", setting:=maxTest
End Sub

Sub Reg_Key_löschen()
'Hauptschlüssel löschen
'bei Deinstallation
DeleteSetting RegAppName
End Sub

Nun kannst du die Variable "countQuestion" verwenden.
Den Code zur Lizenzeingabe kann der Anwender dann bei Bedarf ausführen.$
Die Deinstallation der Settings falls nicht mehr gebraucht werden sollte ist ebenfalls beigefügt. Du musst sie halt dann einem Button deiner Tabelle zuordnen
Gruss Rainer

Beliebteste Forumthreads (12 Monate)

Forumthread: variablen einen zellwert geben

8 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

8
Beiträge zum Forumthread

Beiträge zu diesem Forumthread