Suchfunktion

Bild

Betrifft: Suchfunktion
von: Stuntebeck
Geschrieben am: 08.10.2003 14:38:29

Ich möchte gerne eine Exceldatei mit mehreren Arbeitsblättern nach teilweise Übereinstimmungen durchsuchen lassen, so dass mir am Ende ausgegeben wird, welche Zellen in welchen Arbeitsblättern eine Übereinstimmung aufweisen.
(Suche nach Meyer, Ergebnis: Mappe 1 Zelle A3, Mappe 3 Zelle B4)
Wer kann mir helfen?

Bild


Betrifft: AW: Suchfunktion
von: ChrisL
Geschrieben am: 08.10.2003 15:00:04

Hi

Option Explicit


Sub Suchen()
Dim WS1 As Worksheet, WS2 As Worksheet
Dim Suchbegriff As String
Dim Zelle As Range, LetzteZeile As Long
Set WS1 = Worksheets("Ergebnis")
Suchbegriff = "Meyer"
WS1.Cells.ClearContents
WS1.Range("A1") = "Blatt"
WS1.Range("B1") = "Zelle"
WS1.Range("C1") = "Inhalt"
For Each WS2 In ActiveWorkbook.Worksheets
    If WS2.Name <> WS1.Name Then
    For Each Zelle In WS2.UsedRange
        If Zelle Like "*" & Suchbegriff & "*" Then
            LetzteZeile = WS1.Range("A65536").End(xlUp).Row + 1
            WS1.Cells(LetzteZeile, 1) = WS2.Name
            WS1.Cells(LetzteZeile, 2) = Zelle.Address
            WS1.Cells(LetzteZeile, 3) = Zelle
        End If
    Next Zelle
    End If
Next WS2
End Sub


Gruss
chris


Bild


Betrifft: AW: Suchfunktion
von: Stuntebeck
Geschrieben am: 08.10.2003 16:34:11

Danke, klappt hervorragend!


 Bild

Beiträge aus den Excel-Beispielen zum Thema " Währungskurse über internet aktualisieren"