Live-Forum - Die aktuellen Beiträge
Datum
Titel
06.10.2025 20:14:37
Ich suche einfach erstmal nach einer Idee oder ein Demo
06.10.2025 19:15:29
Mit Uhrzeit rechnen
06.10.2025 18:25:16
Einträge einer Tabelle über Userform ändern
06.10.2025 17:03:04
Makro csv-Datei laden und Int.Tabelle anlegen
Keine passende Antwort im Forumarchiv gefunden?
Stelle deine Frage im Live-Forum
Anzeige
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Vorheriger Thread
Vorheriger Thread
Rückwärts Blättern
1776to1780
1776to1780
Aktuelles Verzeichnis
Verzeichnis Übersicht
Verzeichnis Übersicht
Übersicht Verzeichnisse
Nächster Thread
Nächster Thread
Vorwärts blättern
Inhaltsverzeichnis

Combobox

Forumthread: Combobox

Combobox
20.08.2020 09:12:37
Tim
Guten Morgen miteinander,
mal wieder habe ich ein kleines Problem.
Wir haben gemeinsam eine Userform gebaut und funktioniert soweit, bis auf ein Thema:
Wir haben eine Combox_Typ ( Tabellenblatt :Daten, Spalte A ) und dann wollen wir wenn eine Auswahl getroffen ist das in Combox_Marke ( Tabellenblatt :Daten, Spalte J) und Textbox_Farbe ( (Tabellenblatt :Daten, Spalte K) gefüllt wird.
Und das gleiche dann umgekehrt. Wähle ich Combox_Marke aus muss Combox_Typ und Textbox_Farbe gefüllt werden.
Manchmal bekommen wir den Typen und manchmal die Marke der Farbe am telefon beschrieben.
Wäre sowas möglich ?
Danke
Gruß Tim
Anzeige

8
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: Combobox
20.08.2020 09:41:50
Nepumuk
Hallo Tim,
Wäre sowas möglich ?
Eindeutig ja. Aber eine Mustermappe mit dem UserForm wäre hilfreich.
Gruß
Nepumuk
Bitte Beispielmappe bereitstellen - o.T.
20.08.2020 09:43:21
Beverly

AW: Bitte Beispielmappe bereitstellen - o.T.
20.08.2020 10:31:43
Tim
Hallo,
danke, leider darf ich hier in der Arbeit nicht hochladen.
Dachte evt. das ihr so hinbekommt.
Dankeschööööön :-)
Anzeige
AW: Bitte Beispielmappe bereitstellen - o.T.
20.08.2020 10:51:51
Beverly
Hi,
man kann eine Mappe auch anonymisieren und anstelle der realen Daten Dummy-Daten verwenden... Außerdem braucht die Mappe nur die für das Problem relevanten Dinge zu enthalten.

AW: Bitte Beispielmappe bereitstellen - o.T.
20.08.2020 12:42:11
Tim
Hallo, :-)
ja ich vesuche Später die Datei hochzuladen.
Es wäre halt wie eine Art INDEX(VERGLEICH Formel.
Danke
Anzeige
AW: Bitte Beispielmappe bereitstellen - o.T.
20.08.2020 12:58:50
TIM
Hallo
Ich war schnell zu Hause und hab es geladen.
https://www.herber.de/bbs/user/139726.xlsm
Ich hoffe ihr könnt es mal anschauen ubd helfen.
Danke
AW: Bitte Beispielmappe bereitstellen - o.T.
20.08.2020 13:48:53
Nepumuk
Hallo Tim,
teste mal:
Option Explicit

Private mblnNoEvent As Boolean

Private Sub ComboBox_Marke_Change()
    If Not NoEvent Then
        ComboBox_Typ.Text = ComboBox_Typ.List(ComboBox_Marke.ListIndex)
        TextBox_Farbe.Value = Worksheets("Daten").Cells(ComboBox_Marke.ListIndex + 2, 11).Text
    End If
End Sub

Private Sub ComboBox_Typ_Change()
    If Not NoEvent Then
        ComboBox_Marke.Text = ComboBox_Marke.List(ComboBox_Typ.ListIndex)
        TextBox_Farbe.Value = Worksheets("Daten").Cells(ComboBox_Typ.ListIndex + 2, 11).Text
    End If
End Sub

Private Sub CommandButton1_Click()
    Call Unload(Object:=Me)
End Sub

Private Sub TextBox_Farbe_Change()
    Dim objCell As Range
    If TextBox_Farbe.TextLength > 0 Then
        Set objCell = Worksheets("Daten").Columns(11).Find(What:=TextBox_Farbe.Text & "*", _
            LookIn:=xlValues, LookAt:=xlWhole, MatchCase:=False)
        If Not objCell Is Nothing Then
            NoEvent = True
            ComboBox_Typ.Text = ComboBox_Typ.List(objCell.Row - 2)
            ComboBox_Marke.Text = ComboBox_Marke.List(objCell.Row - 2)
            NoEvent = False
            Set objCell = Nothing
        Else
            NoEvent = True
            ComboBox_Typ.ListIndex = -1
            ComboBox_Marke.ListIndex = -1
            NoEvent = False
        End If
    Else
        NoEvent = True
        ComboBox_Typ.ListIndex = -1
        ComboBox_Marke.ListIndex = -1
        NoEvent = False
    End If
End Sub

Private Sub UserForm_Initialize()
    Dim lngLastRow As Long
    With Worksheets("Daten")
        lngLastRow = .Cells(.Rows.Count, 1).End(xlUp).Row
        ComboBox_Typ.List = .Range(.Cells(2, 1), .Cells(lngLastRow, 1)).Value2
        ComboBox_Marke.List = .Range(.Cells(2, 10), .Cells(lngLastRow, 10)).Value2
    End With
End Sub

Private Property Get NoEvent() As Boolean
    NoEvent = mblnNoEvent
End Property

Private Property Let NoEvent(ByVal pvblnNoEvent As Boolean)
    mblnNoEvent = pvblnNoEvent
End Property

Gruß
Nepumuk
Anzeige
AW: Bitte Beispielmappe bereitstellen - o.T.
20.08.2020 15:21:10
Tim
Hallo,
bei der Datei geht es und bei der original Datei leider nicht.
Ich versuche es morgen nochmal.
Danke
;

Beliebteste Forumthreads (12 Monate)

Jetzt das Excel-Portal bewerten: Deine Stimme zählt!
Anzeige
Anzeige
Entdecke mehr
Finde genau, was du suchst

Die erweiterte Suchfunktion hilft dir, gezielt die besten Antworten zu finden

Suche nach den besten Antworten
Unsere beliebtesten Threads

Entdecke unsere meistgeklickten Beiträge in der Google Suche

Top 100 Threads jetzt ansehen
Anzeige