Sheetwechsel mit Scrolldown-Menü

Hallo ihr Lieben!
Ich sitze hier vor einer Aufgabe fürs Studium, die ich leider nicht gelöst bekomme.
Aber vielleicht könnt ihr mir ja helfen.
Es handelt sich um eine Exceldatei mit mehreren Sheets. Auf den einzelnen Sheets sind Daten von Fahrzeugen hinterlegt. Die Bezeichnung des Fahrzeugs befindet sich auf jedem Sheet in Zelle B3.
Nun soll sich auf dem ersten Sheet ein Scrolldown-Menu befinden, welches mir die ganzen Fahrzeugbezeichnungen auflistet. Durch klicken auf die gewünschte Bezeichnung soll Excel nun automatisch zum gewünschten Sheet springen.
Alleine das bekomme ich schon nicht gelöst.
Nun kommt aber noch hinzu, das manche Fahrzeuge mehrfach vorhanden sind. Wie könnte man das zusätzlich lösen?
Vielleicht durch ein zweites Scrolldown-Menu welches die mehrfach vorhandenen Fahrzeuge nochmals in Nummern unterteilt!? Diese Nummer gibt es nämlich auch auf jedem Sheet in Zelle B5 und die sind nie doppelt. (Es soll aber auf jeden Fall zuerst nach der Bezeichnung gesucht werden können)
Ich habe leider keine Ahnung wie ich das hinbekommen soll. Nehme mal an, das dazu viel Basic Wissen erforderlich ist!? Naja, damit kenne ich mich nur leider nicht so gut aus.
Ich wäre euch sehr dankbar, wenn ihr mir bei meinem Problem helfen könntet.
Viele Dank!!
Liebe Grüße,
Moni

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Private Sub Workbook_Open() Dim sh As Worksheet Dim Cb As ComboBox Dim i As Integer Set Cb = Sheets(1).ComboBox1 Cb.Clear For i = 2 To Sheets.Count Cb.AddItem Sheets(i).Name & " " & Sheets(i).Range("B3") Next i End Sub

Hallo Moni,
ok mal sehen:
In "DieseArbeitsmappe":


Private Sub Workbook_Open()
Dim sh As Worksheet
Dim cB As ComboBox
Dim i As Integer
Set cB = Sheets(1).ComboBox1
cB.Clear
For i = 2 To Sheets.Count
ZuListe cB, Sheets(i).Range("B3")
Next i
End Sub

Ins Tabellenblattmodul: 2 Comboboxen (ComboBox1, ComboBox2)
und dieser Code:


Private Sub ComboBox1_Change()
Dim i As Integer
If HatPunkte(ComboBox1.Value) Then
With ComboBox2
.Visible = True
.Clear
For i = 2 To Sheets.Count
If Sheets(i).Range("B3").Value = OhnePunkte(ComboBox1.Value) Then
.AddItem Sheets(i).Range("B5")
End If
Next i
End With
Else
ComboBox2.Visible = False
For i = 2 To Sheets.Count
If Sheets(i).Range("B3") = ComboBox1.Value Then
Sheets(i).Activate
Exit Sub
End If
Next i
End If
End Sub
Private Sub ComboBox2_Change()
Dim i As Integer
For i = 2 To Sheets.Count
If Sheets(i).Range("B3").Value = OhnePunkte(ComboBox1.Value) And _
Sheets(i).Range("B5").Value = ComboBox2.Value Then
Sheets(i).Activate
Exit Sub
End If
Next i
End Sub

In eine Standardmaodul (z.B. Modul1):


Public Const ZMehr = " ->" 'Zeichen für mehrfache Treffer
Sub ZuListe(cB As ComboBox, wert As String)
Dim SchonDa As Integer
Dim ListenWert As String
Dim i As Integer, lc As Integer
lc = cB.ListCount - 1
SchonDa = -1
For i = 0 To lc
ListenWert = OhnePunkte(cB.List(i))
If ListenWert = wert Then
SchonDa = i
Exit For
End If
Next i
If SchonDa >= 0 Then
Debug.Print cB.List(SchonDa),
cB.List(SchonDa) = OhnePunkte(cB.List(SchonDa)) & ZMehr
Debug.Print cB.List(SchonDa)
Else
cB.AddItem wert
End If
End Sub
Function OhnePunkte(ByVal wert As String) As String
On Error GoTo errhandler
If Right(wert, Len(ZMehr)) = ZMehr Then
OhnePunkte = Left(wert, Len(wert) - Len(ZMehr))
Exit Function
End If
errhandler:
OhnePunkte = wert
End Function
Function HatPunkte(wert As String)
HatPunkte = Right(wert, Len(ZMehr)) = ZMehr
End Function
Sub AddPunkte(ByRef wert)
If Not HatPunkte(wert) Then wert = wert & ZMehr
End Sub

Viel Erfolg,
Matthias

Beliebteste Forumthreads (12 Monate)

Sheetwechsel mit Scrolldown-Menü

21
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

Sheetwechsel mit Scrolldown-Menü

21 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

21
Beiträge zum Forumthread

Beiträge zu diesem Forumthread