Microsoft Excel

Herbers Excel/VBA-Archiv

Tabelle dynamisch filtern

Betrifft: Tabelle dynamisch filtern von: Falk
Geschrieben am: 07.09.2020 17:56:19

Hallo ,

ich habe eine Tabelle, die dynamisch gefiltert werden soll.

Aus dem Bereich D19:A5173 soll das Kürzel aus B1 gesucht werden. Wenn es gefunden wird, soll der Wert, der drei Spalten davor steht (Klasse) unterhalb von A2 aufgelistet werden und der Wert, der zwei Spalten davor steht (Fach) unterhalb von B2 aufgelistet werden. Letztendlich soll immer das jeweilige Datum unterhalb von C2 aufgelistet werden.

Mit dieser Übersicht möchte ich verhindern, dass sich bei einigen Kollegen Klausuren häufen.

Nach meiner Recherche könnte hier eine Kombination aus Aggregat, Index und Finden hin, aber dazu fehlt´s bei mir. Kann jemand helfen? Vielen Dank.

Falk


https://www.herber.de/bbs/user/140101.xlsx

Betrifft: Befleißige Dich doch bitte eines kompletten ...
von: lupo1
Geschrieben am: 07.09.2020 18:17:47

... Beispiels mit allen Daten und einem Wunschergebniss, händisch eingetragen. Danke schön.

(Das müssen wir bei ungefähr der Hälfte aller Fragen anmerken).

Betrifft: AW: Befleißige Dich doch bitte eines kompletten ...
von: Falk
Geschrieben am: 08.09.2020 08:21:52

Hallo,
nachvollziehbarer Hinweis. Danke, das nächste Mal mach ich das so.
Viele Grüße
Falk

Betrifft: AW: mit AGGREGAT(), INDEX() und VERGLEICH()... ...
von: neopa C
Geschrieben am: 07.09.2020 19:07:56

Hallo Falk,

... nachfolgend geh ich allerdings momentan noch davon aus, dass jeder Lehrer je Tag nur eine Klausur zugeordnet wurde. Wenn dem nicht so sein sollte, werden die Formeln etwas komplexer.

Die Formel A3 nach rechts und anschließend Formeln A3:C3 ziehend nach unten kopieren.

Arbeitsblatt mit dem Namen 'Übersicht'
 ABC
1KollegeDan 
2KlasseFachDatum
313TLK DeuMontag, 28. September 2020
413AOLK DeuDienstag, 6. Oktober 2020
511T2DeuMontag, 9. November 2020
613TLK DeuMontag, 30. November 2020
713AOLK DeuDienstag, 8. Dezember 2020
8   

ZelleFormel
A3=WENN($C3="";"";INDEX($A:$AS;18+VERGLEICH($C3;$C$19:$C$173;0);VERGLEICH($B$1;INDEX($D$19:$AS$173;VERGLEICH($C3;$C$19:$C$173;0););0)+(A$2="Fach")))
C3=WENNFEHLER(AGGREGAT(15;6;C$19:C$173/(D$19:AS$173=B$1);ZEILE(A1));"")

ZelleGültigkeitstypOperatorWert1Wert2
B1Liste =Listen!$B$4:$B$29 
Verwendete Systemkomponenten: [Windows (32-bit) NT 6.02] MS Excel 2010
Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg


Gruß Werner
.. , - ...

Betrifft: AW: mit AGGREGAT(), INDEX() und VERGLEICH()... ...
von: Falk
Geschrieben am: 08.09.2020 08:19:40

Hallo Werner,
Was soll ich sagen ... Danke, top!

Ich nehme an, der Hinweis für die Zelle B1 ist für all jene, die eine ähnliche Frage haben.

Viele Grüße
Falk

Betrifft: AW: gerne, bitteschön owT
von: neopa C
Geschrieben am: 08.09.2020 10:35:21

Gruß Werner
.. , - ...

Betrifft: AW: gerne, bitteschön owT
von: Falk
Geschrieben am: 08.09.2020 11:43:34

Hallo Werner,
ich bins nochmal.
Ich brauche zur besseren Übersicht eigentlich auch die Klausurtermine pro Klasse.
Ich habe versucht, die Formel dafür anhand deiner Vorlage nachzuempfinden. Für das Datum gelingt mir das auch, die Klasse 9A hat am 13.01.21 eine Klausur. Aber für das Fach ist mir das nicht gelungen.
Könntest du da nochmal draufschauen. In F3 müsste "Deu" erscheinen, wenn F1="9A".

