Microsoft Excel

Herbers Excel/VBA-Archiv

Nummer zu Text

Betrifft: Nummer zu Text von: Roberto
Geschrieben am: 13.10.2020 11:07:56

Hallo zusammen


Ich habe ein "kleines" Problem zu lösen.

Ich muss Zahlen in Text verwandeln. Nicht in irgendeinen Text sondern er muss ein bestimmtes Format haben.


Beispiele:


0.25 ist SZQ wird zusammengesetzt Positive Zahl = S, 0 = Z, .25 = Q

0.5 ist SZH wird zusammengesetzt Positive Zahl = S, 0 = Z, .5 = H

0.75 ist SZT wird zusammengesetzt Positive Zahl - S, 0 = Z, .75 = T

1.25 ist S1Q wird zusammengesetzt Positive Zahl = S, Ganzahl = 1, .25 = Q

3.5 ist S3H wird zusammengesetzt Positive Zahl = S, Ganzahl = 3, .5 = H

7.75 ist S7T -wird zusammengesetzt Positive Zahl - S, Ganzahl = 7, .75 = T


Für negative Zahlen würde Anstelle S der Buchstabe N benutzt.

In den Spezialfälle mit 0.13 wird x und für 0.15 müsste ich f benutzt


Ich habe mit meinen Versuchen mal eine Datei erstellt. Aber Leider bin ich nicht an mein Ziel gelangt.

https://www.herber.de/bbs/user/140853.xlsx

Vielleicht habt Ihr ja ein paar Ideen wie ich das lösen könnte.

Betrifft: AW: Nummer zu Text
von: ralf_b
Geschrieben am: 13.10.2020 11:11:56

in deiner datei befindet sich irgendwas anderes

Betrifft: AW: Nummer zu Text
von: Roberto
Geschrieben am: 13.10.2020 11:28:59

Da habe ich Wohl die Falsche Datei Hochgeladen. Sorry

https://www.herber.de/bbs/user/140854.xlsx

Betrifft: AW: Nummer zu Text
von: ralf_b
Geschrieben am: 13.10.2020 12:05:30

https://www.herber.de/bbs/user/140856.xlsx

mit daniels cooler formel im Vergleich

Betrifft: AW: Nummer zu Text
von: Daniel
Geschrieben am: 13.10.2020 11:36:57

Hi
mal so als Gedankenansatz.

=WAHL(VORZEICHEN(A1)+2;"N";"S";"S")&GANZZAHL(ABS(A1))&SVERWEIS(REST(ABS(A1);1);{0."";0,25."Q"; 0,5."H";0,75."T"};2;0)

die Datentabelle des SVerweises ist hier in die Formel integriert.
dabei bilden Suchwert und Ausgabewert immer ein mit "." getrenntes Paar, die einzelnen Paare sind dann wieder mit Semikolon getrennt.

Die Formel ist mit Dezimal- und Parametertrennzeichen für ein deutsches Excel geschrieben.
da du den Punkt als Dezimalzeichen verwendest, müsstest du das ggf anpassen.

Gruß Daniel

Betrifft: AW: Nummer zu Text
von: Roberto
Geschrieben am: 13.10.2020 12:09:37

Hi Daniel

Herzlichen Dank schon mal.
Das Problem das ich habe ist, dass ich ein auf Schweizerdeutsch eingestelltes Excel habe. Sprich ich bin aus der Schweiz und da machen wir leider einen Punkt anstatt des Kommas. Wenn ich also deine Formel anpasse bekomme ich einen Fehler.
Kann ich für die paar trennung auch etwas anderes nehmen?

Danke

Roberto

Betrifft: AW: Nummer zu Text
von: Daniel
Geschrieben am: 13.10.2020 12:14:40

Sorry, da musst du dich selber informieren, wie das mit den Trennern bei euch aussieht.
wenn die Matrix-Konstante ein zweidimensionales Array sein soll, dann Trennen bei uns das Semikolon die Zeilen und der Punkt die Spalten.
Was es bei euch ist ??? keine Ahnung.

alternativ kannst du natürlich auch eine Hilfstabelle erstellen (erste Spalte 0; 0.25; 0.5 usw, zweite Spalte dann den dazugehörigen Buchstaben) und in der SVerweisfunktion dann den Zellbezug auf diese Hilfstabelle angeben anstelle der Matrixkonstanten (SVerweis sollte bei Excel-gut bekannt sein)

Gruß Daniel

Betrifft: AW: Nummer zu Text
von: Roberto
Geschrieben am: 13.10.2020 13:26:25

Hi Daniel

Habe es in der Zwischenzeit gefunden. (Nachdem ich den SVERWEIS begriffen habe)

=WAHL(VORZEICHEN(A1)+2;"N";"S";"S")&GANZZAHL(ABS(A1))&SVERWEIS(REST(ABS(A1);1);{0\"Z";0.25\"Q"; 0.5\"H";0.75\"T";0.13\"x";0.15\"f"};2;0)

Das einzige Problem das ich jetzt noch habe ist mit 0.13 und .15 und mit der Zahl 0. Diese sollte Z geben und nicht S0Z.

Vielleicht hast du dazu noch eine Idee.

Auf alle Fälle HERZLICHEN DANK

Roberto

Betrifft: AW: Nummer zu Text
von: Daniel
Geschrieben am: 13.10.2020 13:33:12

Hi
naja, .13 und .15 hast du doch gelöst.
das mit der 0 würde ich durch eine Vorabangfrage lösen: =Wenn(A1=0;"Z";Wahl(…)&)
ansonsten erzeugt das zu viele Ausnahmen im Rest der Formel.
Gruß Daniel

Betrifft: AW: Nummer zu Text
von: Roberto
Geschrieben am: 13.10.2020 13:41:47

Hi,

ja sollte man meinen. Aber leider funktioniert es nicht. Logisch müsste es sein. Aber Der Teufel ist offensichtlich doch ein Eichhörnchen.

Gruss

Betrifft: AW: Nummer zu Text
von: Daniel
Geschrieben am: 13.10.2020 13:58:31

wenns nicht funktionert, lade bitte die Datei hoch.
dann kann man suchen, wo das Eichhörnchen die Nüsschen versteckt hat.
Gruß Daniel

Betrifft: AW: Nummer zu Text
von: Roberto
Geschrieben am: 13.10.2020 14:11:02

Hi Daniel

Ich bin noch auf ein Problem gestossen.
Bei 0.75 sollte es SZT ergeben. Mit deiner guten Formel bekomme ich aber S0T. Sprich das 0 setzt er nicht in Z um.

der Formelteil =REST(ABS(A1);1) ergibt 0.75 aber mir fehlt die Umsetzung der Vorkomma Zahl.
Umgesetzt also =WENN(M4=0;"Z";GANZZAHL(A1))

Ich habe auch noch die Sonderlocke ATM hinzu genommen.
=WENN(A1="ATM";"ATM";WENN(A1=0;"Z";WAHL(VORZEICHEN(A1)+2;"N";"S";"S")&GANZZAHL(ABS(A1)) &SVERWEIS(REST(ABS(A1);1);{0\"Z";0.25\"Q";0.5\"H";0.75\"T";0.13\"x";0.15\"f"};2;0)))

Aber die 0 in der Zahl bekomme ich nicht gelöst

Ich habe die Datei Angepasst und nochmal Hochgeladen.

https://www.herber.de/bbs/user/140861.xlsx

Danke und Grüsse

Roberto

Betrifft: AW: Nummer zu Text
von: Daniel
Geschrieben am: 13.10.2020 14:30:39

Hi

probiers mal so

=WENN(ISTTEXT(B6);B6;WENN(B6=0;"Z";WAHL(VORZEICHEN(B6)+2;"N";"";"S")&TEXT(GANZZAHL(ABS(B6));"0;;Z") &SVERWEIS(REST(ABS(B6);1);{0."Z";0,25."Q";0,5."H";0,75."T";0,13."x";0,15."f"};2;0)))

Trennzeichen bitte wieder anpassen, aber so läuft die Formel bei mir.

Texte werden jetzt generell übernommen, egal was drin steht.
bei NK-Stellen für die du noch keine Zuordnung hast, bekomnmst du den #NV-Fehler

Gruß Daniel

Betrifft: AW: Nummer zu Text
von: Roberto
Geschrieben am: 13.10.2020 15:09:39

Hi Daniel

Darf ich sagen Superdaniel ;)

HERZLICHEN Dank Die Formel Funktioniert perfekt.

Danke für Deine Hilfe

Roberto