exakter Zelleninhalt suchen | Herbers Excel-Forum

Forumthread: exakter Zelleninhalt suchen

exakter Zelleninhalt suchen

22.01.2010 09:08:55

Timothy

Morgen miteinander,
für mich ein Problem, für euch wahrscheinlich ein Kinderspiel ;);)
Ich suche in einem Sheet einen genauen vorgegebenen Wert:
In Zeile 1 stehen z.B. in Spalte 1 "BLB", in Spalte 2 "LB", in Spalte 3"BEB", in Spalte 9 "EB",.....
Wenn ich jetzt nach "LB" suche, wird bei mir die Spalte 1 mit "BLB" gefunden!
Kann ich auch nach dem exakten Wert in einer Spalte suchen, also hier z.B. "LB"?
Wäre über eure Hilfe sehr dankbar!
Viele Grüße

Dim RowLB As Long
Dim ColLB As Integer
Dim SuchStrLB As String
SuchStrLB = "LB" 'Suchbegriff
ColLB = Cells(1, 1).End(xlToRight).Column 'Suchspalte
RowLB = 1 'Suchzeile
For ColLB = 1 To Cells(1, 1).End(xlToRight).Column
If InStr(Cells(RowLB, ColLB), SuchStrLB) <> 0 Then
Cells(RowLB, ColLB).Activate
MsgBox SuchStr & " gefunden in " & Cells(RowLB, ColLB).Address   'mach was draus
Exit For
End If
Next
If InStr(Cells(RowLB, ColLB), SuchStrLB) = 0 Then
MsgBox "" & SuchStrLB & " nicht gefunden. Bitte überprüfen ob " & SuchStrLB & " in   _
_
erster Zeile definiert und keine leere Zellen vorhanden sind!"
Exit Sub
End If

3
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: exakter Zelleninhalt suchen

22.01.2010 09:19:25

Hajo_Zi
verwende doch die Suchfunktion

22.01.2010 09:28:12

Tino
AW: verwende doch die Suchfunktion

22.01.2010 09:45:15

Timothy

AW: exakter Zelleninhalt suchen

22.01.2010 09:19:25

Hajo_Zi

Hallo Timothy,
benutze FIND()

Sub Find_mehrmals()
'* H. Ziplies                                    *
'* 24.11.08                                      *
'* erstellt von HajoZiplies@WEB.de              *
'* http://Hajo-Excel.de
Dim RaFound As Range
Dim FirstAddress As String
Dim Search As String
Dim LoLetzte As Long
Dim LoI As Long
Dim ByMldg As Byte
Search = Worksheets("Tabelle2").Range("A1")
With Worksheets("Tabelle1")
LoLetzte = IIf(IsEmpty(.Range("A65536")), .Range("A65536").End(xlUp).Row, 65536)
'   von Peter Haserodt
Set RaFound = .Range("A1:A" & LoLetzte).Find(Search, .Range("A" & LoLetzte), ,  _
xlWhole, , xlNext)
If RaFound Is Nothing Then Exit Sub  'falls nicht gefunden wird sub verlassen
If MsgBox("Gefunden in Zelle " & RaFound.Address(0, 0) & " ist dies richt richtige  _
Zelle !!!" _
, vbYesNo + vbQuestion, "Abfrage") = 6 Then
RaFound.Interior.ColorIndex = 3
Else
FirstAddress = RaFound.Address
Do
Set RaFound = .Range("A1:A" & LoLetzte).FindNext(RaFound)
If RaFound.Address = FirstAddress Then Exit Sub
If MsgBox("Gefunden in Zelle " & RaFound.Address(0, 0) & " ist dies richt  _
richtige Zelle !!!" _
, vbYesNo + vbQuestion, "Abfrage") = 6 Then
RaFound.Interior.ColorIndex = 3
Exit Do
End If
If RaFound.Row = LoLetzte Then Exit Do
LoI = LoI + 1
Loop
End If
End With
Set RaFound = Nothing
End Sub

verwende doch die Suchfunktion

22.01.2010 09:28:12

Tino

Hallo,
verwende doch die Suchfunktion von Excel da kannst Du dies einstellen.
Zeichne es mit dem Rekorder, damit Du die richtige Syntax für die Suche bekommst.

Dim SuchStrLB As String
Dim rngRange As Range
SuchStrLB = "LB" 'Suchbegriff
Set rngRange = Rows(1).Find(What:=SuchStrLB, LookIn:=xlValues, LookAt _
:=xlWhole, SearchOrder:=xlByRows, SearchDirection:=xlNext, MatchCase:=True,  _
SearchFormat:=False)
If Not rngRange Is Nothing Then
rngRange.Select
MsgBox SuchStrLB & " gefunden in " & rngRange.Address   'mach was draus
Else
MsgBox SuchStrLB & " nicht gefunden."
End If

