Live-Forum - Die aktuellen Beiträge
Datum
Titel
16.10.2025 11:48:44
Makro von Excel in Word aufrufen
16.10.2025 11:16:26
SUMMEWENN erweitern
16.10.2025 09:40:53
Mehrere Konferenzen ohne Personenüberschneidung terminieren
16.10.2025 00:15:51
Passwort im Herbersforum ändern
Keine passende Antwort im Forumarchiv gefunden?
Stelle deine Frage im Live-Forum
Anzeige
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Vorheriger Thread
Vorheriger Thread
Rückwärts Blättern
1444to1448
1444to1448
Aktuelles Verzeichnis
Verzeichnis Übersicht
Verzeichnis Übersicht
Übersicht Verzeichnisse
Nächster Thread
Nächster Thread
Vorwärts blättern
Inhaltsverzeichnis

Formel aus Zelle in VBA einlesen und ändern

Forumthread: Formel aus Zelle in VBA einlesen und ändern

Formel aus Zelle in VBA einlesen und ändern
11.09.2015 10:56:14
Herbert
Hallo,
wie kann ich per VBA eine Formel einlesen und Teile der Formel ändern? Die Formel wird nicht in die Zelle zurückgeschrieben, sondern in VBA weiter verarbeitet.
=VERKETTEN(InputB!A2;"||";InputA!F2;"||";InputA!B2;"||";InputB!G2;"||"
Hier muss ich nun die "2" bei den InputA-Zellangaben in eine 3 ändern. Mit "Replace" geht es nicht, da es unterschiedliche Spalten betrifft
Habt ihr da evtl eine Idee? Vielen Dank im Voraus!
Servus

Anzeige

35
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: Formel aus Zelle in VBA einlesen und ändern
11.09.2015 11:20:07
Michael
Hallo Herbert!
Aber so funktioniert es schon mit Replace... oder hab ich Dich falsch verstanden:
Sub a()
Dim Formel As String
Formel = ActiveCell.Formula
Debug.Print Formel
Formel = Replace(Formel, "2,", "3,", 1)
Debug.Print Formel
End Sub
LG
Michael

Anzeige
AW: Ergänzung...
11.09.2015 11:22:05
Michael
Hallo Herbert,
... mein voriger Ansatz ergibt bei mir:
vor Replace
=CONCATENATE(InputB!A2,"||",InputA!F2,"||",InputA!B2,"||",InputB!G2,"||")
nach Replace
=CONCATENATE(InputB!A3,"||",InputA!F3,"||",InputA!B3,"||",InputB!G3,"||")
So hätte ich es verstanden...
LG
Michael

Anzeige
AW: Meine Beiträge = Blödsinn, mein Fehler...
11.09.2015 11:24:49
Michael
Sorry, hab jetzt erst verstanden, dass es Dir um InputA geht und Du auch InputB dabei hast!
Tut mir leid - wer lesen kann ist klar im Vorteil!
LG
Michael

AW: Offen! owT
11.09.2015 11:37:02
Michael

AW: Offen! owT
11.09.2015 12:24:02
Herbert
Hallo Michael,
vielen Dank für Deinen Versuch. Der gute Wille zählt! ;o)=)
Aber vielleicht hat ja noch jemand eine Idee!
Servus

Anzeige
AW: Die entscheidende Frage ...
11.09.2015 12:26:52
Gerd
Hallo Herbert!
... ist, ob der neue Text oder das neue Formelergebnis in eine Variable sollen.
Gruß Gerd

AW: Die entscheidende Frage ...
11.09.2015 15:46:52
Herbert
Hallo Gerd,
diese Frage ist allerdings berechtigt, denn es soll das neue Formelergebnis in eine Variable. Warum fragst Du?
Servus

AW: Die entscheidende Frage ...
11.09.2015 16:27:50
Daniel
Hi
nun, dann müsstest du doch die neue Formel in die Zelle schreiben und den Wert der Zelle ins Array übertragen.
oder du berechnest mit =Evaluate(FormelText) das Formelergebnis der neuen Formel direkt in VBA.
Dann muss allerdings die Formel in Englisch geschrieben sein (.Formula statt .FormulaLocal)
Gruß Daniel

