Live-Forum - Die aktuellen Beiträge
Datum
Titel
26.09.2025 10:29:46
Wert aus einer Zelle bei jeder Eingabe in neue Zelle
26.09.2025 08:51:00
Teilinhalt einer Zelle vergleichen
25.09.2025 23:04:12
Einen von drei möglichen Einträgen in einer Zeile suchen
25.09.2025 19:59:48
Lebenserleichternde Datei, im Bezug auf die Essensauswahl
Keine passende Antwort im Forumarchiv gefunden?
Stelle deine Frage im Live-Forum
Anzeige
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Vorheriger Thread
Vorheriger Thread
Rückwärts Blättern
988to992
988to992
Aktuelles Verzeichnis
Verzeichnis Übersicht
Verzeichnis Übersicht
Übersicht Verzeichnisse
Nächster Thread
Nächster Thread
Vorwärts blättern
Inhaltsverzeichnis

Von rechts finden

Forumthread: Von rechts finden

Von rechts finden
25.06.2008 12:54:21
Gordon
Moin,
kann mir jemand sagen, ob es möglich ist, in einer Excel-Zelle etwas von rechts zu finden. Mit der Funktion Finden() kann man ja normalerweise von links an etwas finden. Nun würde ich es gerne aber von rechts an versuchen. Z.B. Ich möchte wissen an welcher Stelle das erste Leerzeichen von rechts steht. Gibt es da 'ne Möglichkeit? Meine bisherigen Versuche sind leider immer gescheitert.
Gruß
Gordon

Anzeige

30
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: Von rechts finden
25.06.2008 12:59:47
Rudi
Hallo,
ich habe dir doch so ein paar hübsche Formel geschickt, auf die du bislang nicht reagiert hast. Da ist das für die Stadt realisiert.
Gruß
Rudi

=VERWEIS(9^99;FINDEN(" ";A1;ZEILE(A:A)))
25.06.2008 13:00:39
WF
.

AW: =VERWEIS(9^99;FINDEN(" ";A1;ZEILE(A:A)))
25.06.2008 13:42:43
Gordon
Super,
die Formel hat mein Problem gelöst. Ich verstehe sie zwar nicht so ganz, aber dennoch Danke! :)
Gruß
Gordon

Anzeige
AW: =VERWEIS(9^99;FINDEN(" ";A1;ZEILE(A:A)))
25.06.2008 13:53:07
Uwe
Hi WF,
ich habe jetz 'ne viertel Stunde gebraucht um ungefähr zu verstehen wie diese Formel "tickt". Wie kommt man bloß auf so raffinierter Tricks. Ist in meiner Sammlung verewigt (:-)
GRATULATION!
Gruß
Uwe
(:o)

AW: =VERWEIS(9^99;FINDEN(" ";A1;ZEILE(A:A)))
25.06.2008 14:36:00
David
Nachdem mir jetzt mein Excel ausgestiegen ist, als ich die Formelauswertung auf diese Formel losgelassen habe, wäre es schön, wenn du deine Erkenntnisse mal auf die Excel-Gemeinde loslässt. Ich verstehe die Formel nämlich nicht so richtig. :-)
Danke schon mal.
Gruß
David

Anzeige
AW: =VERWEIS(9^99;FINDEN(" ";A1;ZEILE(A:A)))
25.06.2008 15:01:50
Rudi
Hallo,
als ich die Formelauswertung auf diese Formel losgelassen habe


Du solltest Zeile(A:A) vorher mal in Zeile(1:20) ändern.
Gruß
Rudi

Formelerläuterung
25.06.2008 15:12:57
WF
schreibe in A1 als Beispiel: abc defg hi
das letzte Leerzeichen ist also an der 9. Position.
Ändere meine Formel geringfügig (um mit F9 Teilergebnisse anzeigen zu können) auf:
=VERWEIS(9^99;FINDEN(" ";A1;ZEILE(1:15)))
markiere darin FINDEN(" ";A1;ZEILE(1:15)) und betätige F9
Du siehst: '=VERWEIS(9^99;{4;4;4;4;9;9;9;9;9;#WERT!;#WERT!;#WERT!;#WERT!;#WERT!;#WERT!})
Das erste Leerzeichen wird in A1 ab dem 1. dem 2. dem 3. dem 4. Zeichen gesucht und ergibt jeweils 4.
Dann weiter ab dem 5. dem 6. usw. ergibt jeweils 9
Ab dem 10. kommt #WERT!, da kein Leerzeichen mehr vorkommt.
der VERWEIS sucht jetzt nach der Zahl 9^99 und wenn er die nicht findet, nimmt er die nächstkleinere Zahl: das ist die 9
voilà
WF

