VBA Abfrage Passwort

Thomas · 2018-01-17T20:40:41+00:00

Hallo zusammen, ich hätte ein Anliegen und hoffe dass so was möglich ist. In der jeweiligen Spalten kommt ein x rein. Diese X werden zusammengezählt. Ich habe die Abfrage, wenn mehr wie 2 (B1) dann soll eine Fehlermeldung kommen."Anzahl überschritten" Danach soll eine Input kommen bitte Passwort eingeben ( oder Abbrechen) dann gebe ich das Passwort ein und dann wird das X eingetragen sonst abbruch.Die Zahl 2 darf nicht überschritten werden ohne die Eingabe des Passwortes. Wäre sowas möglich ? Ich hab schon mal angefangen, aber ich hab null plan  Danke Thomas https://www.herber.de/bbs/user/119050.xlsb

Hallo Thomas,
Die Formeln in Zeile 1 brauchst du nicht.

' **********************************************************************
' Modul: Tabelle1  Typ: Element der Mappe(Sheet, Workbook, ...)
' **********************************************************************

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
Dim strPW As String, objRng As Range

On Error GoTo ErrorHandler
Application.EnableEvents = False

If Not Intersect(Target, Range("C3:H100")) Is Nothing Then
  For Each objRng In Intersect(Target, Range("C3:H100"))
    If Application.CountIf(objRng.EntireColumn, "x") > 2 Then
      strPW = InputBox("Die Anzahl wird überschritten!" & vbLf & vbLf & _
        "Um den Eintrag vornehmen zu können, müssen Sie das Passort eingeben!", "Passwort")
      If strPW <> cstrPW Then
        Application.Undo
        objRng = ""
        objRng.Select
        Exit For
      End If
    End If
  Next
End If

ErrorHandler:
Application.EnableEvents = True
End Sub

' **********************************************************************
' Modul: Modul1  Typ: Allgemeines Modul
' **********************************************************************

Option Explicit

Public Const cstrPW = "test" 'Passwort

Gruß Sepp

Hallo Thomas,
warum dauernd wechselnde Bedingungen und andere Spalten?

' **********************************************************************
' Modul: Tabelle1  Typ: Element der Mappe(Sheet, Workbook, ...)
' **********************************************************************

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
Dim strPW As String, objRng As Range

On Error GoTo ErrorHandler
Application.EnableEvents = False

If Not Intersect(Target, Range("C3:H100")) Is Nothing Then
  For Each objRng In Intersect(Target, Range("C3:H100"))
    If LCase(objRng) = "x" And Application.CountIfs(Columns(objRng.Column), "x", Columns(6), "Lager") > 2 Then
      strPW = InputBox("Die Anzahl wird überschritten!" & vbLf & vbLf & _
        "Um den Eintrag vornehmen zu können, müssen Sie das Passort eingeben!", "Passwort")
      If strPW <> cstrPW Then
        Application.Undo
        objRng = ""
        objRng.Select
        Exit For
      End If
    End If
  Next
End If

ErrorHandler:
Application.EnableEvents = True
End Sub

' **********************************************************************
' Modul: Modul1  Typ: Allgemeines Modul
' **********************************************************************

Option Explicit

Public Const cstrPW = "test" 'Passwort

Gruß Sepp

Forumthread: VBA Abfrage Passwort

11
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

VBA Abfrage Passwort

Forumthread: VBA Abfrage Passwort

11 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

11
Beiträge zum Forumthread

Beiträge zu diesem Forumthread