Herbers Excel/VBA-Archiv

Autofilter mit Passwortschutz beim öffnen entferne

• Autofilter mit Passwortschutz beim öffnen entferne von Stephan vom 21.10.2014 12:07:45
• AW: Autofilter mit Passwortschutz beim öffnen entferne - von fcs am 21.10.2014 14:16:14
  • AW: Autofilter mit Passwortschutz beim öffnen entferne - von Stephan am 21.10.2014 15:03:51

Betrifft: Autofilter mit Passwortschutz beim öffnen entferne von: Stephan
Geschrieben am: 21.10.2014 12:07:45

Guten Tag zusammen,

Ich habe eine Passwortgeschützte Tabelle bei der der Autofilter aktiv ist.
Beim öffnen der Tabelle soll jedoch jeweils der Autofilter entfernt werden und die Tabelle jedoch wieder mit Passwortschutz versehen werden. Dabei soll der Filter bedient werden können. Auch soll das Makro zu keinem Fehler kommen, falls beim Öffnen kein Filter gesetzt wird. Ich habe versucht das ganze mit diversen Makros die ich aus dem Netz gefunden haben zu basteln. Kommt jedoch immer zu einem Fehlerüberlauf.

Gestartet habe ich mit folgende Makro:

Private Sub Workbook_Open()
Worksheets("KVP@Wander_Liste").ShowAllData
End Sub

Dies funkttioniert auch soweit, jedoch nicht mit Passwort und es eben kommt auch zu einem Fehler beim öffnen, falls kein Filter gesetzt ist. Hat jemand eine Lösung.

Ich wünsche allseits en Guete.

Lieber Gruss Stephan

Betrifft: AW: Autofilter mit Passwortschutz beim öffnen entferne von: fcs
Geschrieben am: 21.10.2014 14:16:14

Hallo Stephan,

etwa so

Private Sub Workbook_Open()
    Dim wks As Worksheet
    
    Set wks = Worksheets("KVP@Wander_Liste")
    With wks
      If .AutoFilterMode = True Then
        If .FilterMode = True Then
          .Unprotect Password:="test"
          .ShowAllData
          .Protect Password:="test", AllowFiltering:=True
        End If
      End If
    End With
End Sub

'oder so

Private Sub Workbook_Open()
    Dim wks As Worksheet, intFilter As Integer
    
    Set wks = Worksheets("KVP@Wander_Liste")
    With wks
      If .AutoFilterMode = True Then
        If .FilterMode = True Then
          .Unprotect Password:="test"
          For intFilter = 1 To .AutoFilter.Filters.Count
            If .AutoFilter.Filters(intFilter).On = True Then
              .AutoFilter.Range.AutoFilter Field:=intFilter
            End If
          Next
          .Protect Password:="test", AllowFiltering:=True
        End If
      End If
    End With
End Sub

Gruß
Franz

Betrifft: AW: Autofilter mit Passwortschutz beim öffnen entferne von: Stephan
Geschrieben am: 21.10.2014 15:03:51

Hallo Franz,

super funktioniert einwandfrei. Besten Dank!

Lieber Gruss
Stephan

Beiträge aus den Excel-Beispielen zum Thema "Autofilter mit Passwortschutz beim öffnen entferne"