Anzeige
AW: Kleine Rehabilitation meinerseits + schönes WE
11.09.2015 13:52:44
Michael
Hallo Herbert und @ alle!
Mich hat's ziemlich gewurmt, dass ich nicht gleich ordentlich gelesen hab, und daher die beiden unnötigen Antworten verzapft habe; und daher hab ich mich nochmal vor dem Wochenende besonnen und auch eine Lösung erbastelt.
Ist mittlerweile unnötig, und mit Kapazundern wie Daniel und Rudi kann ich mich leider nicht mal im Ansatz messen, aber ich poste hier noch meine Lösung, weil ich das für mein eigenes VBA-Gewissen brauche ;-). Soweit ich es jetzt mal getestet hab müssten auch 2- und 3-Buchstaben- umfassende Spaltenbezüge möglich sein. 
Sub FormelTausch()
Dim Formel As String
Dim Zeichen As String
Dim FolgeZeichen As String
Dim i As Integer
Dim Merker As Boolean
Dim Sammler As String
Formel = ActiveCell.FormulaLocal
Debug.Print Formel
For i = 1 To Len(Formel)
Zeichen = Mid(Formel, i, 1)
Select Case IsNumeric(Zeichen)
Case Is = True
If Merker = True Then
Sammler = Sammler & "3"
Merker = False
Else: Sammler = Sammler & Zeichen
End If
Case Is = False
FolgeZeichen = Mid(Formel, i + 1, 1)
Select Case FolgeZeichen
Case Is = "!"
Select Case Zeichen
Case Is = "A"
Merker = True
Sammler = Sammler & Zeichen
Case Else
Sammler = Sammler & Zeichen
End Select
Case Else
Sammler = Sammler & Zeichen
End Select
End Select
Next
Debug.Print Sammler
End Sub
Danke auch an alle Antworter hier - da hab ich auch gleich wieder was gelernt ;-). Allen wünsche ich damit ein schönes Wochenende!
LG
Michael

Anzeige
AW: Kleine Rehabilitation meinerseits + schönes WE
11.09.2015 15:57:01
Herbert
Hallo Michael,
das ist auch super. Es funktioniert tadellos. Doch befürchte ich, dass es bei den Hunderttausenden von Datensätzen doch deutlich langsamer, als Rudis Version, sein wird, da Du ja jeden String Zeichen für Zeichen abklapperst. Aber für nicht ganz so viele DS ist es immer zu gebrauchen. Danke vielmals!
Servus

Anzeige
AW: Formel aus Zelle in VBA einlesen und ändern
11.09.2015 12:32:01
Rudi
Hallo, 
Sub HebbettG()
Dim s As String, a, i As Integer
s = Range("A2").FormulaLocal
a = Split(s, "!")
For i = 1 To UBound(a)
If Right(a(i - 1), 6) = "InputA" Then
a(i) = Replace(Left(a(i), 2), "2", "3") & Mid(a(i), 3)
End If
Next
s = Join(a, "!")
MsgBox s
End Sub
Gruß
Rudi

Anzeige
AW: Formel aus Zelle in VBA einlesen und ändern
11.09.2015 12:42:51
Gerd
Hallo Rudi!
Das geht. Man kann Aufgaben einfach im eigenen Verständnis interpretieren.
Sub bb()
Dim strKette As String
strKette = Replace(Cells(2, 1).FormulaLocal, "InputA!A2", "InputA!A3")
MsgBox strKette
End Sub
Gruß Gerd

AW: Formel aus Zelle in VBA einlesen und ändern
11.09.2015 12:52:08
Herbert
Hallo Gerd,
vielen Dank für Deine Lösung. Die ist so weit so gut. Doch was mache ich, wenn die Angaben in der Formel jedesmal anders sind und anstatt InputA!A2 nur noch InputA!B2 oder InputA!H2 kommt?
Rudis Vorschlag ist genau das, was ich gesucht habe! Aber trotzdem, vielen Dank für Deinen Vorschlag.
Servus

