Live-Forum - Die aktuellen Beiträge
Datum
Titel
20.10.2025 10:29:26
Userform Multipage - Page auswählen
19.10.2025 21:57:06
Diagrammpunkte in unterschiedlichen Farben je nach Wert
19.10.2025 18:21:56
Prüfen, ob Bild geladen wurde
19.10.2025 15:24:14
VBA -Drucken nur, wenn ich mit bestimmtem WLAN verbunden bin
Keine passende Antwort im Forumarchiv gefunden?
Stelle deine Frage im Live-Forum
Anzeige
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Vorheriger Thread
Vorheriger Thread
Rückwärts Blättern
308to312
308to312
Aktuelles Verzeichnis
Verzeichnis Übersicht
Verzeichnis Übersicht
Übersicht Verzeichnisse
Nächster Thread
Nächster Thread
Vorwärts blättern
Inhaltsverzeichnis

Worksheet_Change: mehrere Zellen auswählen

Forumthread: Worksheet_Change: mehrere Zellen auswählen

Worksheet_Change: mehrere Zellen auswählen
16.09.2003 09:08:11
Franz W.
Hallo Fachleute,

ich habe mal wieder eine Frage, von der ich nicht weiß, ob das überhaupt geht.

Mit folgendem Code setze ich je nachdem ob die Zelle leer ist oder nicht einen Kommentar ein oder lösche ihn wieder:


Private Sub Worksheet_Change(ByVal Target As Range)
Dim Cmt As Comment
Dim cl As Range
Application.ScreenUpdating = False
Set cl = Target
If Not cl.Comment Is Nothing Then
cl.Comment.Delete
End If
If cl = "" Then
If cl.Column = 2 Then
Set Cmt = cl.AddComment
Cmt.Text "Zählernummer"
Cmt.Visible = True
ElseIf cl.Column = 3 Then
Else
Exit Sub
End If
With Cmt.Shape
.TextFrame.AutoSize = True
With .TextFrame.Characters.Font
.Name = "Arial"
.Size = 12
End With
End With
Application.DisplayCommentIndicator = xlCommentIndicatorOnly
End If
End Sub


Das klappt auch bestens, wenn ich lediglich eine einzige Zelle auswähle.

Wenn ich nun mehrere Zellen gleichzeitig auswähle und die "Löschen"-Taste drücke um alle auf einmal zu löschen, dann kommt bei der Zeile " If cl = "" Then " die Fehlermeldung: "Typen unverträglich" (was ja eigentlich eine falsche Dim bedeutet?!?). Gibt es dafür eine Lösung? Oder kann das gar nicht gehen?

Vielen Dank schon mal im Voraus und Grüße
Franz
Anzeige

16
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: Worksheet_Change: mehrere Zellen auswählen
16.09.2003 09:18:46
Hajo_Zi
Hallo Franz

ich bin nun nicht an meinem Homecomputer. Schaue mal auf meine Homepage da gibts es ein Code für mehr als 3 bedingte Formatierungen. Dort ist es eingearbeitet falls mehr als eine Zelle ausgefüllt wird.

Adresse unter Profile links

Gruß Hajo
AW: Worksheet_Change: mehrere Zellen auswählen
16.09.2003 10:14:05
Franz W.
Hallo Hajo,

vielen Dank, habs jetzt mal damit versucht:


Private Sub Worksheet_Change(ByVal Target As Range)
Dim Cmt As Comment
Dim cl As Range
Dim RaBereich As Range, RaZelle As Range
' Bereich der Wirksamkeit
Set RaBereich = Range("A1:Q200")
Application.ScreenUpdating = False
Set cl = Target
If Not cl.Comment Is Nothing Then
cl.Comment.Delete
End If
For Each RaZelle In Range(Target.Address)
If Not Intersect(RaZelle, RaBereich) Is Nothing Then
If cl.Column = 2 Then
Set Cmt = cl.AddComment
Cmt.Text "Zählernummer"
Cmt.Visible = True
Else
Exit Sub
End If
With Cmt.Shape
.TextFrame.AutoSize = True
With .TextFrame.Characters.Font
.Name = "Arial"
.Size = 12
End With
End With
Application.DisplayCommentIndicator = xlCommentIndicatorOnly
End If
Next
End Sub



