Datei schon offen

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Private Sub Workbook_Open() Dim wb As Workbook 'Schleife: alle geöffneten Mappen For Each wb In Application.Workbooks 'Diese Mappe aus der Prüfung ausnehmen If wb.Name <> ThisWorkbook.Name Then 'Prüfung jeder Mappe auf "Verboten" in Blatt1, A1 If wb.Sheets(1).Range("A1") = "Verboten" Then 'Strg+Pause deaktivieren Application.EnableCancelKey = xlDisabled MsgBox "Es ist bereits eine Mappe mit ... geöffnet!" & vbLf & _ "Die Mappe wird geschlossen!", vbExclamation, "FEHLER" Application.EnableCancelKey = xlInterrupt ThisWorkbook.Close False End If End If Next wb End Sub

Hallo Erich!
Der Code von Mathias prüft aber nur ob die Datei in der selben Excelinstanz geöffnet ist!
Eine andere Möglichkeit wäre so.

' **********************************************************************
' Modul: Modul1 Typ: Allgemeines Modul
' **********************************************************************

Option Explicit

Public Enum XL_FILESTATUS
  XL_UNDEFINED = -1
  XL_CLOSED
  XL_OPEN
  XL_DONTEXIST
End Enum

Public Function FileStatus(xlFile As String) As XL_FILESTATUS

On Error Resume Next

Dim File%: File = FreeFile

Err.Clear

Open xlFile For Binary Access Read Lock Read As #File
Close #File

Select Case Err.Number
  Case 0: FileStatus = XL_CLOSED
  Case 70: FileStatus = XL_OPEN
  Case 76: FileStatus = XL_DONTEXIST
  Case Else: FileStatus = XL_UNDEFINED
End Select

End Function

'Die ersten beiden Dateien werden immer mit dem Datum des aktuellen Tages gespeichert.
'Die andere ändert sich Mitte des Monats zu " 16.07_31.07_Fremde.xls

Sub test()
Dim result As Long
Dim strFile As String, strPath As String

strPath = "F:\Temp" 'Pfad auf dem die Dateien liegen ' anpassen

If Right(strPath, 1) <> "\" Then strPath = strPath & "\"

'TT.MM.JJJJ.xls
strFile = Format(Date, "dd.mm.yyyy") & ".xls"

result = FileStatus(strPath & strFile)

If result = 1 Then MsgBox strFile & " ist geöffnet!"

'TT.MM.JJJJ Reserve.xls
strFile = Format(Date, "dd.mm.yyyy") & " Reserve.xls"

result = FileStatus(strPath & strFile)

If result = 1 Then MsgBox strFile & " ist geöffnet!"

'TT.MM_TT.MM_Fremde.xls
If Day(Date) <= 15 Then
  strFile = "01." & Format(Date, "mm") & "_15." & Format(Date, "mm") & "_Fremde.xls"
Else
  strFile = "16." & Format(Date, "mm_") & Day(DateSerial(Year(Date), Month(Date) + 1, 0)) & _
    Format(Date, "\.mm") & "_Fremde.xls"
End If

result = FileStatus(strPath & strFile)

If result = 1 Then MsgBox strFile & " ist geöffnet!"

End Sub

Gruß Sepp

Beliebteste Forumthreads (12 Monate)

12 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

12
Beiträge zum Forumthread

Beiträge zu diesem Forumthread