Textbox und Barcode Scanner

Forumthread: Textbox und Barcode Scanner

05.09.2014 08:02:29

Markus

Guten Morgen ich habe folgendes Problem,
ich hätte gerne über einen Barcode Scanner meine Lager Tabelle gepflegt.
Leider hab ich das Ergebnis bis jetzt nur bedingt umsetzen können.
Es sollte so sein das über einen Option Button hinzufügen oder entnehmen angewählt wird und dann ein Barcode gescannt wird die ID Nr. aus dem Barcode (beginnt mit 10001)wird in Eine versteckte Textbox in der Userform geschrieben und soll in Spalte U gesucht werden und dann aus derselben Zeile in Spalte N der Bestand geändert werden.
Falls in Spalte N "Alt" steht soll eine Msg Box mit einer Nachricht aufgehen.
Leider bekomme ich es nicht hin das In Spalte U gesucht wird, im Moment Zähle ich die Zeilen, dass funktioniert allerdings nur Solange bis ein neuer Artikel eingepflegt wird.
Ich hoffe mir kann jemand Helfen.
Mfg
Markus
p.s. mein bisheriger Code
Option Explicit
Dim barc As Integer
Dim entn As Integer

Private Sub OptionButton1_Click()
TextBox1.SetFocus
End Sub

Private Sub OptionButton2_Click()
TextBox1.SetFocus
End Sub

Private Sub TextBox1_KeyDown(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)
TextBox1.SetFocus
If KeyCode = 13 Then
barc = TextBox1.Value
TextBox1.Text = ""
With ActiveCell
End With
Sheets("Regalordnung").Activate
If Tabelle2.Cells(barc + 2, 14).Value = "Alt" Then
MsgBox "Altes Bauteil kein Bestand hinterlegt"
Exit Sub
End If
If OptionButton1.Value = True Then
Tabelle2.Cells(barc + 2, 14).Value = Tabelle2.Cells(barc + 2, 14).Value - Val(1)
If Tabelle2.Cells(barc + 2, 14).Value = 0 Then
MsgBox "Achtung Bestand aufgebraucht! Ersatz bestellen", , "Warnung"
End If
End If
If OptionButton2.Value = True Then
Tabelle2.Cells(barc + 2, 14).Value = Tabelle2.Cells(barc + 2, 14).Value + Val(1)
End If
End If
End Sub


Private Sub CommandButton1_Click()
Unload Me
End Sub

3
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Textbox und Barcode Scanner

05.09.2014 11:46:18

fcs
AW: Textbox und Barcode Scanner

05.09.2014 12:28:16

Markus
AW: Textbox und Barcode Scanner

05.09.2014 13:53:44

fcs

AW: Textbox und Barcode Scanner

05.09.2014 11:46:18

fcs

Hallo Markus,
zum Einlesen des per Barcode in eine Textbox kann ich dir nichts schreiben.
Soweit ich weiss schreibt die Scanner-Software den gescannten Wert meistens in eine Zelle in xcel.
Den Code hab ich jetzt mal so angepasst, dass der in Textbox1 eingegebene Barcode/ID nach drücken der Enter-Taste in Spalte U gesucht wird und abhängig vom Ergebnis bestimmte Aktionen ausgeführt werden.
Das muss du dann ggf. noch an deine Tabelle(n) anpassen.
Gruß
Franz