Anzeige
genial, aber...
25.06.2008 15:25:54
David
... besteht da nicht die Gefahr, dass der Rechner bei mehreren Formeln dieser Art in die Knie geht? Sollte man das dann nicht lieber begrenzen, derart: Zeile(1:1000) oder so ähnlich?
Gruß

=SUMME(A:A) ist doch auch problemlos
25.06.2008 15:34:25
WF
.

AW: =SUMME(A:A) ist doch auch problemlos
26.06.2008 10:18:36
Gordon
Hmm....die Formel klappt wunderbar,
leider habe ich nun doch einen Fall entdeckt, wo sie mir anscheinend leider nicht ganz weiterhilft. Gibt es eine Möglichkeit, wenn man eine Adresse hat (z.B. ABC-Strasse 31 a 12345 Bad Musterland), dass man herausfindet, an welcher Stelle die PLZ endet?
Gruß
Gordon

Anzeige
Position der Leerstelle nach der PLZ
26.06.2008 10:59:00
WF
Hi Gordon,
folgende Arrayformel:
{=MAX(WENN(ISTZAHL(TEIL(A1;SPALTE(1:1);1)*1);SPALTE(1:1)))+1}
nach der PLZ darf aber keine Zahl mehr auftauchen!
ARRAY-Formel {=geschweifte Klammern} nicht eingeben;
Abschluß der Formel mit gleichzeitig Strg / Shift / Enter; - das erzeugt sie.
Salut WF

Anzeige
Die PLZ
26.06.2008 11:16:47
Rudi
Hallo,
diese Matrixformel:
{=VERWEIS(9^9;(--TEIL(A1;SPALTE(1:1);6)))}
Gruß
Rudi

prima o.T.
26.06.2008 11:31:01
WF
.

sehr schön, aber ...
26.06.2008 11:39:23
neopa
Hallo Rudi
... wie immer werden die Sachsen vergessen.
Wollte meine Lösung zwar nicht einstellen, weil Sie auch noch nicht ganz astrein ist (findest Du bestimmt auch heraus), aber nun tue ich es doch, um die Sachsen zu verteten und Dir die Möglichkeit zu geben nachzubessern (auch ist mE Deine zusätzliche Matrix-Klammerung in Deiner Formel nicht notwendig).
Hier der Vergleich mit meiner Monsterformel:
 ABCD
1AdresseWFRudineopa
2ABC-Strasse 31 a 12345 Bad Musterland123451234512345
323-Str 31a12 09345 Bad Sachsenland 9band 9934509345

Formeln der Tabelle
ZelleFormel
B2{=TEIL(A2;MAX(WENN(ISTZAHL(TEIL(A2;SPALTE(2:2); 1)*1); SPALTE(2:2)))-4;5)}
C2=VERWEIS(9^9;(--TEIL(A2;SPALTE(2:2); 6)))
D2=TEIL(A2;VERWEIS(9;1/(ISTZAHL(--(TEIL(WECHSELN(A2;" ";"#"); ZEILE($1:$256); 5)))); SPALTE(1:1)); 5)
B3{=TEIL(A3;MAX(WENN(ISTZAHL(TEIL(A3;SPALTE(3:3); 1)*1); SPALTE(3:3)))-4;5)}
C3=VERWEIS(9^9;(--TEIL(A3;SPALTE(3:3); 6)))
D3=TEIL(A3;VERWEIS(9;1/(ISTZAHL(--(TEIL(WECHSELN(A3;" ";"#"); ZEILE($1:$256); 5)))); SPALTE(2:2)); 5)
Enthält Matrixformel:
Umrandende { } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
Matrix verstehen


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Gruß Werner
.. , - ...

Anzeige
die Sachsen kann man formatieren
26.06.2008 11:51:52
WF
Moin Werner,
bedingte Formatierung bei Rudi: 00000
alle Lösungen gehen aber in die Hose, wenn der string mit einer Zahl endet.
Salut WF

so ist es Walter, Gruß Werner .. , - ... (kwT)
26.06.2008 11:56:00
neopa

