Live-Forum - Die aktuellen Beiträge
Anzeige
Archiv - Navigation
924to928
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
924to928
924to928
Aktuelles Verzeichnis
Verzeichnis Index
Verzeichnis Index
Übersicht Verzeichnisse
Inhaltsverzeichnis

mehrere Spalten per Schleife auswählen

mehrere Spalten per Schleife auswählen
12.11.2007 15:35:06
Jörg
Hallo,
ich habe folgendes Problem.
In einer Tabelle (die jedesmal anders aussieht) gibt es immer Spalten mit der gleichen Überschrift.
Ich möchte nun bestimme Spalten in eine neues Arbeitsblatt kopieren.
Dazu habe ich eine Funktion, die mir die Spalte mit einer bestimmten Spaltenüberschrift ermittelt (Spalte wird als Buchstabe zurückgegeben).
Ich kann also mittels

For Each Spalte In Array("Nummer", "Auflage", "Rechnung")
ls = SucheSpalte(Spalte)
Next


für jede meiner Wunsch-Spalten die Spalte ermitteln. Nun möchte ich diese alle auf einmal auswählen und kopieren. Und genau da weiß ich nicht weiter. Ich kann zwar mit Range("$" & ls & ":$" & ls).select in der Schleife die jeweilige Spalte auswählen aber nicht zu einer Auswahl hinzufügen.
Ich hoffe meine Frage ist verständlich.
Vielen Dank
Jörg

3
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: mehrere Spalten per Schleife auswählen
12.11.2007 16:14:00
Josef
Hallo Jörg,
meinst du so?
Sub SpaltenSuchen()
Dim vCol As Variant
Dim rng As Range, rngU As Range
Dim intI As Integer


vCol = Array("Nummer", "Auflage", "Rechnung")


For intI = 0 To UBound(vCol)
    Set rng = Rows(1).Find(What:=vCol(intI), LookAt:=xlWhole)
    
    If Not rng Is Nothing Then
        If rngU Is Nothing Then
            Set rngU = rng.EntireColumn
        Else
            Set rngU = Union(rngU, rng.EntireColumn)
        End If
    End If
Next


If Not rngU Is Nothing Then
    rngU.Copy Workbooks.Add(xlWBATWorksheet).Sheets(1).Range("A1")
End If

End Sub

Gruß Sepp

Anzeige
AW: mehrere Spalten per Schleife auswählen
12.11.2007 16:44:13
Jörg
Hallo Sepp,
ich verstehe zwar noch nicht alles, aber das macht genau das was ich brauche :-)
Super vielen Dank. Ich fange gerade erst mit VBA an. Gibt es ein gutes Buch mit der kompletten VBA Referenz, wo so etwas wie "xlWBATWorksheet" auch erklärt ist.
Sehe ich das richtig, dass

Set rngU = Union(rngU, rng.EntireColumn)


die vorhandene Range rngU jeweils mit rng.EntireColumn erweitert?
Nochmals Danke
Jörg

AW: mehrere Spalten per Schleife auswählen
12.11.2007 16:47:00
Josef
Hallo Jörg,
Buch kann ich keines empfehlen, Das Forum, Google und Interesse sind die besten Lehrmeister.
Sehe ich das richtig, dass
Set rngU = Union(rngU, rng.EntireColumn)
die vorhandene Range rngU jeweils mit rng.EntireColumn erweitert?
>
Ja!
Gruß Sepp

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige