Sonderzeichen finden

BS · 2024-06-27T12:42:22+00:00

Hallo, für einen SEPA-Einzug brauche ich eindeutige Daten. Ich habe eine umfangreiche Liste mit Namen und möchte Sonderzeichen entfernen, die in der Tabelle leider vorliegen, beispielsweise ß, ö, ü, a etc. Es gibt aber noch mehr, sodass ich mit der Suchen und Ersetzen-Variante nie sicher sein kann, alles gefunden zu haben. Ich habe also ein Tabellenblatt mit den Daten und ein weiteres, in dem ich die zulässigen Zeichen eingetragen habe (Alphabet, Buchstaben groß und klein, Bindestrich und Komma). Alle anderen Zeichen sollen entlarvt werden. Leider finde ich keine Formel mit der das möglich ist. Ich wollte ein WENN-Funktion erstellen, die mir ein X in eine Spalte setzt, wenn mehr als die erlaubten Zeichen des Suchbereichs vorhanden sind. Hat jemand eine Idee? Die Zelle, die untersucht werden soll, ist A2.

Hi
mit dieser Formel kannst du prüfen, ob in Zelle A2 unerlaubte Sonderzeichen vorhanden sind.
die Erlaubten Zeichen müssen in Spalte G (hab ich jetzt fürs testen genommen) untereinander aufgelistet stehen

=WENN(SUMME(ZÄHLENWENN(G:G;TEIL(A2;SEQUENZ(LÄNGE(A2));1))-1);"Sonderzeichen";"i.O.")

oder ne anderen Mögilchkeit, hier kannst du die erlaubten Zeichen in einem Text bzw in einer einzigen Zelle darstellen (hier mal nur "abcde", kannst du ja erweitern)

=WENN(ODER(ISTFEHLER(SUCHEN(TEIL(A2;SEQUENZ(LÄNGE(A2));1);"abcde")));"Sonderzeichen";"i.O")

oder diese Formel, welche die erlaubten Zeichen durch ein "-" ersetzt und die Sonderzeichen stehen lässt, so dass du sehen kannst, welches Zeichen es ist und wo es im Text steht:

=LET(x;TEIL(A2;SEQUENZ(LÄNGE(A2));1);TEXTKETTE(WENN(ISTFEHLER(SUCHEN(x;"abcde"));x;"-")))

noch ein Hinweis: suchen unterscheidet nicht zwischen Groß und Klein (ebenso ZählenWenn), es reicht also aus, nur die Klein- oder Großbuchstaben aufzulisten, aber man braucht nicht beide.
sollte die Groß/Klein-Unterscheidung wichtig sein ("A" ist erlaubt, aber "a" verboten), dann musst du SUCHEN durch FINDEN ersetzen.
beim ZählenWenn kann man diese Unterscheidung nicht machen.

Gruß Daniel

Hi
1. du darfst jedes Zeichen nur einmal listen, damit es 1 ergibt, wenn es gefunden wird.
Zählenwenn unterscheidet aber nicht zwischen Groß- und Kleinschreibung und wenn du jetzt in der Liste ein "a" und ein "A" hast, dann kommt "a" oder "A" zweimal vor. Damit funktioniert meine Formel aber nicht mehr.
du müsstest also entweder die Groß- oder die Kleinbuchstaben in der Tabelle2 löschen.

2. du musst in der Formel Zellbereiche, die sich beim Ziehen oder kopieren der Formel nicht verändern dürfen, als "absolut" kennzeichnen. Das macht man, in dem man dem Spaltenbuchstaben und der Zeilennummer ein $ voranstellt:
=WENN(SUMME(ZÄHLENWENN(Tabelle2!$A$1:$A$29;TEIL(A2;SEQUENZ(LÄNGE(A2));1))-1);"Sonderzeichen";"i.O.")

alternativ probier auch mal den zweiten Formelvorschlag.
du kannst hier auch deine Buchstabenliste verwenden:

=WENN(ODER(ISTFEHLER(FINDEN(TEIL(A2;SEQUENZ(LÄNGE(A2));1);TEXTKETTE(Tabelle2!$A$1:$A$55))));"Sonderzeichen";"i.O")

Gruß Daniel

Forumthread: Sonderzeichen finden

14
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Beliebteste Forumthreads (12 Monate)

Sonderzeichen finden

Forumthread: Sonderzeichen finden

14 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

14
Beiträge zum Forumthread

Beiträge zu diesem Forumthread