Excel Grafik nach Ppt exportieren

Forumthread: Excel Grafik nach Ppt exportieren

26.10.2005 21:56:01

Tinu

Liebe VBA-Könner
Ich habe eine Excel Datei, mit der ich per Button eine Grafik aktualisiere. Nun möchte ich, ebenfalls per Button, die jeweilige Grafik als Picture in eine PowerPoint Datei exportieren. Diese Ppt Datei liegt als Template im selben Verzeichnis. Für jede Grafik soll ein neues Blatt generiert werden. Damit die Template nicht überschrieben wird, soll die Ppt Datei gleich beim Aufruf mit neuem Namen (z.B. mit Datums-Anhänsel) gespeichert werden.
Kann mir hier jemand weiterhelfen? Ich wäre sehr dankbar dafür!
Grüsse aus der Schweiz
Tinu

2
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Excel Grafik nach Ppt exportieren

27.10.2005 13:17:26

Galenzo
AW: Excel Grafik nach Ppt exportieren

27.10.2005 15:11:27

Tinu

AW: Excel Grafik nach Ppt exportieren

27.10.2005 13:17:26

Galenzo

Hallo,
ich benutze dieses Makro, um alle Diagramme einer Excel-Tabellenseite in eine geöffnete (!) PPT zu exportieren und dort als Bild einzufügen. Ich habe mir dafür auch gleich einen eigenen Button in die Symbolleiste gelegt.


Sub ChartsAndTitlesToPresentation()
' Set a VBE reference to Microsoft PowerPoint Object Library
Dim pptApp As PowerPoint.Application
Dim pptPresentation As PowerPoint.Presentation
Dim pptSlide As PowerPoint.Slide
Dim varPresentationFileName As Variant
Dim lngSlideCount As Long
Dim intChartCounter As Integer
Dim strChartTitle As String
' Reference existing instance of PowerPoint
On Error GoTo Fehler
Set pptApp = GetObject(, "Powerpoint.Application")
' Reference active presentation
Set pptPresentation = pptApp.ActivePresentation
pptApp.ActiveWindow.ViewType = ppViewSlide
For intChartCounter = 1 To ActiveSheet.ChartObjects.Count
With ActiveSheet.ChartObjects(intChartCounter).Chart
' get chart title
If .HasTitle Then
strChartTitle = .ChartTitle.Text
Else
strChartTitle = ""
End If
' copy chart as a picture
.CopyPicture Appearance:=xlScreen, Size:=xlScreen, Format:=xlPicture
End With
' Add a new slide and paste in the chart
lngSlideCount = pptPresentation.Slides.Count
Set pptSlide = pptPresentation.Slides.Add(lngSlideCount + 1, ppLayoutTitleOnly)
pptApp.ActiveWindow.View.GotoSlide pptSlide.SlideIndex
With pptSlide
' paste and select the chart picture
.Shapes.Paste.Select
' align the chart
pptApp.ActiveWindow.Selection.ShapeRange.Align msoAlignCenters, True
pptApp.ActiveWindow.Selection.ShapeRange.Align msoAlignMiddles, True
.Shapes.Placeholders(1).TextFrame.TextRange.Text = strChartTitle
End With
Next
' Clean up
Set pptSlide = Nothing
Set pptPresentation = Nothing
Set pptApp = Nothing
Exit Sub
Fehler:
MsgBox "keine geöffnete PPT-Instanz gefunden. Abbruch"
End Sub

Viel Erfolg!

AW: Excel Grafik nach Ppt exportieren

27.10.2005 15:11:27

Tinu

Hi Galenzo
Dein Code ist super!! Hat eine Weile gedauert, bis ichrausgefunden habe, was es mit der Object Library auf sich hat, aber jetzt läuft alles wie gewünscht.
Vielen Dank :))))
Gruss
Tinu

Beliebteste Forumthreads (12 Monate)

Excel Grafik nach Ppt exportieren

Forumthread: Excel Grafik nach Ppt exportieren

2 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

2
Beiträge zum Forumthread

Beiträge zu diesem Forumthread