Kalenderwochen Jahreswechsel

Konrad · 2005-09-15T13:31:11+00:00

Hallo zusammen, nachdem ich lange recherchiert habe, für mein Problem aber noch keine Lösung gefunden habe, versuche ich es auf diesem Wege. In Feld A1 soll ein Datum in Kalenderwochen stehen. In Feld B1 soll das aktuelle Datum in KW stehen. In Feld C1 soll, die Differenz in Kalenderwochen stehen. Im Grunde nicht aufregend, aber: Wie gebe ich in A1 die Kalenderwoche so an, damit das Jahr berücksichtigt ist. Falls A1 = KW 10 des Jahres 2006 und B1 = KW 50 des Jahres 2005 soll C1 = + 12 und nicht - 40 Feld B1 lass ich über add-ins Kalenderwoche(Heute) laufen. A1 soll in KW (10/06 oder irgendwie so) angegeben werden, nicht als exaktes Datum. Hoffe, jemand hat verstanden, was ich etwas umständlich versucht habe zu beschreiben. Für jegliche Hilfe bin ich natürlich dankbar. Grüße, Konrad

Hallo Konrad,
Willst du vielleicht nur die Wochen zwischen zwei Datumwerten unabhängig vom Jahr ermitteln? Dann beachte die gelben Zellen.

	A	B	C	D
1	KW von Datum	KW Heute	KW Heute - KW von Datum	Datum
2	5	37	32	02.02.2005
3	51	37	-14	24.12.2005
4	5	37	32	01.02.2005
5	Ergebnis in Zelle C2 ist ein absoluter Wert
6	Ergebnisse in Zellen C3 und C4 können auch negativ sein.
7	Berechnung nur innerhab eines Kalenderjahres
8
9
10	Datum Heute	Datum	ganze Wochen	Resttage
11	15.09.2005	24.12.2005	14	2
12	15.09.2005	24.12.2006	66	3
13	15.09.2005	24.12.2004	-38	1
14	ganze Wochen unabhängig vom Jahr der Datumwerte

Formeln der Tabelle

A2 : =WENN(ISTZAHL(D2);KÜRZEN((D2-DATUM(JAHR(D2+3-REST(D2-2;7));1;REST(D2-2;7)-9))/7);"")
B2 : =WENN(ISTZAHL(D2);KÜRZEN((HEUTE()-DATUM(JAHR(HEUTE()+3-REST(HEUTE()-2;7));1;REST(HEUTE()-2;7)-9))/7);"")
C2 : =WENN(UND(ISTZAHL(A2);JAHR(D2)=JAHR(HEUTE());B2>A2);B2-A2;WENN(UND(ISTZAHL(A2);JAHR(D2)=JAHR(HEUTE());B2<=A2);A2-B2;""))
A3 : =WENN(ISTZAHL(D3);KÜRZEN((D3-DATUM(JAHR(D3+3-REST(D3-2;7));1;REST(D3-2;7)-9))/7);"")
B3 : =WENN(ISTZAHL(D3);KÜRZEN((HEUTE()-DATUM(JAHR(HEUTE()+3-REST(HEUTE()-2;7));1;REST(HEUTE()-2;7)-9))/7);"")
C3 : =WENN(UND(ISTZAHL(A3);JAHR(D3)=JAHR(HEUTE()));B3-A3;"")
A4 : =WENN(ISTZAHL(D4);KÜRZEN((D4-DATUM(JAHR(D4+3-REST(D4-2;7));1;REST(D4-2;7)-9))/7);"")
B4 : =WENN(ISTZAHL(D4);KÜRZEN((HEUTE()-DATUM(JAHR(HEUTE()+3-REST(HEUTE()-2;7));1;REST(HEUTE()-2;7)-9))/7);"")
C4 : =WENN(UND(ISTZAHL(A4);JAHR(D4)=JAHR(HEUTE()));B4-A4;"")
A11 : =HEUTE()
C11 : =WENN(UND(ISTZAHL(A11);ISTZAHL(B11));GANZZAHL((B11-A11)/7);"")
D11 : =WENN(UND(ISTZAHL(A11);ISTZAHL(B11));REST((B11-A11);7);"")
A12 : =HEUTE()
C12 : =WENN(UND(ISTZAHL(A12);ISTZAHL(B12));GANZZAHL((B12-A12)/7);"")
D12 : =WENN(UND(ISTZAHL(A12);ISTZAHL(B12));REST((B12-A12);7);"")
A13 : =HEUTE()
C13 : =WENN(UND(ISTZAHL(A13);ISTZAHL(B13));GANZZAHL((B13-A13)/7);"")
D13 : =WENN(UND(ISTZAHL(A13);ISTZAHL(B13));REST((B13-A13);7);"")