Dass von E3:E8 immer der Wert aus F1 steht ist richtig. Die Klassen haben bei uns nur 6 Fächer.
https://www.herber.de/bbs/user/140118.xlsx


Vielen Dank und Grüße
Falk

Betrifft: AW: dazu bedarf es nur einer Anpassung ...
von: neopa C
Geschrieben am: 08.09.2020 16:01:27

Hallo Falk,

... hatte Deine Zusatzfragefragestellung bisher übersehen. Sorry.

In E3 besser so, wenn Du dort wirklich nochmal die Klasse listen willst, weil mE nicht notwendig.

=WENN(G3="";"";F$1) (denn z.B. für 12AO hat hier 8 Termine die 9 A nur einen.

In F3:

=WENN($G3="";"";INDEX($A:$AS;18+VERGLEICH($G3;$C$19:$C$173;0);VERGLEICH($F$1;INDEX($D$19:$AS$173; VERGLEICH($G3;$C$19:$C$173;0););0)+4))

Gruß Werner
.. , - ...

Betrifft: AW: dazu bedarf es nur einer Anpassung ...
von: Falk
Geschrieben am: 09.09.2020 08:04:49

Guten Morgen Werner,
danke.
Am Ende der Formel für F3 habe ich (+4) verstanden. Es wird von Spalte A + x gezählt. D.h. "+6" und ich kann mir in einer weiteren Spalte den Kollegen ausgeben. Funktioniert.

Nochmals Danke und viele Grüße
Falk

Betrifft: AW: bitteschön owT
von: neopa C
Geschrieben am: 09.09.2020 11:40:28

Gruß Werner
.. , - ...

Betrifft: AW: dazu bedarf es nur einer Anpassung ...
von: Falk
Geschrieben am: 09.09.2020 13:47:32

Hallo Werner,
ein Problem bleibt mir. Es ist aber nicht dringend.
Von E3:I15 werden die Klassen doppelt ausgegeben, wenn die Klasse an diesem Tag mehr als eine Klausur schreibt. (Du hattest das Problem, meine ich, schon im ersten Durchgang geahnt.) Dann wird zwar die Klasse mehrfach gezählt, aber nicht mehr dem unterschiedlichen Kollegen und Fach zugeordnet.
https://www.herber.de/bbs/user/140144.xlsx

In den Jahrgängen 11 bis 13 kann das vorkommen, wenn so genannte Blöcke nebeneinander liegen, also Gruppen unterschiedlicher Schüler einer Klasse gleichzeitig schreiben.

Mach dir bitte nur die Arbeit, wenn du Zeit dafür hast. Vielen Dank und Grüße.
Falk

Betrifft: AW: ja, ist auch möglich, dann ...
von: neopa C
Geschrieben am: 09.09.2020 15:37:54

Hallo Falk,

... wird es noch etwas komplexer, VERGLEICH() allein reicht hier nicht mehr aus.

Folgende Formel in F3:

=WENN($G3="";"";INDEX($A:$AS;18+VERGLEICH($G3;$C$19:$C$173;0);AGGREGAT(15;6;SPALTE($D3:$AS3)/($F$1=INDEX($D$19:$AS$173;VERGLEICH($G3;$C$19:$C$173;0);));ZÄHLENWENN($G$3:$G3;$G3))+SPALTE(A3)))

und diese nach unten kopieren und dann F3:F16 nach rechts in Spalte H und I kopieren.

Gruß Werner
.. , - ...

Betrifft: AW: ja, ist auch möglich, dann ...
von: Falk
Geschrieben am: 10.09.2020 14:06:46

Hallo Werner,
vielen Dank. Habe mich erst ein bisschen dämlich angestellt, aber: Lesen hilft! Am Ende hat es geklappt.
Wieder großen Dank.
Viele Grüße
Falk

Betrifft: AW: bitteschön und ...
von: neopa C
Geschrieben am: 10.09.2020 14:20:46

Hallo Falk,

... nun interessehalber nachgefragt, in welcher Stadt bzw. wenigstens Bundesland bist Du tätig?

Gruß Werner
.. , - ...

Beiträge aus dem Excel-Forum zum Thema "Tabelle dynamisch filtern"