Microsoft Excel

Herbers Excel/VBA-Archiv

Makro - bestimmte Zeilen eines Zeitintervalls anze

Betrifft: Makro - bestimmte Zeilen eines Zeitintervalls anze von: Sören
Geschrieben am: 05.11.2014 13:21:27

Hallo zusammen,

habe auf Arbeit folgendes Problem.

Ich habe eine Tabelle in der verschiedene Werte gespeichert werden mit dem jeweiligen Eingabedatum.

Nun möchte ich mir gerne über ein Makro nur die Zeilen anzeigen lassen, die in einem bestimmten Intervall liegen.
Z.b. vom 01.01.2014 bis 15.01.2014

Ich bin leider absoluter Anfänger was Makros angeht.
Ich habe dazu aber einen Code im Netz gefunden, mit dem ich mir Spalten anzeigen lassen, welche das Datum des Eingabefeldes enthalten:

Code:

Option Explicit



Private Sub Worksheet_Change(ByVal Target As Range)
    Dim loZeile As Long
    If Target.Address = "$X$6" Then
    Application.ScreenUpdating = False
    ActiveSheet.UsedRange.Rows.Hidden = False
    If Target <> "" Then
    For loZeile = ActiveSheet.UsedRange.SpecialCells(xlCellTypeLastCell).Row To 6 Step -1
    Cells(loZeile, 1).EntireRow.Hidden = Application.CountIf(Rows(loZeile), Target) = 0
    Next loZeile
    End If
    Application.ScreenUpdating = True
    End If
    End Sub

Leider habe ich nicht die Möglichkeit zu sagen: Von Datum X bis Datum Y. Ich hoffe ihr versteht was ich meine. Falls es relevant ist: es gibt in der Tabelle nicht für jeden Tag des Jahres Messwerte.
Danke schonmal für eure Hilfe

  

Betrifft: AW: Makro - bestimmte Zeilen eines Zeitintervalls anze von: Hajo_Zi
Geschrieben am: 05.11.2014 13:23:27

warum nicht Autofilter?

GrußformelHomepage


  

Betrifft: AW: Makro - bestimmte Zeilen eines Zeitintervalls anze von: Sören
Geschrieben am: 05.11.2014 13:27:24

Weil es gewünscht ist, dass der Zeitintervall eingegeben werden kann

Also im Eingabefeld des Makros z.B.:
01.01.2014 - 05.01.2014


  

Betrifft: AW: Makro - bestimmte Zeilen eines Zeitintervalls anze von: Hajo_Zi
Geschrieben am: 05.11.2014 13:32:20

auch bei Autofilter gibt man den Zeitintervall an, jedenfalls soweit mir bekannt.
Autofilter kann man auch über Makro ansteuern.

GrußformelHomepage


  

Betrifft: AW: Makro - bestimmte Zeilen eines Zeitintervalls anze von: Sören
Geschrieben am: 05.11.2014 13:41:32

trotzdem ist es kompliziert, da ich jedesmal auf den filter klicken muss und einen benutzerdefinierten datumsfilter auswählen muss...
ein feld für eine eingabe wäre hilfreicher und einfacher


  

Betrifft: AW: Makro - bestimmte Zeilen eines Zeitintervalls anze von: Rudi Maintaire
Geschrieben am: 05.11.2014 13:58:20

Hallo,
Tabellenaufbau:

ABC
1vonbis 
2   
3   
4Datumxy
501. Jun8777
602. Jun7832
703. Jun5359
804. Jun8532
905. Jun7334
1006. Jun3633
1107. Jun816
1208. Jun2925
1309. Jun7331


Code:
Private Sub Worksheet_Change(ByVal Target As Range)
  Dim rngC As Range, rngH As Range
  If Not Intersect(Target, Range("A2:B2")) Is Nothing Then
    Rows.Hidden = False
    If WorksheetFunction.Count(Range("A2:B2")) = 2 Then
      For Each rngC In Range(Cells(5, 1), Cells(Rows.Count, 1).End(xlUp))
        Select Case rngC
          Case Range("A2") To Range("B2")
          Case Else
            If rngH Is Nothing Then
              Set rngH = rngC
            Else
              Set rngH = Union(rngH, rngC)
            End If
        End Select
      Next
    End If
  End If
  If Not rngH Is Nothing Then rngH.EntireRow.Hidden = True
End Sub
Gruß
Rudi


  

Betrifft: AW: Makro - bestimmte Zeilen eines Zeitintervalls anze von: Sören
Geschrieben am: 05.11.2014 14:37:30

Vielen DANK !!!!!


 

Beiträge aus den Excel-Beispielen zum Thema "Makro - bestimmte Zeilen eines Zeitintervalls anze"