aber auch hier hab ich dasselbe Problem wie bei UDos Vorschlag: er mault bei der Zeile:

Set Cmt = " cl.AddComment " mit der Meldung: " Ungültiger Prozeduraufruf oder ungütliges Argument."

Ändere ich das in " Set Cmt = c.AddComment ", kommt die Meldung: " Anwendungs- oder objektorientierter Fehler. "
Anzeige
Die hier ist richtig!!
16.09.2003 10:16:02
Franz W.
Hallo Hajo,

vielen Dank, habs jetzt mal damit versucht:


Private Sub Worksheet_Change(ByVal Target As Range)
Dim Cmt As Comment
Dim cl As Range
Dim RaBereich As Range, RaZelle As Range
' Bereich der Wirksamkeit
Set RaBereich = Range("A1:Q200")
Application.ScreenUpdating = False
Set cl = Target
If Not cl.Comment Is Nothing Then
cl.Comment.Delete
End If
For Each RaZelle In Range(Target.Address)
If Not Intersect(RaZelle, RaBereich) Is Nothing Then
If cl.Column = 2 Then
Set Cmt = cl.AddComment
Cmt.Text "Zählernummer"
Cmt.Visible = True
Else
Exit Sub
End If
With Cmt.Shape
.TextFrame.AutoSize = True
With .TextFrame.Characters.Font
.Name = "Arial"
.Size = 12
End With
End With
Application.DisplayCommentIndicator = xlCommentIndicatorOnly
End If
Next
End Sub



aber auch hier hab ich dasselbe Problem wie bei UDos Vorschlag: er mault bei der Zeile:

Set Cmt = " cl.AddComment " mit der Meldung: " Ungültiger Prozeduraufruf oder ungütliges Argument."

Danke und Grüße
Franz

P.S.: Die vorige Nachricht ist aus Versehen rausgerutscht, sorry
Anzeige
AW: Die hier ist richtig!!
16.09.2003 10:31:11
Hajo_Zi
Hallo Franz

in Deinem Code wurde Application.ScreenUpdating nicht wieder eingeschaltet.


Private Sub Worksheet_Change(ByVal Target As Range)
Dim Cmt As Comment
Dim cl As Range
Dim RaBereich As Range, RaZelle As Range
' Bereich der Wirksamkeit
Set RaBereich = Range("A1:Q200")
Application.ScreenUpdating = False
Set cl = Target
If Not cl.Comment Is Nothing Then cl.Comment.Delete
For Each RaZelle In Range(Target.Address)
If Not Intersect(RaZelle, RaBereich) Is Nothing Then
If cl.Column = 2 Then
With cl
.AddComment
.Comment.Text "Zählernummer"
.Comment.Visible = True
With .Comment.Shape.TextFrame
.AutoSize = True
.Characters.Font.Name = "Arial"
.Characters.Font.Size = 12
End With
End With
Else
GoTo Ende
End If
Application.DisplayCommentIndicator = xlCommentIndicatorOnly
End If
Next
Ende:
Set RaBereich = Nothing
Set cl = Nothing
Application.ScreenUpdating = True
End Sub


Gruß Hajo
Anzeige
Leider noch nicht...
16.09.2003 11:00:46
Franz W.
Hallo Hajo,

toll Dein Code! Schaut schon gleich viel sauberer aus als meiner (ob ich das auch mal noch lerne...???)

Application.ScreenUpdating = True: stimmt, hab ich noch vergessen.

Aber leider gibt es noch zwei Probleme:

1. Wenn ich mehrere Zellen markiert habe und Delete drücke, kommt jetzt eine Fehlermeldung bei: " .AddComment " und zwar: " Anwendungs- oder objektorientierter Fehler. "

2. Wenn ich jetzt in eine Zelle der Spalte B etwas eintrage, bleibt der Kommentar bestehen. Da sollte er eigentlich weg. Der Kommentar sollte nur in einer leeren Zelle stehen, sollte also geschrieben werden, wenn der Inhalt der Zelle gelöscht wird und verschwinden, wenn was eingetragen wird.

Grüße
Franz
Anzeige
AW: Leider noch nicht...
16.09.2003 11:06:10
Hajo_Zi
Hallo Franz

ich habe auf Deinen Code aufgebaut. Jetzt habe ich mir das nochmal vorgenommen. Aber irgendwie fehlt mir noch der Zusammenhang. Ich Vermute mal wenn keine Inhalt in der Zelle dann soll auch kein Kommenmtar??


Private Sub Worksheet_Change(ByVal Target As Range)
Dim Cmt As Comment
Dim RaBereich As Range, RaZelle As Range
' Bereich der Wirksamkeit
Set RaBereich = Range("A1:Q200")
Application.ScreenUpdating = False
Set cl = Target
For Each RaZelle In Range(Target.Address)
If Not Intersect(RaZelle, RaBereich) Is Nothing Then
If RaZelle.Column = 2 Then
If Not RaZelle.Comment Is Nothing Then RaZelle.Comment.Delete
With RaZelle
.AddComment
.Comment.Text "Zählernummer"
.Comment.Visible = True
With .Comment.Shape.TextFrame
.AutoSize = True
.Characters.Font.Name = "Arial"
.Characters.Font.Size = 12
End With
End With
Else
GoTo Ende
End If
Application.DisplayCommentIndicator = xlCommentIndicatorOnly
End If
Next
Ende:
Set RaBereich = Nothing
Application.ScreenUpdating = True
End Sub


Gruß Hajo
Anzeige
AW: Leider noch nicht...
16.09.2003 11:09:48
Franz W.
Hallo Hajo,

doch, genau umgekehrt: wenn kein Inhalt, dann Kommentar. Wenn Inhalt, dann kein Kommentar. Sinn: es geht um viele Zellen (auch noch in anderen Spalten, das füge ich noch ein. Die bekommen dann andere Kommentare). Diese Zelle sind i. d. R. gefüllt. Als kleine Hilfe, falls eine Zelle leer ist, soll der Kommentar dann anzeigen, was rein soll.Drum soll er verschwinden, wenn was drin steht.

Grüße
Franz
Anzeige
AW: Leider noch nicht...
16.09.2003 11:28:09
Hajo_Zi
Hallo Franz

ich habe mal paar Kommentare geschrieben


Private Sub Worksheet_Change(ByVal Target As Range)
Dim Cmt As Comment
Dim RaBereich As Range, RaZelle As Range
' Bereich der Wirksamkeit
Set RaBereich = Range("A1:Q200")
Application.ScreenUpdating = False
Set cl = Target
For Each RaZelle In Range(Target.Address)
If Not Intersect(RaZelle, RaBereich) Is Nothing Then
If RaZelle.Column = 2 Then  ' Kommentare nur in Spalte B
If Not RaZelle.Comment Is Nothing Then RaZelle.Comment.Delete
If RaZelle = Empty Then
' vorhandene Kommentare löschen
With RaZelle
.AddComment
.Comment.Text "Zählernummer"
' braucht nicht sein
'.Comment.Visible = True
With .Comment.Shape.TextFrame
.AutoSize = True
.Characters.Font.Name = "Arial"
.Characters.Font.Size = 12
End With
End With
End If
' Else
'GoTo Ende
' Warum Ende sobald eine Zelle nicht in Spalte B wird For Next Schleife verlassen
' und die restlichen Zellen werden nicht mehr abgearbeitet
End If
' diese Anweisung ist mir nicht ganz klar
Application.DisplayCommentIndicator = xlCommentIndicatorOnly
End If
Next
'Ende:
Set RaBereich = Nothing
Application.ScreenUpdating = True
End Sub


Gruß Hajo
Anzeige
Jaa!! So tut er's !!
16.09.2003 11:59:33
Franz W.
Hallo Hajo,

toll, ganz vielen Dank. So klappt er in allen Variationen. Auch mit meinen Erweiterungen für andere Spalten (Code siehe unten)! Hab da noch nicht alle drin, da kommen noch 4 Stück dazu.

Und drum hätte ich noch eine abschließende Frage, wenn Du noch magst: ich könnte mit dem Code schon leben, auch wenn er kilometerlang ist. Er klappt ja. Aber gibt es theoretisch da noch eine Möglichkeit, das zu verkürzen? Ist das überhaupt möglich, da ja für jede Spalte was anderes in den Kommentar eingetragen wird? Falls ja, in welche Richtung müsste ich da denken? Nur einen Ansatz bitte, sollte dann schon selber irgendwie klar kommen, denke ich.