Gruß Tino

AW: verwende doch die Suchfunktion

22.01.2010 09:45:15

Timothy

Sehr nett....
Mit der such-Funktion klappt das ganz gut!
Danke!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
Have a nice weekend!
Grezze

Infobox / Tutorial

Schritt-für-Schritt-Anleitung

Um in Excel nach einem exakten Zelleninhalt zu suchen, kannst du die Funktion Find() verwenden. Hier ist eine einfache Anleitung:

Öffne dein Excel-Dokument und gehe zu dem Arbeitsblatt, in dem du suchen möchtest.
Drücke ALT + F11, um den VBA-Editor zu öffnen.
Füge ein neues Modul hinzu durch Rechtsklick auf VBAProject > Einfügen > Modul.

Füge den folgenden Code ein:

Sub SucheExakt()
    Dim SuchStrLB As String
    Dim rngRange As Range
    SuchStrLB = "LB" ' Suchbegriff
    Set rngRange = Rows(1).Find(What:=SuchStrLB, LookIn:=xlValues, LookAt:=xlWhole, SearchOrder:=xlByRows, SearchDirection:=xlNext, MatchCase:=True, SearchFormat:=False)

    If Not rngRange Is Nothing Then
        rngRange.Select
        MsgBox SuchStrLB & " gefunden in " & rngRange.Address
    Else
        MsgBox SuchStrLB & " nicht gefunden."
    End If
End Sub

Führe das Makro aus, um nach dem exakten Wert in der ersten Zeile zu suchen.

Häufige Fehler und Lösungen

Fehler: Der Suchbegriff wird nicht gefunden
- Lösung: Stelle sicher, dass der Suchbegriff korrekt eingegeben wurde und in der ersten Zeile vorhanden ist. Achte auf Groß- und Kleinschreibung, wenn MatchCase auf True gesetzt ist.
Fehler: Falsche Zelle wird ausgewählt
- Lösung: Überprüfe, ob LookAt auf xlWhole gesetzt ist, um nur exakte Übereinstimmungen zu finden.

Alternative Methoden

Eine andere Möglichkeit, exakte Werte zu suchen, besteht darin, die integrierte Suchfunktion von Excel zu verwenden:

Drücke Strg + F, um das Suchfenster zu öffnen.
Gib deinen Suchbegriff ein und klicke auf „Optionen“.
Wähle „Exakt“ unter „Suchen in“ und aktiviere die Option „Groß-/Kleinschreibung beachten“, wenn nötig.

Praktische Beispiele

Hier sind einige Beispiele, die dir helfen können:

Wenn du nach „BLB“ suchst, aber nur „LB“ gefunden werden soll, achte darauf, dass du in der Suchfunktion die Optionen korrekt einstellst, um nur exakte Übereinstimmungen zu finden.

Search = Worksheets("Tabelle2").Range("A1") ' Hier wird der Suchbegriff aus einer anderen Tabelle verwendet

Du kannst auch mehrere Suchbegriffe nacheinander suchen, indem du eine Schleife einbaust.

Tipps für Profis

Verwende die VBA-Entwicklerumgebung, um komplexere Suchalgorithmen zu erstellen, die mehrere Spalten oder Zeilen durchsuchen.
Nutze Application.Match, um zu prüfen, ob dein Suchbegriff in einem bestimmten Bereich vorhanden ist, ohne die Zellen manuell zu durchsuchen.

Dim Ergebniss As Variant
Ergebniss = Application.Match(SuchStrLB, Range("A1:A10"), 0) ' Gibt die Position des Suchbegriffs zurück

FAQ: Häufige Fragen

1. Wie kann ich nach mehreren Werten gleichzeitig suchen?
Du kannst eine Schleife verwenden, um durch eine Liste von Suchbegriffen zu iterieren und jeden Wert nacheinander zu suchen.

2. Was mache ich, wenn ich nach einem Wert in einer anderen Zeile suchen möchte?
Ändere einfach die Zeilenangabe in deinem VBA-Code, z.B. Rows(2).Find(...) für die zweite Zeile.

3. Gibt es eine Möglichkeit, die Suchergebnisse zu markieren?
Ja, du kannst die Hintergrundfarbe der gefundenen Zelle ändern, indem du RaFound.Interior.ColorIndex = 3 verwendest, um die Zelle rot zu markieren.

Beliebteste Forumthreads (12 Monate)