Rang von Summen mit Kriterium(Gruppe)

HI zusammen,
leider komme ich bei meinem Excel Problem nicht weiter. Ich hoffe ihr könnt mir dabei weiterhelfen.
Ich habe 2 Tabellen. Eine enthält Rohdaten und die andere die Auswertung der Daten.
Anbei eine Beispieldatei mit der Darstellung der Daten. https://www.herber.de/bbs/user/153452.xlsx
Ich habe die Spalten Produkt ID, Produktname, Firmenname und Umsatz.
Gerne würde ich die Rangfolge des Umsatzes bezogen auf den Firmenname herausfinden.
Das würde einfach über eine Pivot gehen, jedoch ist es in unserem Anwendungsfall besser dies über eine Formel zu machen. Habt ihr hier Vorschläge?
Um den Rang des Umsatz auf Basis der Produkt ID (ist eine eindeutige Nummer) herauszufinden, verwende ich eine Kombination aus der SUMMENPRODUKT und KGRÖSSTE Formel.
Für jegliche Antworten bin ich euch sehr dankbar.
Grüße
Chris
https://www.herber.de/bbs/user/153452.xlsx

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Hallo Chris,
... wenn die Auswertung wieder nur nach der Firma erfolgen soll und für die nun formatierte Datentabelle, dann in C2:
=WENNFEHLER(1/(1/AGGREGAT(14;6;SUMMEWENN(Tabelle1[Firmenname];Tabelle1[Firmenname];Tabelle1[Umsatz])*(VERGLEICH(Tabelle1[Firmenname]&"";Tabelle1[Firmenname]&"";0)=ZEILE(Tabelle1[Region])-1);ZEILE(A1)));"")
und in B2:
=WENN(C2="";"";INDEX(Tabelle1[Firmenname];AGGREGAT(15;6;ZEILE(Tabelle1[Region])/(SUMMEWENN(Tabelle1[Firmenname];Tabelle1[Firmenname];Tabelle1[Umsatz])=C2);ZÄHLENWENN(C$2:C2;C2))-ZEILE(Tabelle1[#Kopfzeilen])))
und beide Formeln nach unten ziehend kopieren.
Die beiden anderen Datenspalten in die Auswertung einzubeziehen macht für vorliegenden Datenbeispiel keinen Sinn, weil dann die gleichen Datenwerte ermittelt würden, wie sie in 'Raw Data'! stehen. Bestenfalls Sinn würde noch machen noch die Region bei der Listung zu berücksichtigen. Oder was suchst Du nun genau?
Gruß Werner
.. , - ...

Beliebteste Forumthreads (12 Monate)

Arbeitsblatt mit dem Namen 'Report'
	A	B	C
1	Rang	Firmenname	Umsatz
2	1	Firma 3	38424
3	2	Firma 1	20541
4	3	Firma 2	6611
5

Zelle	Formel
A2	=WENN(C2="";"";RANG(C2;C$2:C$50))
B2	=WENN(C2="";"";INDEX('Raw Data'!C:C;AGGREGAT(15;6;ZEILE(C$2:C$99)/(SUMMEWENN('Raw Data'!C$2:C$99;'Raw Data'!C$2:C$99;'Raw Data'!D$2:D$99)=C2);ZÄHLENWENN(C$2:C2;C2))))
C2	=WENNFEHLER(1/(1/AGGREGAT(14;6;SUMMEWENN('Raw Data'!C$2:C$99;'Raw Data'!C$2:C$99;'Raw Data'!D$2:D$99)*(VERGLEICH('Raw Data'!C$2:C$99&"";'Raw Data'!C$2:C$99&"";0)=ZEILE(C$2:C$99)-1);ZEILE(A1)));"")

Rang von Summen mit Kriterium(Gruppe)

7 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

7
Beiträge zum Forumthread

Beiträge zu diesem Forumthread