Ha, ich habs ...
26.06.2008 12:00:19
neopa
... einfach z.B:
=VERWEIS(9^9;(--TEIL(A1&"'#";SPALTE(1:1);6)))
Gruß Werner
.. , - ...

Anzeige
hatten sich zwei Zeichen ...
26.06.2008 12:05:00
neopa
Hallo Walter und Rudi,
... zuviel eingeschmuggelt:
z.Zt. kürzeste Fassung: =VERWEIS(9^9;(--TEIL(A2&"#";ZEILE(A:A);6)))
und anzumerken ist noch, dass die Grundidee von Rudi stammt.
Gruß Werner
.. , - ...

AW: hatten sich zwei Zeichen ...
26.06.2008 12:14:04
Rudi
und noch zu viele Klammern (bei mir auch)
=VERWEIS(9^9;--TEIL(A2&"#";ZEILE(A:A);6))
Gruß
Rudi

Anzeige
war eben eine echte Klammerei ;-) ... (kWT)
26.06.2008 12:21:00
neopa

das landet auf unserer Seite
26.06.2008 12:26:39
WF
.

das landet auf unserer Seite, WOW!
26.06.2008 12:42:00
Rudi
ich werd' berühmt!
Hätte nicht gedacht, dass ich mal ne Formel bastele, die eurer würdig ist.
Danke.

Anzeige
AW: das landet auf unserer Seite, WOW!
26.06.2008 12:44:00
Gordon
Äh,
da stelle ich 'ne Frage und schaue später nach und ihr habt dann daraus 'ne Doktorarbeit gemacht! ;-)
Aber ich hab jetzt ziemlich die Übersicht verloren. Mag mir also jemand meine Ausgangsfrage beantworten? Wäre sehr dankbar. :)
Gruß
Gordon

AW: das landet auf unserer Seite, WOW!
26.06.2008 12:51:04
Rudi
Hallo,

da stelle ich 'ne Frage


Hm, wie war die noch?
Ach ja! du brauchst die PLZ.
https://www.herber.de/forum/messages/988949.html
Gruß
Rudi

Anzeige
AW: das landet auf unserer Seite, WOW!
26.06.2008 12:55:00
Gordon
Danke,
aber eigentlich wollte ich die Postion/Stelle der PLZ in einer Zelle wissen. Ob nun das Ende der PLZ oder der Anfang der PLZ ist für mich egal...
Beste Grüße
Gordon

AW: das landet auf unserer Seite, WOW!
26.06.2008 13:10:54
Rudi
Hallo,
dann bastel dir doch noch ein FINDEN() drumrum.
Oder mit Matrix:
{=VERGLEICH(WAHR;ISTZAHL(TEIL(A1;SPALTE(1:20);6)*1);0)}
ist die 1. Leerstelle hinter der Hausnummer.
Gruß
Rudi

Anzeige
AW: das landet auf unserer Seite, WOW!
26.06.2008 13:59:01
Gordon
Ich danke....

AW: sehr schön, aber ...
26.06.2008 12:02:03
Rudi
Hallo,
was sind Sachsen? Der Plural von Saxofon? ;-)
Mit 0 vorne und falls das letzte Zeichen eine Zahl ist:
{=TEXT(VERWEIS(9^9;(--TEIL(A1&"!";SPALTE(1:1);6)));"00000")}
Gruß
Rudi

aber mit der kleinen Zusatzidee "&"
26.06.2008 12:16:46
neopa
Hallo Rudo,
... war ich diesmal einen Tick schneller ;-)
Nun erklär mir aber mal, warum Du so klammerst. Das {} ist doch hier doppelt gemoppelt oder hab ich noch etwas übersehen?
Gruß Werner
.. , - ...

Anzeige
AW: aber mit der kleinen Zusatzidee "&"
26.06.2008 12:26:02
Rudi
Hallo,

Das {} ist doch hier doppelt gemoppelt


in der Tat! War so auf Matrix, dass ich das gar nicht erst ohne{} probiert habe.
Das Ergebnis der Seminararbeit:


=TEXT(VERWEIS(9^9;--TEIL(A1&"!";SPALTE(1:1);6));"00000")


Gruß
Rudi

Anzeige
;
Anzeige
Anzeige

Infobox / Tutorial

Excel: Finde Werte von Rechts

Schritt-für-Schritt-Anleitung