Private Sub Worksheet_Change(ByVal Target As Range)
Dim Cmt As Comment
Dim cl As Range, RaBereich As Range, RaZelle As Range
' Bereich der Wirksamkeit
Set RaBereich = Range("A1:Q200")
Application.ScreenUpdating = False
Set cl = Target
For Each RaZelle In Range(Target.Address)
If Not Intersect(RaZelle, RaBereich) Is Nothing Then
If RaZelle.Column = 2 Then  ' Kommentare nur in Spalte B
If Not RaZelle.Comment Is Nothing Then RaZelle.Comment.Delete
If RaZelle = Empty Then
' vorhandene Kommentare löschen
With RaZelle
.AddComment
.Comment.Text "Zählernummer"
With .Comment.Shape.TextFrame
.AutoSize = True
.Characters.Font.Name = "Arial"
.Characters.Font.Size = 12
End With
End With
End If
ElseIf RaZelle.Column = 3 Then  ' Kommentare nur in Spalte B
If Not RaZelle.Comment Is Nothing Then RaZelle.Comment.Delete
If RaZelle = Empty Then
' vorhandene Kommentare löschen
With RaZelle
.AddComment
.Comment.Text "Kd.-Nr."
With .Comment.Shape.TextFrame
.AutoSize = True
.Characters.Font.Name = "Arial"
.Characters.Font.Size = 12
End With
End With
End If
ElseIf RaZelle.Column = 6 Then  ' Kommentare nur in Spalte B
If Not RaZelle.Comment Is Nothing Then RaZelle.Comment.Delete
If RaZelle = Empty Then
' vorhandene Kommentare löschen
With RaZelle
.AddComment
.Comment.Text "Ablesung 1. Quartal"
With .Comment.Shape.TextFrame
.AutoSize = True
.Characters.Font.Name = "Arial"
.Characters.Font.Size = 12
End With
End With
End If
ElseIf RaZelle.Column = 8 Then  ' Kommentare nur in Spalte B
If Not RaZelle.Comment Is Nothing Then RaZelle.Comment.Delete
If RaZelle = Empty Then
' vorhandene Kommentare löschen
With RaZelle
.AddComment
.Comment.Text "Ablesung 2. Quartal"
With .Comment.Shape.TextFrame
.AutoSize = True
.Characters.Font.Name = "Arial"
.Characters.Font.Size = 12
End With
End With
End If
ElseIf RaZelle.Column = 10 Then  ' Kommentare nur in Spalte B
If Not RaZelle.Comment Is Nothing Then RaZelle.Comment.Delete
If RaZelle = Empty Then
' vorhandene Kommentare löschen
With RaZelle
.AddComment
.Comment.Text "Ablesung 3. Quartal"
With .Comment.Shape.TextFrame
.AutoSize = True
.Characters.Font.Name = "Arial"
.Characters.Font.Size = 12
End With
End With
End If
ElseIf RaZelle.Column = 12 Then  ' Kommentare nur in Spalte B
If Not RaZelle.Comment Is Nothing Then RaZelle.Comment.Delete
If RaZelle = Empty Then
' vorhandene Kommentare löschen
With RaZelle
.AddComment
.Comment.Text "Ablesung 4. Quartal"
With .Comment.Shape.TextFrame
.AutoSize = True
.Characters.Font.Name = "Arial"
.Characters.Font.Size = 12
End With
End With
End If
End If
' diese Anweisung ist mir nicht ganz klar
'Application.DisplayCommentIndicator = xlCommentIndicatorOnly
End If
Next
Set RaBereich = Nothing
Application.ScreenUpdating = True
End Sub


Vielen Dank und Grüße
Franz
Anzeige
Kommentar in mehreren Spalten
16.09.2003 12:32:38
Hajo_Zi
Hallo Franz

mal ungetestet