Anzeige
AW: Formel aus Zelle in VBA einlesen und ändern
11.09.2015 12:46:24
Herbert
Hallo Rudiiiu,
kennst Du das höchste Lob, was Dir aus dem Munde eines Urbayern zu Teil werden kann? Nein? Dann sage ich es Dir jetzt: "A Hund bist fei scho!"!!! Kannst Du gerne recherchieren, doch das ist verbrieft und versiegelt!
In diesem Sinne: "A Hund bist fei scho!"!!! Und mercie vielmals!
Servus

Anzeige
Ergänzung
11.09.2015 12:52:58
Rudi
Hallo,
falls es auch mal um 2- und 3-buchstabige Zellen geht: 
Sub HebbettG()
Dim s As String, a1, a2, i
s = Range("A2").FormulaLocal
a1 = Split(s, "!")
For i = 1 To UBound(a1)
If Right(a1(i - 1), 6) = "InputA" Then
a2 = Split(a1(i), ";")
a2(0) = Replace(a2(0), "2", "3")
a1(i) = Join(a2, ";")
End If
Next
s = Join(a1, "!")
MsgBox s
End Sub

Gruß
Rudi

Anzeige
AW: Ergänzung: Mercie nochmals! owt
11.09.2015 13:01:13
Herbert
,,

AW: Formel aus Zelle in VBA einlesen und ändern
11.09.2015 12:43:28
Daniel
Hi
da musst du wohl in einer Schleife durch den Text gehen.
hier mal eine Variante für ein- und zweibuchtabige Spalten.
sollte deine Tabelle auf auf 3-Buchstabenspalten referenzieren, dann kannst du das ja entsrpechend ergänzen:
Sub test()
Dim FO As String
Dim i As Long
FO = Cells(1, 1).Formula
i = 1
Do
i = InStr(i, FO, "InputA!")
If i = 0 Then Exit Do
i = i + Len("InputA!")                          '--- Zeiger auf Adresse setzen
If Mid(FO, i, 3) Like "[A-Z]2," Then            '--- Ein Spaltenbuchstabe
Mid(FO, i + 1, 1) = "3"
ElseIf Mid(FO, i, 4) Like "[A-Z][A-Z]2," Then   '--- Zwei Spaltenbuchstaben
Mid(FO, i + 2, 1) = "3"
End If
Loop
Cells(1, 1).Value = FO
End Sub
Gruß Daniel

Anzeige
AW: Formel aus Zelle in VBA einlesen und ändern
11.09.2015 12:56:14
Herbert
Hallo Daniel,
vielen Dank für Deinen Lösungsvorschlag. Leider brachte er bei mir nicht das gewünschte Ergebnis. Aber macht ja nix, der gute Wille zählt. Außerdem ist Rudis Lösung genau das was ich suchte.
Servus

AW: Formel aus Zelle in VBA einlesen und ändern
11.09.2015 13:16:45
Daniel
Hi
was funktioniert denn nicht?
was wäre denn dein gewünschtes Ergebnis und welches Ergebnis hat mein Makro anstatt geliefert?
falls du nur die Formeln auf deutsch brauchst, dann ersetze das ".Formula" durch ".FormualLocal"
und in den beiden LIKE-Funktionen das "," durch ";"
der eigentliche Unterschied zwischen Rudis und meinem Makro ist, das bei mir wirklich nur die Zeile 2 auf die Zeile 3 geändert wird, während bei Rudi auch die Zeilen 12, 22, 32, 42 usw zu 13, 33, 33, 43 usw würden, falls sie in der Formel den vorkommen.
Gruß Daniel

Anzeige
12, 22, 32, 42 usw zu 13, 33, 33, 43
11.09.2015 13:30:46
Rudi
Hallo Daniel,
berechtigter Einwand.
Function HebbettG(s As String, strSheet As String, r1 As Long, r2 As Long)
Dim a1, a2, i
s = Range("A2").FormulaLocal
a1 = Split(s, "!")
For i = 1 To UBound(a1)
If Right(a1(i - 1), 6) = strSheet Then
a2 = Split(a1(i), ";")
If Range(a2(0)).Row = r1 Then
a2(0) = Cells(r2, Range(a2(0)).Column).Address(0, 0)
End If
a1(i) = Join(a2, ";")
End If
Next
HebbettG = Join(a1, "!")
End Function


