Microsoft Excel

Herbers Excel/VBA-Archiv

Informationen und Beispiele zum Thema InputBox
BildScreenshot zu InputBox InputBox-Seite mit Beispielarbeitsmappe aufrufen
Informationen und Beispiele zum Thema MsgBox
BildScreenshot zu MsgBox MsgBox-Seite mit Beispielarbeitsmappe aufrufen

Werte flexibel kopieren | Herbers Excel-Forum


Betrifft: Werte flexibel kopieren von: Christian
Geschrieben am: 01.12.2009 11:17:40

Folgendes Problem:
Ich habe in diversen Zellen Inhalte stehen, welchen ich vorher über ein Makro ermittelt habe.

Dieser Inhalt, welcher nun nicht editierbar ist möchte ich von dieser Zelle in eine andere kopieren, so das ich diesen Inhalt nun editieren kann.

Ich könnte jetzt jedesmal "von Hand" - kopieren - Inhalte einfügen - Werte ausführen, was aber umständlich ist und lange dauert.

Ich bräuchte da ein flexibles Makro wo ich "von" "nach" vorgeben kann, z.B =Wert ("Wert" Name des Makro) B26 (Zelle "von" in welcher der nicht editierbare Inhalt steht) F30 (Zelle "nach" in welcher dann der editierbare Inhalt steht)

Hatte jemand schon einmal diese "Problem" und eine Lösung ?

Viele Grüße
Christian

  

Betrifft: AW: Werte flexibel kopieren von: fcs
Geschrieben am: 01.12.2009 14:44:04

Hallo Christian,

hier eine Lösung mit Auswahl via Input-Box
Es können bis zum Abbrechen mehrere Kopiervorgänge nach einander durchgeführt werden.

Gruß
Franz

Sub aaWert()
  Dim Zelle_von As Range, Zelle_nach As Range
  On Error GoTo Fehler
  Set Zelle_von = ActiveCell
Auswahl_von:
  Set Zelle_von = Application.InputBox(Prompt:="Bitte Zelle ""von"" wählen", _
    Title:="Werte übertragen - Auswahl VON-Zelle", _
    Default:=Zelle_von.Address, _
    Type:=8).Range("A1")
Auswahl_nach:
  Set Zelle_nach = Application.InputBox(Prompt:="Bitte Zelle ""nach"" wählen", _
    Title:="Werte übertragen - Auswahl NACH-Zelle", _
    Default:="", _
    Type:=8).Range("A1")
  Zelle_nach.Value = Zelle_von.Value
  Set Zelle_nach = Nothing
  GoTo Auswahl_von
  Err.Clear
Fehler:
  With Err
    Select Case .Number
      Case 0 'kein Fehler
      Case 424 'Application.Inputbox wurde abgebrochen mit Type=8 wurde abgebrochen
      Case 1004 'geschützte Zelle wurde als Ziel gewählt
        MsgBox "Geschützte Zelle wurde als Ziel gewählt, bitte ander Zelle wählen!"
        Resume Auswahl_nach
      Case Else
        MsgBox "Fehler-Nr.: " & .Number & vbLf & .Description
    End Select
  End With
End Sub



  

Betrifft: AW: Werte flexibel kopieren von: Christian
Geschrieben am: 01.12.2009 16:03:02

Hallo Franz !

Genau das was ich gesucht habe !

Vielen Dank

Christian


Beiträge aus den Excel-Beispielen zum Thema "Werte flexibel kopieren"