Spalten ausblenden

• Spalten ausblenden von Bernd vom 15.12.2006 23:34:13
• AW: Spalten ausblenden - von Kurt Isane am 16.12.2006 00:02:43
• AW: Spalten ausblenden - von Uduuh am 16.12.2006 00:06:11
• AW: Spalten ausblenden - von Erich G. am 16.12.2006 00:10:46
• ok (m.T.) - von Bernd am 16.12.2006 00:23:44

Betrifft: Spalten ausblenden
von: Bernd

Geschrieben am: 15.12.2006 23:34:13
Hallo zur späten Stunde,
ich habe zum Spalten ausblenden folgendes Konstrukt angefangen...

Sub ausbl2()
Dim i
Application.ScreenUpdating = False
For i = 2 To 187
With Worksheets("Jan 07")
If .Columns(i).Hidden = False Then .Columns(i).Hidden = True
End With
Next i
Application.ScreenUpdating = True
End Sub

ok..nun sind alle Spalten ab B bis GF ausgeblendet.
Ich möchte aber, dass jede 5. Spalte, beginnend ab B, nicht ausgeblendet wird, bzw. wenn sie es aktuell ist, eingeblendet wird.
Also ein Bastelansatz..

Sub ausbl()
Dim i
Dim x
For i = 2 To 182 Step 5
For x = 1 To 5
Worksheets("Jan 07").Columns(x + i).Hidden = True
Next x
Next i
End Sub

...und ich bastel mir auch noch einen Wolf wenns sein muß, aber ich bekomme diesen blöden "Hüpfer über jede 5. Spalte" einfach nicht hin.
Bis mein Logigzentrum wieder im Dienst ist, hat evtl. vorher jemand hier ein nachsehen ;-)
Bernd

Betrifft: AW: Spalten ausblenden
von: Kurt Isane

Geschrieben am: 16.12.2006 00:02:43
Option Explicit

Sub ausbl2()
Dim i As Integer
Application.ScreenUpdating = False
For i = 2 To 187
With Worksheets("Jan 07")
.Columns(i).Hidden = True
If i Mod 5 = 0 Then .Columns(i).Hidden = False
End With
Next
Application.ScreenUpdating = True
End Sub

mfg Kurt

Betrifft: AW: Spalten ausblenden
von: Uduuh

Geschrieben am: 16.12.2006 00:06:11
Hallo,
etwa so:

Sub ausblenden()
Dim i
Application.ScreenUpdating = False
For i = 2 To 187
With Worksheets("Jan 07")
.Columns(i).Hidden = (i - 2) Mod 5 <> 0
End With
Next i
Application.ScreenUpdating = True
End Sub

Gruß aus’m Pott
Udo


Betrifft: AW: Spalten ausblenden
von: Erich G.

Geschrieben am: 16.12.2006 00:10:46
Hallo Bernd,
oder so, mit nur einem Schleifchen:

Sub ausbl5()
Dim i As Integer
With Worksheets("Jan 07")
For i = 2 To 182 Step 5
.Columns(i).Hidden = False
Range(.Columns(i + 1), .Columns(i + 4)).Hidden = True
Next i
End With
End Sub

Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort

Betrifft: ok (m.T.)
von: Bernd

Geschrieben am: 16.12.2006 00:23:44
Hallo ihr Nachtschwärmer,
herzlichen Dank an Euch für die Hilfe zur späten Stunde.
Alles klasse, aber die Lösung aus dem Pott
Hidden = (i - 2) Mod 5 <> 0
finde ich am genialsten ;-)
Gruß, Bernd

Excel-Beispiele zum Thema "Spalten ausblenden"
Vorkommen von Zahlenreihen in Spalten	Funktion ANZAHL2 ohne ausgeblendete Spalten
Spaltenbreite anpassen	Spalten einer Mehrbereichsauswahl ausblenden.
Spaltennamen bestimmen	Spalten/Zeilen aus- und einblenden
Zeilen und Spalten über ein Drehfeld ein- und ausblenden	In einem Dialog ausgewählte Spalten drucken
Spalten bedingt summieren und Zellen formatieren	Abfrage der markierten Spalten