Sub test()
MsgBox HebbettG(Range("A2").FormulaLocal, "InputA", 2, 3)
End Sub

Gruß
Rudi

Anzeige
AW: 12, 22, 32, 42 usw zu 13, 33, 33, 43
11.09.2015 15:39:58
Herbert
Hallo Rudi,
in meinem Falle ist das unerheblich, da die Formeln immer nur in Zeile 2 stehen!
So, und jetzt muss ich das Ganze noch für 26 Spalten in eine "For - Next"-Schleife reinpacken. Doch das kriege ich hin.
Aber da fällt mir doch noch eine Frage ein: Ich will die Formelergebnisse der jeweils geänderten Formeln in ein Array packen (kann bis zu 1 Million und mehr Datensätze werden) und das Array dann als csv-Datei speichern. Wie würdest Du das Array dimensionieren?
Servus

Anzeige
AW: Formel aus Zelle in VBA einlesen und ändern
11.09.2015 15:03:16
Herbert
Hallo Daniel,
Rudis Code bringt mir diesen String = gewünschtes Ergebnis:
=VERKETTEN(InputA!A3;"||";InputB!F2;"||";InputA!B3;"||";InputB!G2;"||"; InputA!H3;"||";InputA!C3)
Dein Code bringt mir das: "Campaign"
Danke und Servus

AW: Formel aus Zelle in VBA einlesen und ändern
11.09.2015 15:33:04
Herbert
Hallo Daniel,
wenn ich bei Deinem Code aus "FO = Cells(1, 1).Formula" das mache: FO = "Cells(2, 1).Formula", dann klappt es auch mit Deinem Code. Danke noch mal!
Servus

Anzeige
AW: Formel aus Zelle in VBA einlesen und ändern
11.09.2015 16:16:05
Daniel
Hallo Herbert
ok, verrate mir mal, woher ich das wissen hätte sollen, dass du die Formel in A2 stehen hast?
Bei VBA-Gut solltest du solche Kleinigkeiten selber anpassen können und nicht dem Antworter als fehlerhafte Lösung rückmelden.
Gruß Daniel

AW: Formel aus Zelle in VBA einlesen und ändern
11.09.2015 16:37:42
Herbert
Hallo Daniel,
gaaanz ruhig bleiben, das war doch kein Vorwurf an Dich, sondern eher an mich, weil ich nicht richtig gekuckt habe. Sorry, das hätte ich beim 2. Mal noch dazu schreiben sollen! Selbstverständlich kann ich das selbst anpassen, aber dazu muss ich es eben erst mal sehen. Und ich habe es leider übersehen. Also noch mal, das war kein Vorwurf an Dich, sondern nur eine Feststellung. Und so wie es jetzt aussieht, werde ich sogar doch Deinen Code verwenden, denn ich brauche das Formelergebnis in meiner Variablen.
Allerdings gibt es noch ein Problem, bei der Fortschreibung der Zeilen. Ab 10 steigt er momentan aus. Also, die Ursprungsformel steht immer in der Tab "Output" in der Zeile 2. Die darin enthaltenen Formeln sollen aber fortgeschrieben werden, von Zeile 2 bis Irgendwas. Irgendwas errechnet sich aus den Zeilen in InputA * die Zeilen in InputB. Was müsste ich in Deinem Code anpassen, um auch noch Zeilen bis in die Million darstellen zu können?
Servus

Anzeige
AW: Formel aus Zelle in VBA einlesen und ändern
11.09.2015 17:04:16
Daniel
Hi
probier mal 