Private Sub Worksheet_Change(ByVal Target As Range)
Dim RaBereich As Range, RaZelle As Range
' Bereich der Wirksamkeit
Set RaBereich = Range("A1:Q200")
Application.ScreenUpdating = False
For Each RaZelle In Range(Target.Address)
If Not Intersect(RaZelle, RaBereich) Is Nothing Then
If RaZelle.Column = 2 Or RaZelle.Column = 3 Or _
RaZelle.Column = 6 Or RaZelle.Column = 8 Or _
RaZelle.Column = 10 Or RaZelle.Column = 12 Then
' vorhandene Kommentare löschen
If Not RaZelle.Comment Is Nothing Then RaZelle.Comment.Delete
If RaZelle = Empty Then
With RaZelle
.AddComment
Select Case RaZelle.Column
Case 2
.Comment.Text "Zählernummer"
Case 3
.Comment.Text "Kd.-Nr."
Case 6
.Comment.Text "Ablesung 1. Quartal"
Case 8
.Comment.Text "Ablesung 2. Quartal"
Case 10
.Comment.Text "Ablesung 3. Quartal"
Case 12
.Comment.Text "Ablesung 4. Quartal"
End Select
With .Comment.Shape.TextFrame
.AutoSize = True
.Characters.Font.Name = "Arial"
.Characters.Font.Size = 12
End With
End With
End If
End If
End If
Next
Set RaBereich = Nothing
Application.ScreenUpdating = True
End Sub


Gruß Hajo
Anzeige
AW: Jaa!! So tut er's !!
16.09.2003 12:40:02
xXx
Hallo,
da bin ich wieder.
1. Die Kommentartexte würde ich als Array definieren z.B.strKomm(2)="Kommentar2", strKomm(3)="Kommentar2 etc. Index immer wie die Spalte in die sie gehören.
2. Die If/ElseIf-bedingungen durch select case ersetzen.
Select Case RaZelle.Column
Case 2, 3, 6, 8, 10, 12
If Not RaZelle.Comment Is Nothing Then RaZelle.Comment.Delete
If RaZelle = Empty Then
' vorhandene Kommentare löschen
With RaZelle
.AddComment
.Comment.Text strkomm(RaZelle.column)
With .Comment.Shape.TextFrame
.AutoSize = True
.Characters.Font.Name = "Arial"
.Characters.Font.Size = 12
End With
End With
end select

Das ist jetzt mit der heißen Nadel gestrick und soll wirklich nur als Ansatz dienen.
Den Code solltest du aber so stark verkürzen können.

Gruß aus'm Pott
Udo
Anzeige
IHR SEID SUPER !!!
16.09.2003 13:00:41
Franz W.
Hallo Hajo, hallo Udo,

ich find das echt toll von Euch!!

Schon Dein vorgezeichneter Weg, Udo ... wie kriegt man so schnell mal einen Ansatz aus dem Ärmel geschüttelt?!?

Und Deine Lösung, Hajo, klappt ja zu 100 Prozent!! Da wäre ich ja wohl drei Tage dran gesessen. Zumal ich Case noch nicht eingesetzt hatte, da gab's gleich mal was Neues für mich.

Ich danke Euch beiden ganz herzlich, Ihr habt mich für heute echt glücklich gemacht!!

Viele Grüße
Franz
Anzeige
Danke für die Rückmeldung oT
16.09.2003 13:01:40
Hajo_Zi
Nur zum Anschauen...
16.09.2003 13:39:43
Franz W.
Hallo Hajo,

weil ich das Ganze nicht für mich mache, sondern für einen Freund, und weil sich die Tabelle noch vergrößern wird, habe ich am Anfang noch was rein, um den Bereich der Wirksamkeit variabel zu gestalten. Hier der Anfang vom Code:


Private Sub Worksheet_Change(ByVal Target As Range)
Dim ws As Worksheet
Dim a&, b As Byte
Dim RaBereich As Range, RaZelle As Range
' Bereich der Wirksamkeit
Set ws = ActiveSheet
a = ws.UsedRange.Row + ws.UsedRange.Rows.Count - 1
b = ws.UsedRange.Column + ws.UsedRange.Columns.Count - 1
Set RaBereich = Range(Cells(1, 1), Cells(a, b))
Application.ScreenUpdating = False
Worksheets("Ablesungen").Unprotect
For Each RaZelle In Range(Target.Address)
End Sub


Grüße
Franz
Anzeige
AW: Worksheet_Change: mehrere Zellen auswählen
16.09.2003 09:18:53
xXx
Hallo,
einen Bereich aus mehreren Zellen kannst du nicht auf "" abfragen.
Mach's so:

For each c in cl.cells
if c="" then
.
.
next c