Diagramm - Grafik - Excel Tabellen einfach im Web darstellen Excel Jeanie HTML 3.0 Download
MfG
Rüdiger

Hallo Konrad,
eine ISO- KW wird aus einem Datum errechnet. Die Funktion KALENDERWOCHE gibt nach unserer Norm unter Umständen falsche Ergebnisse aus, also bitte nicht anwenden.
Wenn du das Enddatum nicht sichtbar haben willst, blende doch die entsprechende Spalte aus (bei mir die Spalte G), formatiere die Enddatum- Zellen ;;; oder aber für den Ausdruck lege den Druckbereich fest.
Man kann auch das Datum des Montags aus angegebener KW und Jahr errechnen. Man könnte also auch nur mit einer KW Ende und Jahr Ende Angabe auskommen (auch kombiniert wie in Zelle A19), jedoch mit reichlich umfangreichen Formeln. Ich meine, die Formeln werden dadurch zu umfangreich und damit unübersichtlich, mit einer Datum- Ende Angabe ist das einfacher.

	A	B	C	D	E	F	G
8	KW Heute	KW Ende	ganze Wochen	Resttage			Datum Ende
9	37 / 2005	51 / 2005	14	1			24.12.2005
10	37 / 2005	51 / 2006	66	2			24.12.2006
11	37 / 2005	52 / 2007	118	3			24.12.2007
12
13	KW- Angaben der Zellen in Spalte A und B sind Text. Damit wird nicht gerechnet
14	Das Datum Ende muss irgendwo sein, damit die KW berechnet werden kann
15
16	Hier wird das Datum des Montags aus angegebener KW und Jahr errechnet. Man könnte also auch nur mit einer KW Ende und Jahr Ende Angabe auskommen (auch kombiniert wie in Zelle A19), jedoch mit reichlich umfangreichen Formeln.
17	Formeln nach Peter Dorigo
18	51	2005	19.12.2005
19	51 / 2005		19.12.2005
20	http://www.excelformeln.de/formeln.html?welcher=186

Formeln der Tabelle

A9 : =KÜRZEN((HEUTE()-DATUM(JAHR(HEUTE()+3-REST(HEUTE()-2;7));1;REST(HEUTE()-2;7)-9))/7)&" / "& JAHR(HEUTE())
B9 : =KÜRZEN((G9-DATUM(JAHR(G9+3-REST(G9-2;7));1;REST(G9-2;7)-9))/7)&" / "& JAHR(G9)
C9 : =WENN(ISTZAHL(G9);GANZZAHL((G9-HEUTE())/7);"")
D9 : =WENN(ISTZAHL(G9);REST((G9-HEUTE());7);"")
A10 : =KÜRZEN((HEUTE()-DATUM(JAHR(HEUTE()+3-REST(HEUTE()-2;7));1;REST(HEUTE()-2;7)-9))/7)&" / "& JAHR(HEUTE())
B10 : =KÜRZEN((G10-DATUM(JAHR(G10+3-REST(G10-2;7));1;REST(G10-2;7)-9))/7)&" / "& JAHR(G10)
C10 : =WENN(ISTZAHL(G10);GANZZAHL((G10-HEUTE())/7);"")
D10 : =WENN(ISTZAHL(G10);REST((G10-HEUTE());7);"")
A11 : =KÜRZEN((HEUTE()-DATUM(JAHR(HEUTE()+3-REST(HEUTE()-2;7));1;REST(HEUTE()-2;7)-9))/7)&" / "& JAHR(HEUTE())
B11 : =KÜRZEN((G11-DATUM(JAHR(G11+3-REST(G11-2;7));1;REST(G11-2;7)-9))/7)&" / "& JAHR(G11)
C11 : =WENN(ISTZAHL(G11);GANZZAHL((G11-HEUTE())/7);"")
D11 : =WENN(ISTZAHL(G11);REST((G11-HEUTE());7);"")
C18 : =DATUM(B18;1;7*A18-3-WOCHENTAG(DATUM(B18;;);3))
C19 : =DATUM(WERT(RECHTS(A19;4));1;7*WERT(LINKS(A19;2))-3-WOCHENTAG(DATUM(WERT(RECHTS(A19;4));;);3))

Diagramm - Grafik - Excel Tabellen einfach im Web darstellen Excel Jeanie HTML 3.0 Download
MfG
Rüdiger

Forumthread: Kalenderwochen Jahreswechsel

7
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Infobox / Tutorial

Kalenderwochen am Jahreswechsel in Excel berechnen

Schritt-für-Schritt-Anleitung

Häufige Fehler und Lösungen

Alternative Methoden

Praktische Beispiele

Tipps für Profis

FAQ: Häufige Fragen

Beliebteste Forumthreads (12 Monate)