If Mid(FO, i, 3) Like "[A-Z]2," Then            '--- Ein Spaltenbuchstabe
FO = Left(FO, i) & "hier deine Zahl" & Mid(FO, i + 2)
mit Rudis zweitem Code sollte es auch problemlos funktionieren, durch das ersetzen jeden beliebigen Wert anstelle der 2 einzufügen.
allerding würde ich, wenn du da mit einer Schleife arbeitest vorab in der Formel die 2 durch ein anderes Zeichen ersetzen, welches sonst in der Formel nicht vorkommt (z.b. "_") und diesen Text in einer Zwischenvariable speichern.
dann kannst du in der Folge einfach mit der Replace-Funktion dieses Zeichen durch deine Zeilennummer ersetzen und musst nicht jedesmal durch den Code durch.
Gruß Daniel

Anzeige
AW: Formel aus Zelle in VBA einlesen und ändern
11.09.2015 17:59:16
Herbert
Hallo Daniel,
vielen Dank, das klappt prima. Jedenfalls bis zur Zeile 9, dann wiederholt er sich dauernd. Schau mal:
0011||Überschrift 1||xyz GmbH||Text Zeile 1||Test Aktion||AUG15
0011||Überschrift 2||xyz GmbH||Text Zeile 2||Test Aktion||AUG15
0011||Überschrift 3||xyz GmbH||Text Zeile 3||Test Aktion||AUG15
0011||Überschrift 4||xyz GmbH||Text Zeile 4||Test Aktion||AUG15
0011||Überschrift 5||xyz GmbH||Text Zeile 5||Test Aktion||AUG15
0011||Überschrift 6||xyz GmbH||Text Zeile 6||Test Aktion||AUG15
0011||Überschrift 7||xyz GmbH||Text Zeile 7||Test Aktion||AUG15
0011||Überschrift 8||xyz GmbH||Text Zeile 8||Test Aktion||AUG15
0011||Überschrift 9||xyz GmbH||Text Zeile 9||Test Aktion||AUG15
0011||Überschrift 9||xyz GmbH||Text Zeile 9||Test Aktion||AUG15
0011||Überschrift 9||xyz GmbH||Text Zeile 9||Test Aktion||AUG15
Und ich finde nicht, wo ich das erweitern kann. Vor allem kann es ja auch bis in die Sechsstelligkeit gehen. Kannst Du mir da noch bitte helfen?
Servus

Anzeige
AW: Formel aus Zelle in VBA einlesen und ändern
11.09.2015 18:02:13
Daniel
Hallo Herbert
du solltest mittlerweile wissen, dass ich, um dir helfen zu können, wissen muss wie dein Code und die dazugehörige Tabelle aussieht.
Gruß Daniel

AW: Formel aus Zelle in VBA einlesen und ändern
11.09.2015 18:21:09
Herbert
Hallo Daniel,
OK, ich lade die Datei hoch. In ein paar Minuten ist es so weit.
Servus

AW: Formel aus Zelle in VBA einlesen und ändern
11.09.2015 18:44:39
Herbert
Hi Daniel,
anbei nun meine Beispieldatei. Vielen Dank im Voraus.
https://www.herber.de/bbs/user/100144.xlsm
Servus

Anzeige
AW: Formel aus Zelle in VBA einlesen und ändern
11.09.2015 19:59:04
Daniel
Hi
ich glaube nicht dass man das programmieren muss.
du kannst doch die Liste in der Tabelle mit Formeln erstellen und dann die ganze Tabelle als CSV speichern.
Im Prinzip so
für InputB:
Index(InputB!A:A;Rest(Zeile()-2;AnzahlWerte in InputB)+2)
für InputA:
Index(InputA!A:A;Ganzzahl((Zeile()-2)/AnzahlWerte in InputB)+2)
damit ab Zeile 2 die Tabelle bis zum Ende füllen und dann Tabelle als ganzes als CSV speichern.
Gruß Daniel

Anzeige
AW: Formel aus Zelle in VBA einlesen und ändern
11.09.2015 20:17:49
Herbert
Hi Daniel,
das mit den Formeln haben wir ja schon. Doch damit läuft das Teil an die 20 Minuten! Deshalb wollen wir es mit VBA probieren. Das ist der Grund.
Servus

