Zahl aus String auslesen

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Text Ergebnis porös M30 Gewinde 893575 893575 druck 0,7bar 623866 623866 undicht 656 698 656698 beschädigt 222 922 222922 undicht 656 698 656698 7.703.493: 665571 test S/N: 15.0061: keine Funktion. 665571 7.703.405: 665571 test S/N: 12.0831: Kein Signal 665571

Text Erwartetes Ergebnis 667 411 Test 667411 842476 Bundhutmutter: Trotz 100 % 842476 241935 Zyl. Schraube ISO 4762 - 241935 test 212 764 und so weiter 212764

Zahlen ohne Leerzeichen davor werden nicht erkannt (wenn am Anfang des Strings -> meistens _ sind die Zahlen jedoch irgendwo mitten im String...) an bereits 6- oder 7-stellige Zahlen werden noch weitere angehängt sofern vorhanden

Wenn mehrere 6- oder 7-stellige Zahlen vorhanden sind, dann bitte alle 6- oder 7-stellige Zahlen mit einem Leerzeichen getrennt ausgeben -> ist sicher jetzt blöd, weil wir ja 3- oder 4-stellige Zahlen verbinden sollen...

Tabelle1

	A	B
1	porös M30 Gewinde 893575	893575
2	druck 0,7bar 623866	623866
3	undicht 656 698	656698
4	beschädigt 222 922	222922
5	undicht 656 698	656698
6	7.703.493: 665571 test S/N: 15.0061: keine Funktion.	665571
7	7.703.405: 665571 test S/N: 12.0831: Kein Signal	665571
8	code 12,000 665161	665161
9	A1234567	1234567
10	1234567asd	1234567
11	das teil 123456 asd987654 enthalten	123456 987654

Formeln der Tabelle

Zelle	Formel
B1	=getZahl(A1)

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4

' **********************************************************************
' Modul: Modul1 Typ: Allgemeines Modul
' **********************************************************************

Option Explicit

Function getZahl(ByVal myStr As String)
    Dim regEx As Object
    Dim Matches As Object
    Dim objMatch As Object
    Dim objSubMatch
    Dim strTmp As String
    Set regEx = CreateObject("Vbscript.Regexp")
    With regEx
        .Pattern = "(\d{6,7}|\d{3,4} +\d{3,4})(?=(\D|$))"
        .Global = True
        If .test(myStr) = True Then
            Set Matches = .Execute(myStr)
            For Each objMatch In Matches
                strTmp = strTmp & objMatch
            Next
            getZahl = Replace(strTmp, " ", "")
        End If
        .Pattern = "(\d{6,7}).+(\d{6,7})"
        If .test(myStr) = True Then
            Set Matches = .Execute(myStr)
            getZahl = Matches(0).submatches(0) & " " & Matches(0).submatches(1)
        End If
    End With
End Function

Aber jetzt wart ich auf ne Beispieltabelle..

* In Klammer bedeutet also immer wieviele Stellen die Zahl haben soll? * Ein Komma in der Klammer zwischen 2 Zahlen bedeutet Stellen von - bis oder? * Was bedeutet genau \ d oder | ? Bzw. was ist mit (?=(\D|$)) gemeint?

HAllo,
Tabelle1

	A	B
1	7.703.404 912iS2 test: 866261 test EGT 3 gewechselt, zeigt 1030 °C an.	866261
2	teilungsgrat 611857	611857
3	Ring fehlt 922 293	922293
4	(Plastikspan)922293	922293
5	rückstand 431 640	431640
6	porös M30 Gewinde dfdd893575	893575
7	2 druck 0,7bar 623866dddd	623866
8	3 undicht 656 698	656698
9	4 beschädigt dddd222 922	222922
10	5 undicht 656ddd 698	656698
11	4 beschädigt 222 922ggggg	222922
12	5 undicht 656 ggg698	656698
13	6 7.703.493: 665571 test S/N: 15.0061: keine Funktion.	665571
14	7 7.703.405: 665571 test S/N: 12.0831: Kein Signalgg	665571
15	8 code 12,000 665161	665161
16	9 A1234567	1234567
17	10 1234567asd	1234567
18	11 das teil 123456 asd987654 enthalten	123456 987654

Formeln der Tabelle

Zelle	Formel
B1	=getzahl(A1)

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Für deine Beispieldaten passt es.
Teste mal an deinen Daten.

' **********************************************************************
' Modul: Modul1 Typ: Allgemeines Modul
' **********************************************************************

Option Explicit

Function getZahl(ByVal myStr As String)
    Dim regEx As Object
    Dim Matches As Object
    Set regEx = CreateObject("Vbscript.Regexp")
    With regEx
        .Global = True
        .Pattern = "(\d{6,7}).+(\d{6,7})" '6-7 stellige Zahl & irgendwelche Zeichen & 6-7 stellige Zahl
        If .test(myStr) = True Then
            Set Matches = .Execute(myStr)
            getZahl = Matches(0).submatches(0) & " " & Matches(0).submatches(1)
            Exit Function
        End If

        .Pattern = "\d{6,7}(?=(\D|$))" '6-7 stellige Zahl (vor einer NichtZahl oder vor dem Ende der Eingabe)
        If .test(myStr) = True Then
            Set Matches = .Execute(myStr)
            getZahl = Matches(0).Value
            Exit Function
        End If

        .Pattern = "(\d{3,4}).+(\d{3,4})(?=(\D|$))" '(3-4stellige Zahl & irgendwelche Zeichen & 3-4 stellige Zahl)( vor einer NichtZahl oder vor dem Ende der Eingabe)
        If .test(myStr) = True Then
            Set Matches = .Execute(myStr)
            getZahl = Matches(0).submatches(0) & Matches(0).submatches(1)
        End If
    End With
End Function

'\d --Zahl
'\D -->Nichtzahl
'| -->oder
'$ -->Ende der Eingabe

Ich hab das jetzt auf 3 Pattern aufgeteilt.
Das macht einfacher.
ransi

Beliebteste Forumthreads (12 Monate)

20
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

309 Forumthreads zu ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

Zahl aus String auslesen

20 Beiträge zum Forumthread Beiträge zu diesem Forumthread

309 Forumthreads zu ähnlichen Themen

VBA Beispiele zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

20
Beiträge zum Forumthread

Beiträge zu diesem Forumthread