Live-Forum - Die aktuellen Beiträge
Datum
Titel
28.03.2024 21:12:36
28.03.2024 18:31:49
Anzeige
Archiv - Navigation
984to988
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
984to988
984to988
Aktuelles Verzeichnis
Verzeichnis Index
Verzeichnis Index
Übersicht Verzeichnisse
Inhaltsverzeichnis

Makkro-Neuling braucht Hilfe

Makkro-Neuling braucht Hilfe
12.06.2008 15:12:00
Tom
Hallo,
ich brauch dringend Hilfe bei der Programmierung von Makkros!
Folgendes Problem:
Es existieren 2 Excel-Files (File A und File B) welche in unterschiedlichen Ordnern abgespeichert sind. In File A gibt es ein Tabellenblatt in dem Informationen eingegeben werden sollen. Z.B. Datum, Bearbeiter, Kunde, Projektnummer. File B ist ein Template. Nachdem in File A die Daten eingegeben wurden, soll ein Makkro eine Kopie von File B erstellen, in dieser Kopie die zuvor eingetragenen Daten an bestimmten Stellen einfuegen und im Anschluss daran die Kopie von File B unter einem Bestimmten Namen, der sich aus Projektname und Datum zusammensetzt wieder im Ordner abspeichern.
Danke im Voraus!!
Gruss
Tom

28
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: Makkro-Neuling braucht Hilfe
12.06.2008 16:07:13
fcs
Hallo Tom,
hier ein Makro, das du in der Datei A in ein allgemeines Modul kopieren muss,
Pfad und Namen des Templates, sowie die Zeilen und Spalten in den Cells(Zeile,Spalte) Befehlen muss du an deine Dateien anpassen.
Gruß
Franz

Sub DatenNachTemplate()
Dim wbThis As Workbook, wbZiel As Workbook
Dim wksThis As Worksheet, wksZiel As Worksheet
Dim strPfad As String, strProjekt As String, strDatum As String
Set wbThis = ThisWorkbook 'Datei A
Set wksThis = wbThis.Worksheets("Tabelle1") 'Tabellenblatt mit den Eingabedaten
Set wbZiel = Workbooks.Add(Template:="C:\Lokale Daten\lokaleVorlagen\DateiB.xlt")
Set wksZiel = wbZiel.Worksheets(1) 'Tabellenblatt in das Daten eingetragen werden.
'Daten übertragen
wksZiel.Cells(2, 2).Value = wksThis.Cells(2, 1).Value ' A2 --> B2 Datum
wksZiel.Cells(3, 2).Value = wksThis.Cells(2, 2).Value ' B2 --> B3 Projekt
wksZiel.Cells(6, 5).Value = wksThis.Cells(2, 3).Value ' C2 --> E6
'u.s.w.
'Dateinamen generieren und Datei speichern
strPfad = wbThis.Path 'Gleiches Verzeichnis Datei A
strProjekt = wksZiel.Cells(3, 2).Value
strDatum = "_" & Format(wksZiel.Cells(2, 2).Value, "YYYYMMDD")
wbZiel.SaveAs Filename:=strPfad & "\" & strProjekt & strDatum & ".xls"
'datei schliessen
wbZiel.Close
End Sub


Anzeige
AW: Makkro-Neuling braucht Hilfe
12.06.2008 20:06:51
Tom
Hey Franz, vielen Dank!
ich hab's jetzt mal probiert..aber funktioniert nich tso richtig.. kannst du nochmal drueber schaun woran das liegen koennte. nur zur info, bin grad in usa und das excel hier ist auf englisch..vielleicht liegts daran?

