button am bildschirm fixieren

Forumthread: button am bildschirm fixieren

25.08.2005 08:16:01

roland_k

hoi guten morgen zusammen
auf einem tabellenblatt habe ich einen commandbutton
wie kan ich erreichen dass dieser immer in der gleichen position bleibt
z. b. bildschirmmitte auch wenn ich im blatt scrolle
danke wenn mir das jemand auf anhieb sagen kann
in recherche habe nichts gefunden (
gruss roland_k

3
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: button am bildschirm fixieren

25.08.2005 08:27:26

OttoH
eine loesung aber nicht optimal

25.08.2005 09:54:24

roland_k
AW: eine loesung aber nicht optimal

25.08.2005 12:37:58

Nepumuk

AW: button am bildschirm fixieren

25.08.2005 08:27:26

OttoH

Hallo Roland,
fixiere einfach ober ein paar Zeilen und setze den Button da hinein.
Gruß OttoH

eine loesung aber nicht optimal

25.08.2005 09:54:24

roland_k

hi otto
das wäre eine loesung
ich suche ws die richtung on top oder so ähnlich
ev geht das mit ner schaltfläche statt button
hmm ich suche mal weiter
oder vielleicht weiss jemand ne weitere loesung
danke gruss roland_k

AW: eine loesung aber nicht optimal

25.08.2005 12:37:58

Nepumuk

Hi,
wie wäre es mit einer frei schwebenden Symbolleiste?
Beispiel:
' **********************************************************************
' Modul: DieseArbeitsmappe Typ: Element der Mappe(Sheet, Workbook, ...)
' **********************************************************************

Option Explicit

Private Sub Workbook_Activate()
    On Error Resume Next
    Application.CommandBars(strCommandbarName).Visible = True
    If Err.Number <> 0 Then Call prcCreate
End Sub

Private Sub Workbook_BeforeClose(Cancel As Boolean)
    With ThisWorkbook
        If Not .Saved Then
            Select Case MsgBox("Änderungen speichern?", 35, "Abfrage")
                Case 2
                    Cancel = True
                    Exit Sub
                Case 6: .Save
                Case 7: .Saved = True
            End Select
        End If
    End With
    On Error Resume Next
    Application.CommandBars(strCommandbarName).Delete
End Sub

Private Sub Workbook_Deactivate()
    On Error Resume Next
    Application.CommandBars(strCommandbarName).Visible = False
End Sub

Private Sub Workbook_Open()
    Call prcCreate
End Sub

' **********************************************************************
' Modul: Modul1 Typ: Allgemeines Modul
' **********************************************************************

Option Explicit

Public Const strCommandbarName As String = "Testleiste"

Public Sub prcCreate()
    Dim MyBar As CommandBar, MyButton As CommandBarButton
    On Error Resume Next
    Application.CommandBars(strCommandbarName).Delete
    On Error GoTo 0
    Set MyBar = Application.CommandBars.Add(Name:=strCommandbarName, _
        Position:=msoBarFloating, Temporary:=True)
    Set MyButton = MyBar.Controls.Add(Type:=msoControlButton)
    With MyButton
        .Caption = "Testname"
        .FaceId = 59
        .OnAction = "prcTest"
        .Style = msoButtonIconAndCaption
        .TooltipText = "Bitte, bitte klick mich!"
    End With
    With MyBar
        .Left = 450
        .Top = 150
        .Visible = True
        .Protection = msoBarNoMove + msoBarNoCustomize + _
            msoBarNoResize + msoBarNoChangeVisible + msoBarNoChangeDock
    End With
End Sub

Private Sub prcTest()
    MsgBox "Dein Makro"
End Sub

Gruß
Nepumuk
Excel & VBA Beispiele

Beliebteste Forumthreads (12 Monate)

Forumthread: button am bildschirm fixieren

3 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

3
Beiträge zum Forumthread

Beiträge zu diesem Forumthread