Gruß aus'm Pott
Udo
Danke, aber Folgeproblem
16.09.2003 09:44:07
Franz W.
Hallo Udo,

vielen Dank für Deine Hilfe, aber jetzt mault er bei der Zeile:

Set Cmt = " cl.AddComment " mit der Meldung: " Ungültiger Prozeduraufruf oder ungütliges Argument."

Ändere ich das in " Set Cmt = c.AddComment ", kommt die Meldung: " Anwendungs- oder objektorientierter Fehler. "

Das weiß ich leider nicht weiter, kannst Du mir bitte nochmal helfen?

Vielen Dank und Grüße
Franz
Anzeige
;

Forumthreads zu verwandten Themen

Formular aufrufen VBA über mehrere Zellen
andreas

Hallo zusammen,
habe eine Tabelle da will ich wenn eine Zelle von B20 - B500 selektiert ist das Formular "Werkzeuge" aufrufen.
Wie muss ich dafür den Code schreiben?
Danach sollte nach einlesen der Daten über das Formular, die Zelle "C?" in der selben Zeile angewählt werden, dazu m...
12.11.2010 12:17:18
Thread-ID: 1186487
3 Beiträge
Excel_VBA_ mehrere Zellen Addieren
B.Varli

Hi Leute,
Das ist mein Erster Beitrag.
Folgendes Problem hab ich das mir den kopf zerbricht.
Ich möchte gerne mehrere zellen addieren.
Am besten mit VBa in Excel
Ich hab ein kleines beispiel erstellt um mein problem zu veranschaulichen.
https://www.herber.de/bbs/user/914...
11.07.2014 17:51:21
Thread-ID: 1369977
3 Beiträge
Anzeige
VBA - Befehl für mehrere Zellen =
Jörg
Hallo,
ich habe z.B. folgenden VBA Befehl:
Case "A15"
If Rows("22:24").Hidden Then
Rows("22:24").Hidden = False
Else
If Rows("25:28").Hidden Then Rows("22:24").Hidden = True
End If
Dieser Befehl wiederholt sich bei A26, A37, A48,... und der Bereich ist immer gleich...
11.07.2016 06:36:24
Thread-ID: 1503640
9 Beiträge
zellen einfügen in mehrere dateien vba
Sasko

Hallo zusammen,
folgendes Problem: Ich habe 900 Excel Dateien, alle im selben Order und alle Listen haben den gleichen Aufbau etc.
Jetzt muss in jede einzelne Excel Datei, 1 neue Zelle eingebaut werden an einer bestimmtem Stelle mit Überschrift. Natürlich kann man jetzt in 500 Dateien...
09.06.2017 16:03:17
Thread-ID: 1563252
2 Beiträge
VBA - mehrere Zellen versetzen
Arnd-Olav

Guten Morgen,
keine Ahnung warum, aber ich krieg eine - eigentlich glaube ich "einfache" Sache - nicht hin.
- Screenshot ist hier:
Ich habe eine Tabelle (SAP Extrakt) in der immer mal wieder einige Zeilen versetzt sind.
Die Tabelle begingt ab Spalte "C". Die versetzten Zeilen t...
14.02.2019 11:38:18
Thread-ID: 1675540
2 Beiträge
Excel VBA - Text über mehrere markierte Zellen
ManuelL.

Hallo Excel-Profis!
Lange Zeit war ich heimlicher Mitleser hier und ihr habt mir schon sehr weiter geholfen. Bei einem Problem komme ich aber einfach nicht weiter und hoffe auf eure Hilfe, da ich auch sonst im Netz nichts gefunden habe.
Ich habe eine Produktionsplanung erstellt wo mithi...
14.03.2019 13:59:29
Thread-ID: 1681269
4 Beiträge
Anzeige
VBA Wertübergabe mehrerer Zellen über eine Schleif
Constantin

Guten Tag,
ich sitze hier an einem Makro-Code und komme nicht weiter.
Ich möchte aus der Tabelle "Gefiltert" die Werte aus den einzelnen Zellen in eine andere Tabelle "Druckversion" reinkopieren und hier ist ein anderer formatierter Zellbereich. Je nach dem was ich an Daten gefiltert zu...
30.07.2019 10:46:04
Thread-ID: 1704928
3 Beiträge
Zellensortierung nach Summe mehrerer Spalten (VBA)
Martin