AW: Formel aus Zelle in VBA einlesen und ändern
11.09.2015 20:35:22
Daniel
dann lies doch die Daten komplett in zwei Arrays ein und kombiniere dann über zwei geschachtelte Schleifen der beiden Arrays.
Das sollte dann schneller sein als jedesmal den Wert aus den Tabellen zu lesen.
Gruß Daniel

Anzeige
AW: Formel aus Zelle in VBA einlesen und ändern
12.09.2015 10:03:44
Herbert
Hallo Daniel,
das mit dem einlesen der Daten in zwei Arrays ist ein super Vorschlag, daran habe ich noch gar nicht gedacht! Das einlesen würde ich ja noch hinbekommen, aber das kombinieren der beiden Arrays ist mir nicht geläufig. Kannst Du mir dabei bitte noch helfen?
Servus

Anzeige
AW: Formel aus Zelle in VBA einlesen und ändern
12.09.2015 15:25:17
Daniel
Hi
im Prinzip so:
ReDim arr3(1 To (UBound(arr1) + 1) * (UBound(arr2) + 1), 1)
For x = 0 To UBound(arr1)
For y = 0 To UBound(arr2)
z = z + 1
arr3(z, 1) = arr1(x) & arr2(y)
Next
Next
bei der Berechnung der Anzahl der Elemente in den Quell- und im Zielarray musst du immer beachten, ob du ein 0- oder ein 1-basiertes Array hast.
ich habe hier im Beispiel für die Quelle zwei normale eindimensionale 0-basierte Arrays verwendet, für das ZielArray jedoch ein 1-basiertes zweidimensionales, weil man das besser in die Zellen zurückschreiben kann.
Gruss Daniel
Anzeige
;

Forumthreads zu verwandten Themen

VBA Code / Freitags Werte aus Zelle auslesen
potetos00

Guten Tag,
ich bitte um Hilfe für folgendes Problem:
ich möchte aus den Arbeitsblatt "Berechnung" den Wert der Zelle "E5" JEDEN FREITAG auslesen. Dieser Wert soll dann in das Arbeitsblatt "Übersicht" in die Zelle "D2" eingetragen werden. In der Zelle E5 steht immer eine Zahl.
z.b: a...
20.08.2011 15:08:34
Thread-ID: 1226909
10 Beiträge
Anzeige
VBA Formel aus Blatt auslesen und in For-Schleife
Alex

Hallo,
ich möchte für ein größeres Marko verschiedene Formeln (zB. y=2*a) aus einem Arbeitsblatt auslesen und dann über eine For Schleife nutzen. Das Ergebnis soll dann in die Tabelle geschrieben werden. Da die Formel geänderbar sein soll, kann sie leider nicht dirket ins Makro schreiben.<...
13.01.2017 17:11:22
Thread-ID: 1534931
6 Beiträge
Formeltext aus Zelle auslesen
Gernot

Hallo Leute,wie kann ich denn in einer Schleife beim prüfen des Zellinhalts nicht das Ergebnis einer Formel sondern den Text der Formel herausbekommen??Mit Cells(x,y).Value bekomme ich nur das Ergebnis der Formel.Ist bestimmt ganz einfach wenn man es weiß!
Vielen Dank schon mal!
Gruß
G...
20.02.2003 14:25:24
Thread-ID: 222086
4 Beiträge
Formel aus einer Zelle Auslesen
Ralf

Hallo,
Ich hätte eine kleine Frage zu Formeln mit Excel. In einer Zelle habe ich folgenden Bezug =Tab1!A197. Nun möchte ich aus einer anderen Zellen den Bezug Tab1!A197 auslesen und diesen weiter verwenden.
Wie kann ich jetzt das machen, ich habs mit verschiedenen Funktionen probiert, do...
26.10.2004 14:18:47
Thread-ID: 506884
5 Beiträge
per VBA Werte aus einer zelle auslesen
Ulf

Ich möchte per VBA den wert aus einer zelle auslesen, in der eigentlich kein wert steht sondern nur ein verweis: ='Z:\HA\[ha.xls]offen'!$E15
In der Zelle wird also ein Wert aus einer anderen Excel Datei geholt. Wenn ich jetzt im Makro anwende: Range("n6").Select:name8$ = ActiveCell.Fo...
02.03.2005 20:56:37
Thread-ID: 579732
5 Beiträge
VBA Code anstelle von Formel für Zellen auslesen
Formel