Um in Excel Werte von rechts zu finden, kannst Du die Kombination von VERWEIS und FINDEN nutzen. Die folgende Formel zeigt, wie Du das erste Leerzeichen von rechts in einer Zelle ermitteln kannst:

=VERWEIS(9^99;FINDEN(" ";A1;ZEILE(1:15)))
  1. Gib einen Text in Zelle A1 ein. Beispiel: abc defg hi
  2. Füge die oben genannte Formel in eine andere Zelle ein.
  3. Drücke die Eingabetaste. Du erhältst die Position des ersten Leerzeichens von rechts.

Achte darauf, dass die Formel in einer Excel-Version funktioniert, die diese Funktionen unterstützt.

Häufige Fehler und Lösungen

  • Fehler: #WERT!

    • Lösung: Achte darauf, dass der Text in der Zelle tatsächlich Leerzeichen enthält. Wenn nicht, wird dieser Fehler angezeigt.

  • Fehler: Formel funktioniert nicht

    • Lösung: Stelle sicher, dass Du die Formel korrekt eingegeben hast und dass die Zellreferenz stimmt (z.B. A1).

  • Leistungsprobleme bei großen Datenmengen

    • Lösung: Reduziere den Bereich in der Formel von ZEILE(A:A) auf ZEILE(1:100) oder eine andere sinnvolle Grenze.

Alternative Methoden

Eine andere Möglichkeit, um Werte von rechts zu finden, ist die Verwendung von TEIL und MAX. Hier ist eine Array-Formel, die die Position der PLZ in einer Adresse findet:

{=MAX(WENN(ISTZAHL(TEIL(A1;SPALTE(1:1);1)*1);SPALTE(1:1)))+1}

Um diese Formel einzugeben, musst Du sie mit Strg + Shift + Enter abschließen, damit sie als Array-Formel erkannt wird.

Praktische Beispiele

Hier sind einige praktische Beispiele, wie Du die Formeln in Excel anwenden kannst:

  1. Finde das letzte Leerzeichen in einer Adresse:

    • Text: ABC-Strasse 31 a 12345 Bad Musterland
    • Formel: =VERWEIS(9^9;FINDEN(" ";A1;SPALTE(1:20)))

  2. Bestimme die Position der PLZ in einer Adresse:

    • Verwende die Array-Formel aus dem vorherigen Abschnitt, um die PLZ aus einer Adresse zu extrahieren.

Tipps für Profis

  • Verwende die Funktion FINDEN in Kombination mit TEXT:

    • Du kannst die TEXT-Funktion verwenden, um sicherzustellen, dass die Ergebnisse immer im gewünschten Format angezeigt werden.

  • Vermeide zu große Bereiche:

    • Wenn Du FINDEN in großen Bereichen nutzt, kann es die Performance beeinträchtigen. Setze sinnvolle Grenzen wie 1:100 statt A:A.

  • Teste Deine Formeln:

    • Nutze die F9-Taste, um Teilergebnisse zu sehen und die Funktionsweise Deiner Formeln besser zu verstehen.

FAQ: Häufige Fragen

1. Kann ich die Formel auch für andere Zeichen als Leerzeichen verwenden?
Ja, Du kannst das Zeichen, nach dem Du suchst, in der Formel anpassen. Ändere einfach " " in das gewünschte Zeichen.

2. Was mache ich, wenn meine Daten viele Leerzeichen enthalten?
In diesem Fall solltest Du sicherstellen, dass Deine Formeln die zusätzlichen Leerzeichen berücksichtigen. Möglicherweise ist eine zusätzliche Bereinigung der Daten erforderlich.

3. Funktioniert das auch in älteren Excel-Versionen?
Ja, die meisten der verwendeten Funktionen wie VERWEIS und FINDEN sind in den meisten Excel-Versionen verfügbar. Achte jedoch darauf, dass die Formeln korrekt eingegeben werden.

Beliebteste Forumthreads (12 Monate)

Jetzt das Excel-Portal bewerten: Deine Stimme zählt!
Anzeige
Anzeige
Entdecke mehr
Finde genau, was du suchst

Die erweiterte Suchfunktion hilft dir, gezielt die besten Antworten zu finden

Suche nach den besten Antworten
Unsere beliebtesten Threads

Entdecke unsere meistgeklickten Beiträge in der Google Suche

Top 100 Threads jetzt ansehen
Anzeige