Hallo,
gibt es eine Möglichkeit zur Sortierung eines Zellenbereiches die Summe von mehreren Spalten als Sortierschlüssel anzugeben (wie es z.B. per SQL möglich ist) ohne dafür eine extra "Hilfsspalte" anlegen zu müssen? Zudem wäre es wichtig, dass die Formatierung der zu sortierenden Zellen...
07.08.2019 14:13:27
Thread-ID: 1706376
4 Beiträge
Anzeige
VBA - Kopfzeile - mehrere Zellen
Manuela

Hallo Ihr Super-VBA'ler!
Bitte dringend um euere Hilfe:
Kann ich mit Hilfe von VBA eine Kopfzeile definieren, wenn ich die Werte aus nicht zusammenhängenden Zellen, also z.B. den Zellen A4:G8 und A36:G36 auf jeder Seite haben möchte?
Ist das möglich?
Wenn ja, wie würde da der Co...
01.01.1970 00:00:00
Thread-ID: 406651
3 Beiträge
Anzeige
Mit VBA mehrere Zellen + Variable in Formel einfüg
zoltan

Hallo zusammen,
ich möchte mittels VBA einer Zelle eine Formel zuweisen. Habe eine Funktion geschrieben, der als Argument fünf Zellen übergeben werden sollen.
Beispiel:
=Berechne(A1; B1; C1; D1; E1)
Man kann in einer Dialogbox neue Einträge in das Sheet einfügen und daraus soll...
26.05.2004 13:40:40
Thread-ID: 433365
5 Beiträge
VBA: Range m. mehreren Zellen mit 1 multiplizieren
Peter

Liebes Forum
Untenstehender Code läuft wunderbar. Im Range ist in jeder Zeile ein Datum im Textformat; nach dem Durchlaufen im Datumsformat. Das Problem ist nur, dass ich zuerst in die einzelnen Zellen klicken muss, damit das neue Format übernommen wird.
Deshalb möchte ich den den Range...
02.02.2007 11:06:47
Thread-ID: 842972
3 Beiträge
VBA aktivieren bei Änderung in mehreren Zellen
Richard

Hallo liebe XL Freunde
Ich habe folgendes VBA:
Option Explicit Private Sub Worksheet_Change(ByVal Target As Range) If Target.Address "$M$12" Then Exit Sub Dim r As Range For Each r In ActiveSheet.Range("20:58").Rows If r.Cells(16) = 0 Then r.EntireRow.Hidden = True If r.Cells(16) = 1...
30.12.2007 03:46:00
Thread-ID: 937691
4 Beiträge
Entdecke relevante Threads

Schau dir verwandte Threads basierend auf dem aktuellen Thema an

Alle relevanten Threads mit Inhaltsvorschau entdecken
Anzeige

Infobox / Tutorial

Mehrere Zellen mit Worksheet_Change in Excel bearbeiten

Schritt-für-Schritt-Anleitung

Um mehrere Zellen in Excel mit dem Worksheet_Change-Ereignis zu bearbeiten und sicherzustellen, dass Kommentare korrekt hinzugefügt oder entfernt werden, kannst du den folgenden VBA-Code verwenden:

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim RaBereich As Range, RaZelle As Range
    ' Bereich der Wirksamkeit
    Set RaBereich = Range("A1:Q200")
    Application.ScreenUpdating = False
    For Each RaZelle In Target
        If Not Intersect(RaZelle, RaBereich) Is Nothing Then
            If RaZelle.Column = 2 Then  ' Kommentare nur in Spalte B
                If Not RaZelle.Comment Is Nothing Then RaZelle.Comment.Delete
                If RaZelle = Empty Then
                    With RaZelle
                        .AddComment
                        .Comment.Text "Zählernummer"
                        With .Comment.Shape.TextFrame
                            .AutoSize = True
                            .Characters.Font.Name = "Arial"
                            .Characters.Font.Size = 12
                        End With
                    End With
                End If
            End If
        End If
    Next
    Application.ScreenUpdating = True
End Sub

Dieser Code ermöglicht es dir, in einem bestimmten Bereich (hier "A1:Q200") zu arbeiten. Er fügt einen Kommentar hinzu, wenn die Zelle leer ist, und entfernt den Kommentar, wenn die Zelle gefüllt wird.

Häufige Fehler und Lösungen

  1. "Typen unverträglich": Dieser Fehler tritt auf, wenn du versuchst, mehrere Zellen gleichzeitig zu bearbeiten. Stelle sicher, dass du den Code so anpasst, dass er jede Zelle in der Target-Range einzeln behandelt, wie im obigen Code gezeigt.

  2. "Ungültiger Prozeduraufruf oder ungültiges Argument": Dieser Fehler kann auftreten, wenn du versuchst, einen Kommentar auf einer Zelle hinzuzufügen, die bereits einen Kommentar hat oder leer ist. Überprüfe, ob die Zelle leer ist, bevor du einen Kommentar hinzufügst.

  3. Kommentare bleiben bestehen: Wenn du einen Kommentar erwartest, der verschwindet, wenn in die Zelle etwas eingegeben wird, stelle sicher, dass du den Kommentar korrekt entfernst, wenn die Zelle nicht mehr leer ist.

Alternative Methoden

Eine alternative Methode zur Handhabung von Kommentaren in Excel ist die Verwendung eines Arrays, um die Kommentartexte zu definieren. Dies kann den Code kürzer und übersichtlicher machen:

Dim strKomm(1 To 12) As String
strKomm(2) = "Zählernummer"
strKomm(3) = "Kd.-Nr."
' usw. für andere Spalten

Select Case RaZelle.Column
    Case 2, 3, 6, 8, 10, 12
        If Not RaZelle.Comment Is Nothing Then RaZelle.Comment.Delete
        If RaZelle = Empty Then
            With RaZelle
                .AddComment
                .Comment.Text strKomm(RaZelle.Column)
                ' Größe und Schriftart wie gewohnt einstellen
            End With
        End If
End Select

Praktische Beispiele

Hier sind einige Anwendungsbeispiele für den Code:

  • Zählernummer in Spalte B: Wenn du in Spalte B eine Zelle leer lässt, wird der Kommentar "Zählernummer" angezeigt.
  • Kunden-Nummer in Spalte C: Ähnlich kannst du für andere Spalten verschiedene Kommentare definieren, abhängig von der Spalte, in die du schreibst.

Tipps für Profis

  • Verwende Application.ScreenUpdating = False, um das Flackern des Bildschirms beim Ausführen des Codes zu vermeiden.
  • Denke daran, die Application.ScreenUpdating = True am Ende des Codes wieder zu aktivieren, um die Bildschirmaktualisierung wiederherzustellen.
  • Nutze die Möglichkeit, mit Select Case den Code zu vereinfachen, anstatt viele If-ElseIf-Anweisungen zu verwenden.

FAQ: Häufige Fragen

1. Wie kann ich mehrere Zellen gleichzeitig bearbeiten? Du kannst den Code so anpassen, dass er eine Schleife über jede Zelle im Target-Bereich durchführt, um Kommentare hinzu- oder zu entfernen.

2. Warum wird mein Kommentar nicht angezeigt? Stelle sicher, dass die Zelle leer ist, bevor du versuchst, einen Kommentar hinzuzufügen. Überprüfe auch, ob der Kommentar möglicherweise bereits vorhanden ist.

3. Wie kann ich den Bereich der Wirksamkeit anpassen? Du kannst die Zeile Set RaBereich = Range("A1:Q200") ändern, um den gewünschten Bereich festzulegen, in dem die Kommentare angezeigt werden sollen.

4. Gibt es eine Möglichkeit, den Code zu verkürzen? Ja, indem du Arrays für Kommentartexte verwendest und Select Case anstelle von If-ElseIf-Anweisungen nutzt, kannst du den Code erheblich kürzen und lesbarer machen.

Beliebteste Forumthreads (12 Monate)

Jetzt das Excel-Portal bewerten: Deine Stimme zählt!
Anzeige
Anzeige
Entdecke mehr
Finde genau, was du suchst

Die erweiterte Suchfunktion hilft dir, gezielt die besten Antworten zu finden

Suche nach den besten Antworten
Unsere beliebtesten Threads

Entdecke unsere meistgeklickten Beiträge in der Google Suche

Top 100 Threads jetzt ansehen
Anzeige