Hallo,
Es ist in Excel ja möglich, mittels Formel eine Zelle aus einem anderen Arbeitsblatt auszulesen mittels z.B. =Tabelle1!C34"! Ist es denn auch möglich Excel mittels VBA-Code zu sagen "Suche in Tabelle1 nach dem namen "Volkswagen" und gib mir den Wert, der zwei Zellen dahinter steht in...
07.03.2006 14:50:25
Thread-ID: 741284
9 Beiträge
Formelergebnis aus Zelle auslesen
ABO

Hallo Excel Cracks!
Wie kann ich ein Formelergebnis aus einer Zelle auslesen und in eine ander Zelle einfügen?
Formelergibnis Spalte "C"
Ergibnis mit VBA in Spalte "D" einfügen
Gruß ABO
17.10.2007 12:05:46
Thread-ID: 916944
4 Beiträge
Anzeige
Formel aus Zelle auslesen aber in englis
Peter
Hallo,
in einer Zelle steht eine Formel. Wenn ich diese mit "Range("E13").Formula" auslese("=HEUTE()"), wird das Ergebnis in deutsch dargestellt.
Wie kann diese in Englisch ("=TODAY()") umgewandelt werden?
Gruss
Peter
03.11.2021 09:52:59
Thread-ID: 1854833
20 Beiträge
VBA Teilstring aus Zelle auslesen
Phil
Hi zusammen,
ich habe folgendes Problem:
ich habe in einer Excel Liste eine Spalte die "kommentar" heißt, hier geben unsere Mitarbeiter, Infos und kommentare zu einem Auftrag ein.
Das kann das so aussehen:
DHL / 230009873 / 2x Paket L
4x Paket S / GLS / 230004562
2300024987...
01.07.2022 14:06:23
Thread-ID: 1889449
3 Beiträge
VBA -Pfad aus Zelle auslesen und ergänze
Tim
Hallo liebe Gemeinschaft,

ich habe ein Problem und bin die letzten Stunden auf der Suche nach einer Lösung verzweifelt. Und zwar arbeite ich in Tabelle2 und möchte aus einer Zelle den hinterlegten Teilpfad auslesen (in Tabelle1 Zelle A1 = \\srvxxxxxx\Musterorder) und diesen in VBA durch de...
26.04.2023 11:26:30
Thread-ID: 1928910
3 Beiträge
Entdecke relevante Threads

Schau dir verwandte Threads basierend auf dem aktuellen Thema an

Alle relevanten Threads mit Inhaltsvorschau entdecken
Anzeige
Anzeige

Infobox / Tutorial

Formel aus Zelle in VBA einlesen und ändern

Schritt-für-Schritt-Anleitung

  1. Formel aus Zelle auslesen: Du kannst die Formel einer aktiven Zelle in VBA auslesen, indem du den folgenden Code verwendest:

    Sub FormelAuslesen()
   Dim Formel As String
   Formel = ActiveCell.FormulaLocal
   Debug.Print Formel
End Sub

  2. Teile der Formel ändern: Um eine bestimmte Zahl in der Formel zu ersetzen, kannst du die Replace-Funktion nutzen. Hier ein Beispiel, das die "2" durch eine "3" ersetzt:

    Sub FormelAendern()
   Dim Formel As String
   Formel = ActiveCell.Formula
   Formel = Replace(Formel, "2", "3")
   Debug.Print Formel
End Sub

  3. Ergebnis in eine Variable speichern: Wenn du das neue Formelergebnis in einer Variable speichern möchtest, kannst du dies so machen:

    Dim neuesErgebnis As String
neuesErgebnis = Evaluate(Formel)

Häufige Fehler und Lösungen

  • Fehler bei der Anwendung von Replace: Wenn du unterschiedliche Spalten bearbeiten möchtest, könnte die direkte Anwendung von Replace nicht funktionieren. Stattdessen solltest du jeden Teil der Formel individuell ansteuern.

  • Formel wird nicht korrekt eingelesen: Stelle sicher, dass du .Formula anstelle von .FormulaLocal verwendest, wenn die Formel in Englisch geschrieben ist.

Alternative Methoden

  • Verwende Schleifen für komplexe Formeln: Wenn deine Formel komplex ist, könntest du eine Schleife nutzen, um durch die Zeichen der Formel zu iterieren und spezifische Änderungen vorzunehmen. Hier ein Beispiel:

    Sub KomplexAendern()
   Dim Formel As String
   Dim i As Integer
   Formel = ActiveCell.FormulaLocal
   For i = 1 To Len(Formel)
       ' Hier kannst du spezifische Änderungen vornehmen
   Next i
End Sub

  • VBA-Funktionen nutzen: Du kannst auch eigene Funktionen in VBA erstellen, um häufige Ersetzungen oder Berechnungen durchzuführen.

Praktische Beispiele

  1. Einfaches Beispiel: Angenommen, du hast die Formel =VERKETTEN(InputA!A2; "||"; InputB!B2) in Zelle A1. Um die "2" in "3" zu ändern:

    Sub Beispiel1()
   Dim Formel As String
   Formel = Range("A1").FormulaLocal
   Formel = Replace(Formel, "2", "3")
   MsgBox Formel
End Sub

  2. Komplexere Formeln: Bei Formeln, die unterschiedliche Zellbezüge haben, wie =VERKETTEN(InputA!A2; "||"; InputB!F2), könntest du Rudi's Ansatz verwenden:

    Sub HebbettG()
   Dim s As String, a, i As Integer
   s = Range("A2").FormulaLocal
   a = Split(s, "!")
   For i = 1 To UBound(a)
       If Right(a(i - 1), 6) = "InputA" Then
           a(i) = Replace(Left(a(i), 2), "2", "3") & Mid(a(i), 3)
       End If
   Next
   s = Join(a, "!")
   MsgBox s
End Sub

Tipps für Profis

  • Debugging: Nutze Debug.Print, um den aktuellen Wert von Variablen zu überprüfen, während du den Code ausführst.
  • Fehlerbehandlung: Implementiere Fehlerbehandlungsroutinen, um unerwartete Ergebnisse abzufangen.
  • Modularität: Schreibe Deine VBA-Programme modular, indem du Funktionen erstellst, die spezifische Aufgaben übernehmen. So wird der Code übersichtlicher und leichter wartbar.

FAQ: Häufige Fragen

1. Wie kann ich eine Formel in VBA aus einer bestimmten Zelle auslesen?
Du kannst die Formel mit Range("A1").FormulaLocal auslesen, wobei "A1" die Zelle ist, aus der du lesen möchtest.

2. Was ist der Unterschied zwischen .Formula und .FormulaLocal?
.Formula gibt die Formel in Englisch zurück, während .FormulaLocal die Formel in der Sprache zurückgibt, die für die Excel-Instanz eingestellt ist.

3. Wie gehe ich mit einer großen Anzahl von Datensätzen um?
Wenn du mit Hunderttausenden von Datensätzen arbeitest, ist es effizienter, die Daten in Arrays zu laden und die Verarbeitung dort durchzuführen, um das Tempo zu erhöhen.

4. Was mache ich, wenn meine Formel von Zeile 2 bis zur Million reicht?
Du kannst eine Schleife verwenden, um die Formel in jeder Zeile zu ändern oder die Ergebnisse in ein Array zu speichern und später auszugeben.

Beliebteste Forumthreads (12 Monate)

Jetzt das Excel-Portal bewerten: Deine Stimme zählt!
Anzeige
Anzeige
Entdecke mehr
Finde genau, was du suchst

Die erweiterte Suchfunktion hilft dir, gezielt die besten Antworten zu finden

Suche nach den besten Antworten
Unsere beliebtesten Threads

Entdecke unsere meistgeklickten Beiträge in der Google Suche

Top 100 Threads jetzt ansehen
Anzeige