Option Explicit
Dim barc As Long
Dim entn As Integer
Dim Zeile As Long
Private Sub OptionButton1_Click()
TextBox1.SetFocus
End Sub
Private Sub OptionButton2_Click()
TextBox1.SetFocus
End Sub
Private Sub TextBox1_KeyDown(ByVal KeyCode As MSForms.ReturnInteger, _
ByVal Shift As Integer)
Dim wksRegal As Worksheet, Zelle As Range, Zeile_1 As Long
TextBox1.SetFocus
If KeyCode = 13 Then
barc = TextBox1.Value
Set wksRegal = Sheets("Regalordnung")
With wksRegal
'letzte Zeile mit Daten in Spalte U
Zeile_1 = 2 'Nummer der Zeile mit Spaltentiteln/Zeile oberhalb der 1. ID-Nummer
Zeile = .Cells(.Rows.Count, 21).End(xlUp).Row
Set Zelle = Nothing
If Zeile > Zeile_1 Then 'es gibt schon ID-Nummern
Set Zelle = .Range(.Cells(Zeile_1 + 1, 21), .Cells(Zeile, 21)).Find(what:=barc, _
LookIn:=xlValues, lookat:=xlWhole)
Else
Zeile = Zeile_1
End If
If Zelle Is Nothing Then
'ID existiert noch nicht
Zeile = Zeile + 1
If MsgBox("ID """ & barc & """ ist noch nicht vorhanden. ID jetzt anlegen?", _
vbQuestion + vbOKCancel, "Unbekannte ID") = vbOK Then
.Cells(Zeile, 21).Value = barc
.Cells(Zeile, 14).Select
.Cells(Zeile, 14).Value = Application.InputBox("Anfangsbestand:", "Neue ID", 1, _
Type:=1)
Else
Exit Sub
End If
Else
'ID-gefunden
Zeile = Zelle.Row
Cells(Zeile, 14).Select
If .Cells(Zeile, 14).Value = "Alt" Then
MsgBox "Altes Bauteil kein Bestand hinterlegt"
Else
If OptionButton1.Value = True Then
.Cells(Zeile, 14).Value = .Cells(Zeile, 14).Value - 1
If .Cells(Zeile, 14).Value = 0 Then
MsgBox "Achtung Bestand aufgebraucht! Ersatz bestellen", , "Warnung"
End If
ElseIf OptionButton2.Value = True Then
.Cells(Zeile, 14).Value = .Cells(Zeile, 14).Value + 1
Else
MsgBox "Es wurde keine der Optionen Entnehmen/Einlagern gewählt!"
End If
End If
End If
TextBox1.Text = ""
End With
End If
End Sub
Private Sub CommandButton1_Click()
Unload Me
End Sub

AW: Textbox und Barcode Scanner

05.09.2014 12:28:16

Markus

Hallo Franz,
danke erstmal für die schnelle Hilfe.
Der Scanner schreibt dahin wo der Cursor gerade Aktiv ist und daher in die Textbox wenn man die Userform startet.
Soweit funktioniert fast alles perfekt komischerweise will er aber immer bei den ID´s mit mit 4 und 9 am ende (10004, 1009, 10014 usw.) eine neue ID anlegen

AW: Textbox und Barcode Scanner

05.09.2014 13:53:44

fcs

Hallo Markus,
sas Problem mit Endziffer 4 und 9 kann ich jetzt nicht nachvollziehen.
Möglichkeit 1:
Der Scanner produziert beim Einlesen von 4 und 9 noch iregendwelche myteriösen Zeichen.
Eher unwahrscheinlich, denn dann müsste es Fehlermeldungen beim Zuweisen des Textbox-Inhalts an die Variable barc geben.
Möglichkeit 2: In der Tabelle sind in Spalte U bei den Einträgen mit Endziffer 4 und 9 noch unsichtbare Zeichen enthalten (z.B. führende/nachgetellte Leerzeichen).
In diesem Fall ersetze via Suchen/Ersetzen die Leerzeichen in dem Zellbereich der ID-Nummern durch nichts.
Möglichkeit 3: In der Tabelle ist in Spalte U bei den Einträgen mit Endziffer 4 und 9 Buchstabe O statt 0 eingetragen.
Weiter reicht meine Phantasie bei diesem Problem nicht.
Gruß
Franz

Infobox / Tutorial

Barcode Scanner in Excel einbinden und nutzen

Schritt-für-Schritt-Anleitung
Häufige Fehler und Lösungen
Alternative Methoden
Praktische Beispiele
Tipps für Profis
FAQ: Häufige Fragen

Schritt-für-Schritt-Anleitung

Vorbereitung der Excel-Datei
- Erstelle eine neue Excel-Datei oder öffne eine bestehende, die Deine Lagerverwaltung enthält.
- Stelle sicher, dass Du eine Tabelle hast, in der die Barcode-IDs in Spalte U und der Bestand in Spalte N stehen.
Einrichten der Userform
- Öffne den VBA-Editor (Alt + F11) und füge eine neue Userform hinzu.
- Füge eine Textbox (TextBox1) hinzu, um den Barcode einzulesen.
- Füge zwei Optionsfelder hinzu: eines für "Hinzufügen" und eines für "Entnehmen".

VBA-Code einfügen

Verwende den folgenden Code, um die Barcode-IDs zu verarbeiten:

Option Explicit
Dim barc As Long
Dim Zeile As Long

Private Sub OptionButton1_Click()
   TextBox1.SetFocus
End Sub

Private Sub OptionButton2_Click()
   TextBox1.SetFocus
End Sub

Private Sub TextBox1_KeyDown(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)
   Dim wksRegal As Worksheet, Zelle As Range
   Set wksRegal = Sheets("Regalordnung")

   If KeyCode = 13 Then ' Enter-Taste
       barc = TextBox1.Value
       Set Zelle = wksRegal.Range("U:U").Find(what:=barc, LookIn:=xlValues, lookat:=xlWhole)

       If Zelle Is Nothing Then
           MsgBox "ID """ & barc & """ nicht gefunden. Bitte ID anlegen."
       Else
           Zeile = Zelle.Row
           If wksRegal.Cells(Zeile, 14).Value = "Alt" Then
               MsgBox "Altes Bauteil, kein Bestand hinterlegt"
           ElseIf OptionButton1.Value Then
               wksRegal.Cells(Zeile, 14).Value = wksRegal.Cells(Zeile, 14).Value - 1
           ElseIf OptionButton2.Value Then
               wksRegal.Cells(Zeile, 14).Value = wksRegal.Cells(Zeile, 14).Value + 1
           End If
       End If
       TextBox1.Text = ""
   End If
End Sub

Private Sub CommandButton1_Click()
   Unload Me
End Sub

Barcode Scanner einrichten
- Verbinde Deinen Barcode Scanner mit dem Computer. Der Scanner sollte so konfiguriert sein, dass er die gescannten Daten direkt in die Textbox schreibt.
Testen der Funktionalität
- Scanne einen Barcode und prüfe, ob die Daten korrekt in Excel eingelesen werden und die entsprechenden Aktionen ausgeführt werden.

Häufige Fehler und Lösungen

Problem: ID wird nicht gefunden
- Überprüfe, ob die ID korrekt in der Tabelle steht. Achte auf unsichtbare Zeichen oder Leerzeichen.
Problem: Alte Bauteile werden nicht erkannt
- Stelle sicher, dass in Spalte N der entsprechende Status ("Alt") korrekt vermerkt ist.
Problem: Neue ID wird automatisch angelegt
- Überprüfe die Logik im Code, insbesondere die Zeile, die nach dem Scannen sucht. Achte darauf, dass keine zusätzlichen Zeichen im Barcode vorhanden sind.

Alternative Methoden

Barcode in Excel scannen ohne VBA
- Wenn Du keine VBA-Programmierung verwenden möchtest, kannst Du auch eine Barcode-Scanner-Software für Excel verwenden, die die Daten direkt in die gewünschten Zellen einfügt.
QR-Code scannen und in Excel einfügen
- Verwende eine App, um QR-Codes zu scannen, und kopiere die Daten dann manuell in Excel.

Praktische Beispiele

Beispiel 1: Lagerbestand aktualisieren
- Scanne den Barcode eines Artikels, der in der Tabelle vermerkt ist. Die Anzahl in Spalte N wird entsprechend angepasst.
Beispiel 2: Neue Artikel anlegen
- Wenn Du einen Barcode scannst, der nicht in der Tabelle vorhanden ist, wird eine Abfrage angezeigt, um einen neuen Artikel hinzuzufügen.

Tipps für Profis

Verwende die richtige Formatierung
- Achte darauf, dass die Zellen in Spalte U und N richtig formatiert sind, um Fehler zu vermeiden.
Barcode Scanner Software für Excel
- Es gibt spezialisierte Softwarelösungen, die das Barcode scannen in Excel erleichtern und zusätzliche Funktionen bieten.
Optimierung des Codes
- Überlege, den VBA-Code weiter zu optimieren, um die Performance zu steigern, insbesondere bei großen Datensätzen.

FAQ: Häufige Fragen

1. Wie kann ich mehrere Barcodes gleichzeitig scannen?
Du kannst mehrere Barcodes nacheinander scannen, indem Du nach jedem Scan die Enter-Taste drückst.

2. Was tun, wenn der Barcode Scanner nicht funktioniert?
Überprüfe die Verbindung und die Einstellungen des Scanners. Stelle sicher, dass er korrekt mit Excel kommuniziert.

3. Kann ich auch andere Barcodetypen verwenden?
Ja, der Barcode Scanner sollte in der Lage sein, verschiedene Typen von Barcodes zu lesen, solange sie im richtigen Format vorliegen.

4. Wie kann ich sicherstellen, dass keine unsichtbaren Zeichen in den IDs sind?
Verwende die Funktion "Suchen und Ersetzen" in Excel, um Leerzeichen und andere unsichtbare Zeichen zu entfernen.

Beliebteste Forumthreads (12 Monate)

Forumthread: Textbox und Barcode Scanner

3 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Infobox / Tutorial

Barcode Scanner in Excel einbinden und nutzen

Schritt-für-Schritt-Anleitung

Häufige Fehler und Lösungen

Alternative Methoden

Praktische Beispiele

Tipps für Profis

FAQ: Häufige Fragen

Beliebteste Forumthreads (12 Monate)

3
Beiträge zum Forumthread

Beiträge zu diesem Forumthread