Sub DatenNachTemplate()
Dim wbThis As Workbook, wbZiel As Workbook
Dim wksThis As Worksheet, wksZiel As Worksheet
Dim strPfad As String, strProjekt As String, strDatum As String
Set wbThis = ThisWorkbook 'Datei A
Set wksThis = wbThis.Worksheets("Input new Quote")
Set wbZiel = Workbooks.Open("C:\Documents and Settings\herbtf\My Documents\Test\Qute Folder\ _
Test_Template.xls")
Set wksZiel = wbZiel.Worksheets("2.1. R&O LoAa") 'Tabellenblatt in das Daten eingetragen  _
werden.
'Daten übertragen
wksZiel.Cells(10, D).Value = wksThis.Cells(5, B).Value
wksZiel.Cells(3, D).Value = wksThis.Cells(4, B).Value ' B2 --> B3 Projekt
wksZiel.Cells(6, 5).Value = wksThis.Cells(2, 3).Value ' C2 --> E6
'u.s.w.
'Dateinamen generieren und Datei speichern
strPfad = ("C:\Documents and Settings\herbtf\My Documents\Test\Qute Folder\") 'Gleiches  _
Verzeichnis Datei B
strProjekt = wksZiel.Cells(D3).Value
strDatum = "_" & Format(wksZiel.Cells(D10).Value, "YYYYMMDD")
wbZiel.SaveAs Filename:=strPfad & "\" & strProjekt & strDatum & ".xls"
'datei schliessen
wbZiel.Close
End Sub


Anzeige
AW: Makkro-Neuling braucht Hilfe
12.06.2008 20:34:00
Franc
Hauptgrund ist die falsche Angabe der Spaltennummer bei cells
Wenn du nur A schreibst, dann denkt er das der Wert in Variable A steht aber du hast keine Variable A.
Setz die Spaltenangaben in Anführungszeichen oder gib die Spaltennr. an (A = 1, B 0 2 etc)
Also
wksZiel.Cells(10, "D").Value = wksThis.Cells(5, "B").Value
wksZiel.Cells(3, "D").Value = wksThis.Cells(4, "B").Value
strProjekt = wksZiel.Cells(D3).Value
strDatum = "_" & Format(wksZiel.Cells(D10).Value, "YYYYMMDD")
cells(D3) oder Cells(D10) verstößt gegen die Syntax
Cells(Zeile, Spalte)
2 Möglichkeiten
strProjekt = wksZiel.Cells(3, "D").Value
strDatum = "_" & Format(wksZiel.Cells(10, "D").Value, "YYYYMMDD")
oder
strProjekt = wksZiel.Range("D3").Value
strDatum = "_" & Format(wksZiel.Range("D10").Value, "YYYYMMDD")

Anzeige
AW: Makkro-Neuling braucht Hilfe
12.06.2008 21:37:00
Tom
Ok, jetzt bin ich schon ein ganzes stueck weiter gekommen! Aber das mit dem Datum funktioniert noch nicht und ich moechte dass die neue datei im selben ordner wie das template abgespeichert wird. er speichert mir das aber ganz wo anders hin..keine ahnung warum :/

Sub DatenNachTemplate()
Dim wbThis As Workbook, wbZiel As Workbook
Dim wksThis As Worksheet, wksZiel As Worksheet
Dim strPfad As String, strProjekt As String, strDatum As String
Set wbThis = ThisWorkbook 'Datei A
Set wksThis = wbThis.Worksheets("Input new Quote")
Set wbZiel = Workbooks.Add(Template:="C:\Documents and Settings\herbtf\My Documents\Test\Qute  _
Folder\Test_Template")
Set wksZiel = wbZiel.Worksheets("2.1. R&O LoAa") 'Tabellenblatt in das Daten eingetragen  _
werden.
'Daten übertragen
wksZiel.Cells(10, 4).Value = wksThis.Cells(5, 2).Value ' Datum
wksZiel.Cells(3, 4).Value = wksThis.Cells(4, 2).Value 'Projekt name
wksZiel.Cells(4, 4).Value = wksThis.Cells(6, 2).Value 'Qutote nummer
wksZiel.Cells(6, 4).Value = wksThis.Cells(9, 2).Value 'End Customer
wksZiel.Cells(7, 4).Value = wksThis.Cells(7, 2).Value 'Distributor
'Dateinamen generieren und Datei speichern
strPfad = wbZiel.Path = "C:\Documents and Settings\herbtf\My Documents\Test\Qute Folder\ ' _
Gleiches Verzeichnis Datei B"
strProjekt = wksZiel.Cells(3, 4).Value
strQuotenr = wksZiel.Cells(4, 4).Value
strDatum = "_" & Format(wksZiel.Cells(10, "D").Value, "YYYYMMDD")
wbZiel.SaveAs Filename:=strQuotenr & "_" & strProjekt & "_" & strDatum & ".xls"
'datei schliessen
wbZiel.Close
End Sub


VIELEN DANK FUER DEINE HILFE!!!

Anzeige
AW: Makkro-Neuling braucht Hilfe
12.06.2008 22:01:00
Franc
gar nicht aufgefallen ^^
Wenn du willst, das für heute anstatt
strDatum = "_" & Format(wksZiel.Cells(10, "D").Value, "YYYYMMDD")
=
20080612
steht, dann mußt du "." dazwischen setzen.
Also zum Beispiel
strDatum = "_" & Format(wksZiel.Cells(10, "D").Value, "YYYY.MM.DD")
=
2008.06.12
yy = Jahr (8 für 2008 oder 10 für 2010)
yyyy = Jahr (2008, 2009 etc)
MM = Monat(01, 02, 03 etc)
MMM = Monat (Jan, Feb etc)
MMMM = Monat (Januar, Februar etc)
DD = Tag(1, 2 ,3 etc.)
DDD = Tag(Mo,Di etc)
DDDD = Tag(Montag, Dienstag etc)

Anzeige
AW: Datum im Dateinamen, Cells(1,"A")
12.06.2008 23:22:00
fcs
Hallo franc und tim,
ich kann nur dringend davon abraten, das Datum mit Punkten im Deutschen oder auch US-Format in den Dateinamen einzubauen. Bestimmte Dateisuchfunktionen (z,B Dir) haben unter Umständen Schwierigkeiten beim Suchen nach solchen Dateinamen die mehr Punkte enthalten als den einen vor der Datei-Namenserweiterung. Außerdem sind Dateinamen mit dem Datum in der Schreibweise YYYYMMDD oder auch in der international standardisierten Schreibweise YYYY-MM-DD vernünftig sortierbar.
2. kleine Totsünde: Angabe der Spalte in Cells(Zeile,Spalte) mit dem Buchstaben. Better don't do that!
Der VBA-Compiler scheint es in den meisten Excel-Versionen zu schlucken, aber ich hatte auch schon Probleme damit.
Wenn man einelne Zellen nicht mit der Cells-Eigenschaft ansprechen möchte, dann besser mit Range arbeiten.
Range("A1") entspricht Cells(1,1)
Gruß
Franz

Anzeige
AW: Datum im Dateinamen, Cells(1,"A")
13.06.2008 01:13:59
Franc
@ fcs
danke für den Tip
man lernt nie aus ;-)

AW: Makkro-Neuling braucht Hilfe
12.06.2008 22:40:00
Franc
gleich mehrere Fehler
Set wbZiel = Workbooks.Add(Template:="C:\Documents and Settings\herbtf\My Documents\Test\Qute _
Folder\Test_Template")
sollte eine Fehlermeldung ergeben
du mußt da den Dateinamen angeben also Dateiname.xls
strPfad = wbZiel.Path = "C:\Documents and Settings\herbtf\My Documents\Test\Qute Folder\ ' Gleiches Verzeichnis Datei B"
macht keinen Sinn und wird immer "Falsch ergeben"
Ich gehe mal von aus, das die Variable strPfad "C:\Documents and Settings\herbtf\My Documents\Test\Qute Folder\" heißen soll
Tip: Wenn du Kommentare setzt, dann achte darauf das es wirklich Kommentare sind. ^^
Bei obiger Zeile ist dein KOmmentar Bestandteil vom Pfad geworden. (wegen den fehlenden " nach dem Pfadende. Die kommen erst nach deinem Kommentar und deshalb denkt excel das die gesamte Zeile dein Pfad ist.
Weiterhin hast du wbZiel.SaveAs Filename:=strQuotenr & "_" & strProjekt & "_" & strDatum & ".xls"
nirgends den Zielpfad (strPfad) angegeben
PS: Heißt der Ordner wirklich "Qute Folder" oder doch eher "Quote Folder" ?
beiletzterem Fall pass das bei den 2 x im makro an
Ich vermute das es so funktionieren sollte.
Den Dateinamen bei "wbZiel" mußt du manuell anpassen

Sub DatenNachTemplate()
Dim wbThis As Workbook, wbZiel As Workbook
Dim wksThis As Worksheet, wksZiel As Worksheet
Dim strPfad As String, strProjekt As String, strDatum As String
Set wbThis = ThisWorkbook 'Datei A
Set wksThis = wbThis.Worksheets("Input new Quote")
Set wbZiel = Workbooks.Add(Template:="C:\Documents and Settings\herbtf\My Documents\Test\ _
Qute Folder\Test_Template")
Set wksZiel = wbZiel.Worksheets("2.1. R&O LoAa") 'Tabellenblatt in das Daten eingetragen  _
werden.
'Daten übertragen
wksZiel.Cells(10, 4).Value = wksThis.Cells(5, 2).Value ' Datum
wksZiel.Cells(3, 4).Value = wksThis.Cells(4, 2).Value 'Projekt name
wksZiel.Cells(4, 4).Value = wksThis.Cells(6, 2).Value 'Qutote nummer
wksZiel.Cells(6, 4).Value = wksThis.Cells(9, 2).Value 'End Customer
wksZiel.Cells(7, 4).Value = wksThis.Cells(7, 2).Value 'Distributor
'Dateinamen generieren und Datei speichern
strPfad = "C:\Documents and Settings\herbtf\My Documents\Test\Qute Folder\" ' Gleiches  _
Verzeichnis Datei B
strProjekt = wksZiel.Cells(3, 4).Value
strQuotenr = wksZiel.Cells(4, 4).Value
strDatum = "_" & Format(wksZiel.Cells(10, "D").Value, "YYYY.MM.DD")
wbZiel.SaveAs Filename:=strPfad & strQuotenr & "_" & strProjekt & "_" & strDatum & ".xls"
'datei schliessen
wbZiel.Close
End Sub


Anzeige
AW: Makkro-Neuling braucht Hilfe
13.06.2008 15:11:00
Thomas
Super! Jetzt funktioniert nahezu alles! File wird geoeffnet, die Daten reinkopiert, und die datei mit gewuenschten dateinamen abgespeichert. aber leider nicht im richtigen ordner.
Mein code sieht jezty folgendermassen aus:

Sub DatenNachTemplate()
Dim wbThis As Workbook, wbZiel As Workbook
Dim wksThis As Worksheet, wksZiel As Worksheet
Dim strPfad As String, strProjekt As String, strDatum As String
Set wbThis = ThisWorkbook 'Datei A
Set wksThis = wbThis.Worksheets("Input new Quote")
Set wbZiel = Workbooks.Add(Template:="C:\Documents and Settings\herbtf\My Documents\Test\Qute  _
Folder\Test_Template")
Set wksZiel = wbZiel.Worksheets("2.1. R&O LoAa") 'Tabellenblatt in das Daten eingetragen  _
werden.
'Daten übertragen
wksZiel.Cells(10, 4).Value = wksThis.Cells(5, 2).Value 'Datum
wksZiel.Cells(3, 4).Value = wksThis.Cells(4, 2).Value 'Projekt name
wksZiel.Cells(4, 4).Value = wksThis.Cells(6, 2).Value 'Qutote nummer
wksZiel.Cells(6, 4).Value = wksThis.Cells(9, 2).Value 'End Customer
wksZiel.Cells(7, 4).Value = wksThis.Cells(7, 2).Value 'Distributor
'Dateinamen generieren und Datei speichern
strPfad = wbZiel.Path = "C:\Documents and Settings\herbtf\My Documents\Test\Quote Folder\" ' _
Gleiches Verzeichnis Datei B
strFilename = wksThis.Cells(11, 2).Value
wbZiel.SaveAs Filename:=strFilename & ".xls"
'datei schliessen
wbZiel.Close
End Sub


wenn ich das richtig seh steht doch ganz klar
strPfad = wbZiel.Path = "C:\Documents and Settings\herbtf\My Documents\Test\Quote Folder\
die datei wird aber immer unter C:\Documents and Settings\herbtf\My Documents\ abegespeichert. wie kann das sein?
gruss
tom

Anzeige
AW: Makkro-Neuling braucht Hilfe
13.06.2008 15:44:00
fcs
Hallo Tom,
probier es mal so. der Filename für SaveAs muss Pfad und Dateianme beinhalten, sonst wird im aktuellen bzw. Standard-Dokumentverzeichnis gespeichert. Da du den Pfad ja auch für das Template brauchst, kannst du den Pfad auch schon zu Beginn des makros festlegen.

Sub DatenNachTemplate()
Dim wbThis As Workbook, wbZiel As Workbook
Dim wksThis As Worksheet, wksZiel As Worksheet
Dim strPfad As String, strProjekt As String, strDatum As String
Set wbThis = ThisWorkbook 'Datei A
Set wksThis = wbThis.Worksheets("Input new Quote")
'Verzeichnis für Template und Datei mit Daten
strPfad = "C:\Documents and Settings\herbtf\My Documents\Test\Qute Folder\"
Set wbZiel = Workbooks.Add(Template:=strPfad & "Test_Template")
Set wksZiel = wbZiel.Worksheets("2.1. R&O LoAa") 'Tabellenblatt in das Daten _
eingetragen werden.
'Daten übertragen
wksZiel.Cells(10, 4).Value = wksThis.Cells(5, 2).Value 'Datum
wksZiel.Cells(3, 4).Value = wksThis.Cells(4, 2).Value 'Projekt name
wksZiel.Cells(4, 4).Value = wksThis.Cells(6, 2).Value 'Qutote nummer
wksZiel.Cells(6, 4).Value = wksThis.Cells(9, 2).Value 'End Customer
wksZiel.Cells(7, 4).Value = wksThis.Cells(7, 2).Value 'Distributor
'Dateinamen generieren und Datei speichern
strFilename = wksThis.Cells(11, 2).Value
wbZiel.SaveAs Filename:=strPfad & strFilename & ".xls"
'datei schliessen
wbZiel.Close
End Sub


Gruß
Franz

Anzeige
AW: Makkro-Neuling braucht Hilfe
13.06.2008 16:05:00
Thomas
Hallo Franz!
Vielen Dank!! jetzt funktioniert es genau so wie ich es wollte!
Momentan ist das alles ja nur auf nem Test-Laufwerk. Wenn ich das dann spaeter auf dem richtigen Laufwerk laufen lasse muss ich eigentlich nur den Abschnitt
'Verzeichnis für Template und Datei mit Daten
strPfad = "C:\Documents and Settings\herbtf\My Documents\Test\Qute Folder\"
aendern und dort den neuen Pfad eingeben, oder?
Herzlichen Dank fuer deine Hilfe!
gruesse aus atlanta!
tom

AW: Makkro-Neuling braucht Hilfe
13.06.2008 16:22:00
fcs
Hallo Tom,
ja, den Pfad und ggf. den Namen der Template-Datei
Kleines ? evtl. bei Datei im Netzlaufwerk da bin ich nicht so firm ob es reibungslos läuft.
Grüße aus Bayern in die Cola-Metropole
Franz

AW: Makkro-Neuling braucht Hilfe
13.06.2008 16:26:00
Thomas
servus franz,
ich probier das dann einfach mal aus mit dem netzlaufwerk und wenns net funktioniert wird mir schon jemand im forum weiterhelfen koennen...
komm ja auch urspruenglich aus bayern (amberg in der opf.) :)
gruss und schoenes wochenende!!

AW: Makkro-Neuling braucht Hilfe
13.06.2008 17:12:22
Thomas
Servus Franz,
hab das jetzt meinem chef gezeigt und er ist begeistert!
Und weil das so gut klappt, hab ich gleich ne zusatztaufgabe bekommen. also wenn du zeit und lust hast, vielleicht kannst du mir ja auch dabei helfen. es geht immer noch um die gleiche datei.
und zwar soll nun nachdem die template datei mit den eingabedaten gefuellt und abgespeichert wurde die gleichen daten in der datei in ein anderes tabellenblatt eingefuegt werden. in diesem tabellenblatt stehen schon mehrere eintraege drin und das neue projekt soll nun unten angefuegt werden. problem dabei ist , dass es da auch eine summenzeile gibt und dort auch die formel angepasst werden muss. hab dir mal nen screenshot gemacht. Userbild
also, wenn z.b. in "input new quote" das projekt D angelegt wird, dann soll er die Daten in die richtigen Spalten in "quote log' eintragen.
waer natuerlich super wenn man das dann gleich an das bestehende makkro

Sub DatenNachTemplate()
Dim wbThis As Workbook, wbZiel As Workbook
Dim wksThis As Worksheet, wksZiel As Worksheet
Dim strPfad As String, strProjekt As String, strDatum As String
Set wbThis = ThisWorkbook 'Datei A
Set wksThis = wbThis.Worksheets("Input new Quote")
'Verzeichnis für Template und Datei mit Daten
strPfad = "C:\Documents and Settings\herbtf\My Documents\Test\Qute Folder\"
Set wbZiel = Workbooks.Add(Template:=strPfad & "Test_Template")
Set wksZiel = wbZiel.Worksheets("2.1. R&O LoAa") 'Tabellenblatt in das Daten _
eingetragen werden.
'Daten übertragen
wksZiel.Cells(10, 4).Value = wksThis.Cells(5, 2).Value 'Datum
wksZiel.Cells(3, 4).Value = wksThis.Cells(4, 2).Value 'Projekt name
wksZiel.Cells(4, 4).Value = wksThis.Cells(6, 2).Value 'Qutote nummer
wksZiel.Cells(6, 4).Value = wksThis.Cells(9, 2).Value 'End Customer
wksZiel.Cells(7, 4).Value = wksThis.Cells(7, 2).Value 'Distributor
'Dateinamen generieren und Datei speichern
strFilename = wksThis.Cells(11, 2).Value
wbZiel.SaveAs Filename:=strPfad & strFilename & ".xls"
'datei schliessen
wbZiel.Close
End Sub


unten mit anfuegen koennte... waer super wenn das klappt!
Gruss
tom

AW: Makkro-Neuling braucht Hilfe
13.06.2008 21:29:45
Franc
in welcher Arbeitsmappe liegt die Liste und wie ist der Name von der Tabelle?
Woher kommen die Daten für Umsatz, Kosten und Gewinn?

AW: Makkro-Neuling braucht Hilfe
13.06.2008 21:38:00
Thomas
Diese Liste liegt in der Ausgangsdatei und das Tabellenblatt heisst "Quote Log". Die Daten fuer Gewinn, Kosten usw. sollen dann spaeter aus der neu erzeugten Datei rauskopiert werden. aber das sollte ich dann schon hinbekommen. erstmal waer wichtig diese Zeile in "Quote Log" zu erstellen und mit den Daten aus "Input new Quote" zu fuellen

AW: Makkro-Neuling braucht Hilfe
13.06.2008 21:55:00
Franc
sollte so klappen am besten vorher immer ne Sicherungskopie anlegen.

Sub DatenNachTemplate()
Dim wbThis As Workbook, wbZiel As Workbook
Dim wksThis As Worksheet, wksZiel As Worksheet, wksListe As Worksheet
Dim strPfad As String, strProjekt As String, strDatum As String
Dim LetzteZeile As Long
Set wbThis = ThisWorkbook 'Datei A
Set wksThis = wbThis.Worksheets("Input new Quote")
Set wksListe = wbThis.Worksheets("Quote Log")
'Verzeichnis für Template und Datei mit Daten
strPfad = "C:\Documents and Settings\herbtf\My Documents\Test\Qute Folder\"
Set wbZiel = Workbooks.Add(Template:=strPfad & "Test_Template")
Set wksZiel = wbZiel.Worksheets("2.1. R&O LoAa") 'Tabellenblatt in das Daten eingetragen  _
werden.
'Daten übertragen
wksZiel.Cells(10, 4).Value = wksThis.Cells(5, 2).Value 'Datum
wksZiel.Cells(3, 4).Value = wksThis.Cells(4, 2).Value 'Projekt name
wksZiel.Cells(4, 4).Value = wksThis.Cells(6, 2).Value 'Qutote nummer
wksZiel.Cells(6, 4).Value = wksThis.Cells(9, 2).Value 'End Customer
wksZiel.Cells(7, 4).Value = wksThis.Cells(7, 2).Value 'Distributor
'Dateinamen generieren und Datei speichern
strFilename = wksThis.Cells(11, 2).Value
wbZiel.SaveAs Filename:=strPfad & strFilename & ".xls"
'datei schliessen
wbZiel.Close
' Werte im Tabellenblatt "Quote Log" eintragen
' letzte beschriebene Zeile + 1 ermitteln
LetzteZeile = wksListe.Range("A65500").End(xlUp).Row + 1
wksListe.Rows(LetzteZeile).Insert Shift:=xlDown ' Zeile einfügen
wksListe.Cells(LetzteZeile, 2).Value = wksThis.Cells(5, 2).Value 'Datum
wksListe.Cells(LetzteZeile, 1).Value = wksThis.Cells(4, 2).Value 'Projekt name
wksListe.Cells(LetzteZeile, 3).Value = wksThis.Cells(6, 2).Value 'Quote nummer
wksListe.Cells(LetzteZeile, 5).Value = wksThis.Cells(9, 2).Value 'End Customer
wksListe.Cells(LetzteZeile, 4).Value = wksThis.Cells(7, 2).Value 'Distributor
wksListe.Cells(LetzteZeile + 1, 6).Formula = "=SUM(F2:F" & LetzteZeile & ")" 'Summe F
wksListe.Cells(LetzteZeile + 1, 7).Formula = "=SUM(G2:G" & LetzteZeile & ")" 'Summe G
wksListe.Cells(LetzteZeile + 1, 8).Formula = "=SUM(H2:H" & LetzteZeile & ")" 'Summe H
End Sub


AW: Makkro-Neuling braucht Hilfe
13.06.2008 22:01:53
Thomas
Ok, vielen dank. ich probiers mal aus und geb dir dann feedback!
Gruss

AW: Makkro-Neuling braucht Hilfe
13.06.2008 23:08:22
Thomas
Hi Franz,
funktioniert perfekt!! Vielen Dank!! Da waer ich allein nie drauf gekommen!
fuer diese woche reicht das jetzt erst mal. ich mach dann auch feierabend und am montag gehts weiter..
gruss
tom

AW: Makkro-Neuling braucht Hilfe
16.06.2008 22:19:02
Thomas
Servus Franz,
mein Makro-Projekt ist noch nicht ganz fertig. Ich hab da noch eine Kleinigkeit zu machen. Waer super wenn du mir dabei helfen koenntest!
Das erste Makro erzeugt ja eine neue Datei (Quote File) und speichert diese unter einem ganz bestimmten Filename ab. Zusaetzlich wird fuer ein neues projekt eine neue zeile in der Quote Log Tabelle angelegt.
nun soll ein zweites makro im quote file bestimmte Werte wieder zurueck an die quote log datei geben und zwar genau in die neu eingefuegte zeile.
dazu hab ich in der quote log tabelle breits eine spalte in der die filenames der projekte eingetragen werden. somit kann jeder quote file eine bestimmte zeile in quote log zugeordnet werden.
wie bekom ich das aber jetzt hin, dass das makro in der quote datei sich seinen filename anschaut, dann in quote log geht in der spalte mit den filenames sich das entsprechende raussucht und dann die werte in aus der quote file in diese zeile kopiert und danach die quote log datei wieder speichert.
ich hab dir das auch mal aufgezeichnet wie das so aussieht..ich hoff du weisst was ich meine u wie das ablaufen soll
Userbild
Vielen Dank schon im Voraus!!!
Gruss
tom

AW: Makkro-Neuling braucht Hilfe
17.06.2008 07:54:43
fcs
Hallo Tom,
franc und Franz (fcs) geht ein wenig durcheinander :-)
Nachfolgend der Grundcode
Die Pfade, Datei- und Blatt-Namen und die Zeilen/Spaltennummern in Cells/Columns-Eigenschaften muss du noch anpassen.
Zum Testen Code im VBA-Editor mit Taste F8 starten und kontollieren, ob im Code noch Fehler stecken oder zeitweise die Zeile
On Error Goto Fehler
deaktivieren, bis der Code durchläuft.
Gruß
Franz

Sub FinancialSummaryToQuoteLog()
Dim wksFinSum As Worksheet
Dim wbQuoteLog As Workbook, wksQuoteLog As Worksheet
Dim varQuoteFile As Variant
Dim lngZeileQL As Long
Dim bolLogOpen As Boolean
Dim objZelle As Range
Const strPfadQuoteLog = "C:\Test\Daten" 'Verzeichnis der QuoteLog-Datei
Const strDateiQuoteLog = "QuoteLog.xls" 'Name der QuoteLog-Datei
On Error GoTo Fehler
Set wksFinSum = ActiveWorkbook.Worksheets("Financial Summary")
'Prüfen, ob Quote Log Datei geöffnet
For Each wbQuoteLog In Application.Workbooks
If LCase(wbQuoteLog.Name) = LCase(strDateiQuoteLog) Then
bolLogOpen = True
Exit For
End If
Next
If bolLogOpen = False Then
Set wbQuoteLog = Workbooks.Open(FileName:=strPfadQuoteLog & "\" & strDateiQuoteLog)
End If
'Quotelog-Tabellenblatt setzen
Set wksQuoteLog = wbQuoteLog.Worksheets("Quote Log")
'Dateiname der Quote-Datei (wie in Quote Log eingetragen!!)
varQuoteFile = wksFinSum.Cells(5, 2).Value 'Zelle-Adresse ggf. anpassen
'Quote - Filenamen im Quotelog Spalte 7 suchen
Set objZelle = wksQuoteLog.Columns(7).Find(What:=varQuoteFile, _
LookIn:=xlValue, lookat:=xlWhole)
If objZelle Is Nothing Then
MsgBox "Der Quote-Filename wurde im Quote-Log nicht gefunden!"
Else
lngZeileQL = objZelle.Row 'Zeile mit Quotefile in Quote-Log
'Werte von Financial Summay nach Quote-Log übertragen
wksQuoteLog.Cells(lngZeileQL, 4).Value = wksFinSum.Cells(2, 2).Value 'Total
wksQuoteLog.Cells(lngZeileQL, 5).Value = wksFinSum.Cells(2, 3).Value 'BU1
wksQuoteLog.Cells(lngZeileQL, 6).Value = wksFinSum.Cells(2, 4).Value 'BU2
'Quote Log- Datei speichern
wbQuoteLog.Save
End If
'Quote Log- Datei nach Rückfrage ggf. wieder schliessen
If bolLogOpen = False Then
If MsgBox("Quote Log Datei wieder schliessen?", vbYesNo, _
"Eintrag Financial Summary in Quote Log") = vbYes Then
wbQuoteLog.Close Savechanges:=True
End If
End If
Fehler:
If Err.Number  0 Then
MsgBox "Fehler Nr. " & Err.Number & " ist augetreten!" & vbLf & Err.Description
End If
End Sub


AW: Makkro-Neuling braucht Hilfe
17.06.2008 15:46:00
Thomas
Hi Franz und franc :)
(da kann man aber auch leicht durcheinander kommen!!)
Der VBA Code laeuft gut durch bis zur markierten Zeile:

Sub FinancialSummaryToQuoteLog()
Dim wksFinSum As Worksheet
Dim wbQuoteLog As Workbook, wksQuoteLog As Worksheet
Dim varQuoteFile As Variant
Dim lngZeileQL As Long
Dim bolLogOpen As Boolean
Dim objZelle As Range
Const strPfadQuoteLog = "\\Noctf01a\DPD_Hyp\FINANCE\Tom\Quotelog\" 'Verzeichnis der QuoteLog- _
Datei
Const strDateiQuoteLog = "Quotelog_test.xls" 'Name der QuoteLog-Datei (Test Version)
'On Error GoTo Fehler
Set wksFinSum = ActiveWorkbook.Worksheets("2.2. Financial Summary")
'Prüfen, ob Quote Log Datei geöffnet
For Each wbQuoteLog In Application.Workbooks
If LCase(wbQuoteLog.Name) = LCase(strDateiQuoteLog) Then
bolLogOpen = True
Exit For
End If
Next
If bolLogOpen = False Then
Set wbQuoteLog = Workbooks.Open(Filename:=strPfadQuoteLog & "\" & strDateiQuoteLog)
End If
'Quotelog-Tabellenblatt setzen
Set wksQuoteLog = wbQuoteLog.Worksheets("Quote Log")
'Dateiname der Quote-Datei (wie in Quote Log eingetragen!!)
varQuoteFile = wksFinSum.Cells(17, 6).Value 'Zelle-Adresse ggf. anpassen
'Quote - Filenamen im Quotelog Spalte 29 suchen
Set objZelle = wksQuoteLog.Columns(29).Find(What:=varQuoteFile, _
LookIn:=xlValue, lookat:=xlWhole)
If objZelle Is Nothing Then
MsgBox "Der Quote-Filename wurde im Quote-Log nicht gefunden!"
Else
lngZeileQL = objZelle.Row 'Zeile mit Quotefile in Quote-Log
'Werte von Financial Summay nach Quote-Log übertragen
wksQuoteLog.Cells(lngZeileQL, 6).Value = wksFinSum.Cells(22, 11).Value 'EABU
wksQuoteLog.Cells(lngZeileQL, 7).Value = wksFinSum.Cells(22, 5).Value 'LVSG
wksQuoteLog.Cells(lngZeileQL, 8).Value = wksFinSum.Cells(22, 6).Value 'Busway
wksQuoteLog.Cells(lngZeileQL, 9).Value = wksFinSum.Cells(22, 7).Value 'MCC
wksQuoteLog.Cells(lngZeileQL, 10).Value = wksFinSum.Cells(22, 8).Value 'PBSB
wksQuoteLog.Cells(lngZeileQL, 11).Value = wksFinSum.Cells(22, 9).Value 'LP
wksQuoteLog.Cells(lngZeileQL, 13).Value = wksFinSum.Cells(22, 10).Value 'Buyout (regular)
wksQuoteLog.Cells(lngZeileQL, 16).Value = wksFinSum.Cells(22, 13).Value 'PMT
wksQuoteLog.Cells(lngZeileQL, 18).Value = wksFinSum.Cells(22, 17).Value 'ISD
'Quote Log- Datei speichern
wbQuoteLog.Save
End If
'Quote Log- Datei nach Rückfrage ggf. wieder schliessen
If bolLogOpen = False Then
If MsgBox("Quote Log Datei wieder schliessen?", vbYesNo, _
"Eintrag Financial Summary in Quote Log") = vbYes Then
wbQuoteLog.Close Savechanges:=True
End If
End If
Fehler:
If Err.Number  0 Then
MsgBox "Fehler Nr. " & Err.Number & " ist augetreten!" & vbLf & Err.Description
End If
End Sub


Da kommt dann ne Fehlermeldung: Runtime error '9' : Subscript out of range
woran kann das liegen?
Gruesse\
Tom

AW: Makkro-Neuling braucht Hilfe
17.06.2008 19:39:00
fcs
Hallo Tom,
mit der Fehlermeldung kann ich wenig anfangen.
Die Find-Methode hat zumindest in älteren Excelversionen Probleme, wenn zum Zeitpunkt der Code-Ausführung der Fokus nicht auf einer Zelle ist, sondern z.B. auf einem Command-Button. Keine Ahnung, ob das bei dir die Ursache ist.
Probiere als Ersatz für die Problemzeile mal folgende etwas langsamere Suchroutine:

'Quote - Filenamen im Quotelog Spalte 29 suchen
Set objZelle = Nothing
With wksQuoteLog
For lngZeileQL = 1 To .Cells(.Rows.Count, 29).End(xlUp).Row
If LCase(.Cells(lngZeileQL, 29).Value) = LCase(varQuoteFile) Then
Set objZelle = .Cells(lngZeileQL, 29)
Exit For
End If
Next
End With

Gruß
Franz

AW: Makkro-Neuling braucht Hilfe
17.06.2008 20:44:00
Thomas
Super! Jetzt funktioniert's!!
Wie ist das jetzt eigentlich, wenn es mehrere neue projekte und damit quote files gibt und diese auch von verschiedenen leuten betreut werden. checkt das makro dann wenn die quote log datei schon von jemand anderem geoeffnet wurde? denn es gibt ja nur eine quote log und wenn da gleichzeitig mehrere zugreifen wollen, dann gibts bestimmt probleme beim abspeichern oder?
ist es darueber hinaus auch moeglich, einen blattschutz in quote log einzufuegen, so dass man manuell dort keine werte eintragen kann und nur durch das makro die daten reinkopiert werden koennen?
gruss tom

AW: Makkro-Neuling braucht Hilfe
18.06.2008 08:35:27
fcs
Hallo Tom,
automatisch prüfen tut das Makro nicht. Da dann die Quotelog schreibgeschürzt geöffnet wird könnte noch eine Prüfung eingebaut werden.
Da die QuoteLog-Datei normalerweise geschlossen sein, solltest du die Abfrage gegen Ende des Makros, ob die Quotelog-Datei wieder geschlossen werden soll, rausnehmen. Wenn die Quotelog-Datei beim Speichern der Quote-Datei-Informationen geschlossen wae, dann wird sie im Anschluss an das Eintragen der Daten auch gleich wieder geschlossen.
Blatt des Quote-Logs ist fast kein Problem. Jedes mal bevor Daten in das Blatt geschrieben werden sollen muss dann der Blattschutz vom Makro deaktiviert werden , hinterher wieder aktiviert werden.
Gruß
Franz

AW: Makkro-Neuling braucht Hilfe
18.06.2008 14:38:00
Thomas
Hallo Franz,
das klingt ja ganz gut. kannst du mir vielleicht ein paar zeilen schreiben die nen blattschutz vor dem eintragen aufheben und nachher wieder den blattschutz aktivieren? kann dann das kennwort direkt im makro hinterlegt werden oder muss das in die datei rein?
gruss
tom

AW: Makkro-Neuling braucht Hilfe
18.06.2008 18:27:00
fcs
Hallo Tom,
ich hab in dein Makro mal an entspechenden Stellen Zeilen eingefügt für Überwachung ob QuoteLog schreibgeschützt geöffnet und für Schuzt des Blattes.
Wenn du das Blatt per Kennwort schützt, dann muss du auch das VBA-Projekt per Kennwort schützen, sonst kann jede/jeder einfach das Kennwort einsehen.
Nicht vergessen Kennwörter beim Boss im Safe zu hinterlegen!
Gruß
Franz
Ob das mit dem schreibgeschützt öffnen funktioniert muss du mal zusammen mit einem Kollegen prüfen.
Dieser soll die Quote-Log-Datei im Netzwerk öffnen. Anschließend muss du das Makro testen.

Sub FinancialSummaryToQuoteLog()
Dim wksFinSum As Worksheet
Dim wbQuoteLog As Workbook, wksQuoteLog As Worksheet
Dim varQuoteFile As Variant
Dim lngZeileQL As Long
Dim bolLogOpen As Boolean
Dim objZelle As Range
Const strPfadQuoteLog = "\\Noctf01a\DPD_Hyp\FINANCE\Tom\Quotelog\" 'Verzeichnis der QuoteLog-  _
_
Datei
Const strDateiQuoteLog = "Quotelog_test.xls" 'Name der QuoteLog-Datei (Test Version)
'On Error GoTo Fehler
Set wksFinSum = ActiveWorkbook.Worksheets("2.2. Financial Summary")
'Prüfen, ob Quote Log Datei geöffnet
For Each wbQuoteLog In Application.Workbooks
If LCase(wbQuoteLog.Name) = LCase(strDateiQuoteLog) Then
bolLogOpen = True
Exit For
End If
Next
If bolLogOpen = False Then
Set wbQuoteLog = Workbooks.Open(Filename:=strPfadQuoteLog & "\" & strDateiQuoteLog)
End If
'Prüfen, ob Quotelog-Datei schreibgeschützt geöffnet wurde    'Anfang Neu 20080618
If wbQuoteLog.ReadOnly = True Then
MsgBox "Die Quote-Log-Datei is momentan von einem anderen User geöffnet!" & vbLf _
& "Bitte versuchen Sie später die Daten der Quote-Datei zu übertragen.", _
vbOKOnly, "Summary-Daten --> QuoteLog"
wbQuoteLog.Close savechanges:=False
End If                                                        'Ende Neu 20080618
'Quotelog-Tabellenblatt setzen
Set wksQuoteLog = wbQuoteLog.Worksheets("Quote Log")
'Blattschutz aufheben                                             'Neu 20080618
wksQuoteLog.Unprotect Password:="XYZ"                             'Neu 20080618
'Dateiname der Quote-Datei (wie in Quote Log eingetragen!!)
varQuoteFile = wksFinSum.Cells(17, 6).Value 'Zelle-Adresse ggf. anpassen
'Quote - Filenamen im Quotelog Spalte 29 suchen
Set objZelle = Nothing
With wksQuoteLog
For lngZeileQL = 1 To .Cells(.Rows.Count, 29).End(xlUp).Row
If LCase(.Cells(lngZeileQL, 29).Value) = LCase(varQuoteFile) Then
Set objZelle = .Cells(lngZeileQL, 29)
Exit For
End If
Next
End With
If objZelle Is Nothing Then
MsgBox "Der Quote-Filename wurde im Quote-Log nicht gefunden!"
Else
lngZeileQL = objZelle.Row 'Zeile mit Quotefile in Quote-Log
'Werte von Financial Summay nach Quote-Log übertragen
wksQuoteLog.Cells(lngZeileQL, 6).Value = wksFinSum.Cells(22, 11).Value 'EABU
wksQuoteLog.Cells(lngZeileQL, 7).Value = wksFinSum.Cells(22, 5).Value 'LVSG
wksQuoteLog.Cells(lngZeileQL, 8).Value = wksFinSum.Cells(22, 6).Value 'Busway
wksQuoteLog.Cells(lngZeileQL, 9).Value = wksFinSum.Cells(22, 7).Value 'MCC
wksQuoteLog.Cells(lngZeileQL, 10).Value = wksFinSum.Cells(22, 8).Value 'PBSB
wksQuoteLog.Cells(lngZeileQL, 11).Value = wksFinSum.Cells(22, 9).Value 'LP
wksQuoteLog.Cells(lngZeileQL, 13).Value = wksFinSum.Cells(22, 10).Value 'Buyout (regular)
wksQuoteLog.Cells(lngZeileQL, 16).Value = wksFinSum.Cells(22, 13).Value 'PMT
wksQuoteLog.Cells(lngZeileQL, 18).Value = wksFinSum.Cells(22, 17).Value 'ISD
'Blattschutz wieder einschalten                 'Neu 20080618
wksQuoteLog.Protect Password:="XYZ"             'Neu 20080618
'Quote Log- Datei speichern
wbQuoteLog.Save
End If
'Quote Log-Datei wieder schliessen wenn sie nicht geöffnet war 'Modifiziert 20080618
If bolLogOpen = False Then
'    If MsgBox("Quote Log Datei wieder schliessen?", vbYesNo, _
"Eintrag Financial Summary in Quote Log") = vbYes Then  'Modifiziert 20080618
wbQuoteLog.Close savechanges:=True
'    End If                                                     'Modifiziert 20080618
End If
Fehler:
If Err.Number  0 Then
MsgBox "Fehler Nr. " & Err.Number & " ist augetreten!" & vbLf & Err.Description
End If
End Sub


AW: Makkro-Neuling braucht Hilfe
18.06.2008 22:55:07
Thomas
hi franz, danke! ich habs jetzt mal so uebernommen, konnte es aber noch nicht ausprobieren weil wir heut server probleme haben. werd das makro dann morgen mal laufen lassen u sag dir dann bescheid ob es funktioniert.
ist es moeglich, den job name der in der quotelog datei mit durch das erste makro von "import new quote" in "quote log" kopiert wird, als hyperlink zu der neu erstellten datei einzufuegen?
momentan sieht der code folgendermassen aus:

Sub DataTransferToTemplateAndQuoteLogNetworkDriveTest()
Dim wbThis As Workbook, wbZiel As Workbook
Dim wksThis As Worksheet, wksZiel As Worksheet, wksListe As Worksheet
Dim strPfad As String, strProjekt As String, strDatum As String
Dim LetzteZeile As Long
Set wbThis = ThisWorkbook 'Quote Log
Set wksThis = wbThis.Worksheets("Input new Quote")
Set wksListe = wbThis.Worksheets("Quote Log")
'Path of Template and new created files
strPfad = "\\Noctf01a\DPD_Hyp\FINANCE\Tom\Template\" ' Get Template from this path
strPfad2 = "\\Noctf01a\DPD_Hyp\FINANCE\Tom\Quote Folder\" ' save quote file in this path  _
later on
Set wbZiel = Workbooks.Add(Template:=strPfad & "Test_Template")
Set wksZiel = wbZiel.Worksheets("2.1. R&O LoAa") 'Transfer data to this worksheet in  _
template
'Transfer following data
wksZiel.Cells(3, 4).Value = wksThis.Cells(4, 2).Value 'Job name / project name
wksZiel.Cells(10, 4).Value = wksThis.Cells(5, 2).Value 'date
wksZiel.Cells(4, 4).Value = wksThis.Cells(6, 2).Value 'Qutote nummer
wksZiel.Cells(7, 4).Value = wksThis.Cells(7, 2).Value 'Distributor
wksZiel.Cells(6, 4).Value = wksThis.Cells(8, 2).Value 'End Customer
wksZiel.Cells(3, 7).Value = wksThis.Cells(9, 2).Value 'Quote Originator
wksZiel.Cells(4, 7).Value = wksThis.Cells(10, 2).Value 'Salesperson
wksZiel.Cells(5, 7).Value = wksThis.Cells(11, 2).Value 'Originator
wksZiel.Cells(6, 7).Value = wksThis.Cells(12, 2).Value 'Marketing Manager
wksZiel.Cells(7, 7).Value = wksThis.Cells(13, 2).Value 'Region
wksZiel.Cells(13, 4).Value = wksThis.Cells(15, 2).Value 'Filename
'Save file as job name_quote#_date.xls in certain path defined above
strFilename = wksThis.Cells(11, 2).Value
wbZiel.SaveAs Filename:=strPfad2 & strFilename & ".xls"
'close file
wbZiel.Close
' Transfer data within "Quote Log" file from worksheet "input new quote" to "Quote log"
' Go into worksheet Quote Log, find the last entry, add a new row, insert the data into  _
this row and adjust the sum formulas
LetzteZeile = wksListe.Range("A65500").End(xlUp).Row + 1
wksListe.Rows(LetzteZeile).Insert Shift:=xlDown ' insert new row
wksListe.Cells(LetzteZeile, 1).Value = wksThis.Cells(4, 2).Value 'transfer project name
wksListe.Cells(LetzteZeile, 2).Value = wksThis.Cells(5, 3).Value 'transfer date
wksListe.Cells(LetzteZeile, 3).Value = wksThis.Cells(6, 2).Value 'transfer Quote number
wksListe.Cells(LetzteZeile, 4).Value = wksThis.Cells(7, 2).Value 'transfer Distributor
wksListe.Cells(LetzteZeile, 5).Value = wksThis.Cells(8, 2).Value 'transfer Customer
wksListe.Cells(LetzteZeile, 6).Value = wksThis.Cells(9, 2).Value 'transfer Quote Originator
wksListe.Cells(LetzteZeile, 7).Value = wksThis.Cells(10, 2).Value 'transfer Salesperson
wksListe.Cells(LetzteZeile, 8).Value = wksThis.Cells(11, 2).Value 'transfer Originator
wksListe.Cells(LetzteZeile, 9).Value = wksThis.Cells(12, 2).Value 'transfer Marketing  _
Manager
wksListe.Cells(LetzteZeile, 10).Value = wksThis.Cells(13, 2).Value 'transfer Region
wksListe.Cells(LetzteZeile, 34).Value = wksThis.Cells(15, 2).Value 'transfer Filename
'adjust formulas
wksListe.Cells(LetzteZeile + 1, 11).Formula = "=SUM(K2:K" & LetzteZeile & ")" 'adjust sum  _
formula EABU sale
wksListe.Cells(LetzteZeile + 1, 12).Formula = "=SUM(L2:L" & LetzteZeile & ")" 'adjust sum  _
formula LVSG
wksListe.Cells(LetzteZeile + 1, 13).Formula = "=SUM(M2:M" & LetzteZeile & ")" 'adjust sum  _
formula Busway
wksListe.Cells(LetzteZeile + 1, 14).Formula = "=SUM(N2:N" & LetzteZeile & ")" 'adjust sum  _
formula MCC
wksListe.Cells(LetzteZeile + 1, 15).Formula = "=SUM(O2:O" & LetzteZeile & ")" 'adjust sum  _
formula PBSB
wksListe.Cells(LetzteZeile + 1, 16).Formula = "=SUM(P2:P" & LetzteZeile & ")" 'adjust sum  _
formula LP
wksListe.Cells(LetzteZeile + 1, 17).Formula = "=SUM(Q2:Q" & LetzteZeile & ")" 'adjust sum  _
formula Buyout total
wksListe.Cells(LetzteZeile + 1, 18).Formula = "=SUM(R2:R" & LetzteZeile & ")" 'adjust sum  _
formula Buyout IIPMO
wksListe.Cells(LetzteZeile + 1, 19).Formula = "=SUM(S2:S" & LetzteZeile & ")" 'adjust sum  _
formula Bayout Regular
wksListe.Cells(LetzteZeile + 1, 21).Formula = "=SUM(U2:U" & LetzteZeile & ")" 'adjust sum  _
formula EBIT
'set frame for new row
Sheets("Quote Log").Select
Cells(LetzteZeile, 1).Select
Selection.Borders(xlDiagonalDown).LineStyle = xlNone
Selection.Borders(xlDiagonalUp).LineStyle = xlNone
With Selection.Borders(xlEdgeLeft)
.LineStyle = xlContinuous
.Weight = xlThin
.ColorIndex = xlAutomatic
End With
With Selection.Borders(xlEdgeTop)
.LineStyle = xlContinuous
.Weight = xlThin
.ColorIndex = xlAutomatic
End With
With Selection.Borders(xlEdgeBottom)
.LineStyle = xlContinuous
.Weight = xlThin
.ColorIndex = xlAutomatic
End With
With Selection.Borders(xlEdgeRight)
.LineStyle = xlContinuous
.Weight = xlThin
.ColorIndex = xlAutomatic
End With
End Sub


was muesste dafuer geaendert werden?
tausend dank und gruesse
tom

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige