SVERWEIS oder WVERWEIS mit VERGLEICH

Forumthread: SVERWEIS oder WVERWEIS mit VERGLEICH

28.04.2008 10:04:23

massimo17

Hallo,
ich versuche einen SVERWEIS zu erzeugen, der in Abhängigkeit von zwei Variablen aus einer Matrix einen Wert wiedergibt.
Ich habe es schon mit SVERWEIS und WVERWEIS versucht, nur komme ich nicht drauf, wie er bei der zweiten Variable den richtigen Bereich finde.
Hier die Beispiel Tabelle:
https://www.herber.de/bbs/user/51916.xls
Danke schonmal für die Hilfe!

3
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: SVERWEIS oder WVERWEIS mit VERGLEICH

28.04.2008 11:16:00

fcs
AW: SVERWEIS oder WVERWEIS mit VERGLEICH

28.04.2008 12:48:19

Sebastian
AW: SVERWEIS oder WVERWEIS mit VERGLEICH

30.04.2008 07:53:21

fcs

AW: SVERWEIS oder WVERWEIS mit VERGLEICH

28.04.2008 11:16:00

fcs

Hallo massimo,
um aus Matrix Spalte und Zeile zu picken kann man die Funktion INDEX in Verbindung mit VERGLEICH verwenden , wobei Spalte und Zeile jeweils mit VERGLEICH ermitelt werden.
=INDEX($A$1:$X$100;VERGLEICH(SuchbegriffZeile; $A$1:$A$100;0);VERGLEICH(SuchbegriffSPalte; $A$1:$X$1; 0))
oder
mit SVERWEIS, wobei die Spalte aus der der Wert gelesen werden soll mit VERGLEICH ermittelt wird.
=SVERWEIS(SuchbegriffZeile; $A$1:$X$100;VERGLEICH(SuchbegriffSPalte; $A$1:$X$1;0);FALSCH)
Hierbei kommt es ggf. auch darauf an, dass die letzten Parameter bei SVERWEIS bzw. VERGLEICH korrekt gesetzt werden, die bestimmen wie Zeilen/Spaltenwerte durchsucht werden sollen -exakte Übereinstimmung oder Suche in einer sortierten Liste.
Gruß
Franz

AW: SVERWEIS oder WVERWEIS mit VERGLEICH

28.04.2008 12:48:19

Sebastian

Ich weiß nich, ob ich es ganz verstanden habe. Wie kann ich denn jetzt bei einem Einsatz von 200 Einheiten Fluor mir den Index: XX danneben schreiben lassen. Also wie bringe ich Excel dazu zwischen das Suchkriterium in Abhängigkeit von den Mengenkriterium in der zweiten Tabelle zu finden?

AW: SVERWEIS oder WVERWEIS mit VERGLEICH

30.04.2008 07:53:21

fcs

Hallo Sebastian,
für eine optimale Nutzung der Funktionen SVERWEIS oder INDEX müsstest du die Basisdaten für die Indexwerte anders anordnen. Fluide in einer Spalte, die zugehörigen mengenabhängiben INDEX-Werte in den weiteren Spalten der gleichen Zeile. Zusätzlich benötigst du eine Hilfszeile für die Mengen, damit die VERGLEICH-Funktion funktioniert.
Falls du INDEX-Daten der Fluide so anordnen muss wie in der Tabelle2 (z.B. weil die Mengenbereiche variieren, dann kannst nach einfügen einer Hilfsspalte für den Datenbereichs jedes Mediums einen Namen festlegen und in der Tabelle1 die Funktion INDIREKT nutzen.
https://www.herber.de/bbs/user/51973.xls
Gruß
Franz
Beispiel:


Tabellenblattname: Tabelle2
A             B             C             D             E             F          G      _
1  Hilfszeile             0         99,99        199,99        299,99        399,99   500,01    _
2                     Index           für         Maneg            in         Liter             _
3       Fluid          500    _
4       Fluor          a.B.            XX           XXX          XXXX         XXXXX     a.B.    _
5       Chlor          a.B.             V            VV           VVV          VVVV     a.B.    _
6                                                                                               _
7                     Menge                                                                     _
8               Hilfsspalte           von           bis         Index                           _
9       Fluor         99,99           100           200            XX                           _
10                    199,99           200           300           XXX                           _
11                    299,99           300           400          XXXX                           _
12                    399,99           400           500         XXXXX                           _
13                    500,01                                                                     _
14       Chlor         99,99           100           200             V                           _
15                    199,99           200           300            VV                           _
16                    299,99           300           400           VVV                           _
17                    399,99           400           500          VVVV                           _
18                    500,01                                                                     _
Namen in der Tabelle:
Chlor:  =Tabelle2!$B$14:$E$18
Fluor:  =Tabelle2!$B$9:$E$13
Tabellenblattname: Tabelle1
A                       B        C       D
1
2                                    NR   Mittel   Menge
3                                     2    Fluor     200     XXX
4                                          Chlor     300     VVV
5                                     3    Fluor     500   XXXXX
6                                          Chlor     200      VV
7
8  Alternative Formel mit Bereichsnamen
9                                     2    Fluor     200     XXX
10                                          Chlor     300     VVV
11                                     3    Fluor     500   XXXXX
12                                          Chlor     200      VV
Benutzte Formeln:
D3:  =SVERWEIS(B3;Tabelle2!$A$4:$G$5;VERGLEICH(C3;Tabelle2!$B$1:$G$1;1)+1;FALSCH)
D4:  =SVERWEIS(B4;Tabelle2!$A$4:$G$5;VERGLEICH(C4;Tabelle2!$B$1:$G$1;1)+1;FALSCH)
D5:  =SVERWEIS(B5;Tabelle2!$A$4:$G$5;VERGLEICH(C5;Tabelle2!$B$1:$G$1;1)+1;FALSCH)
D6:  =SVERWEIS(B6;Tabelle2!$A$4:$G$5;VERGLEICH(C6;Tabelle2!$B$1:$G$1;1)+1;FALSCH)
D9:  =SVERWEIS(C9;INDIREKT(B9);4;WAHR)
D10:  =SVERWEIS(C10;INDIREKT(B10);4;WAHR)
D11:  =SVERWEIS(C11;INDIREKT(B11);4;WAHR)
D12:  =SVERWEIS(C12;INDIREKT(B12);4;WAHR)

Infobox / Tutorial

Schritt-für-Schritt-Anleitung

Matrix vorbereiten: Stelle sicher, dass deine Daten in einer geeigneten Matrix angeordnet sind. Die erste Spalte sollte die Suchkriterien enthalten, während die zugehörigen Werte in den nachfolgenden Spalten sind.
Formel wählen: Du kannst entweder die SVERWEIS- oder die WVERWEIS-Funktion verwenden, je nach der Ausrichtung deiner Daten:
- SVERWEIS: Wird verwendet, wenn die Suchkriterien in der ersten Spalte stehen.
- WVERWEIS: Wird verwendet, wenn die Suchkriterien in der ersten Zeile stehen.

Formel eingeben:

Für SVERWEIS könnte die Formel so aussehen:

=SVERWEIS(Suchkriterium; Matrix; Spaltenindex; FALSCH)

Für WVERWEIS könnte die Formel so aussehen:

=WVERWEIS(Suchkriterium; Matrix; Zeilenindex; FALSCH)

Nutzung von VERGLEICH: Um die Spalte oder Zeile dynamisch zu bestimmen, kannst du VERGLEICH in Verbindung mit SVERWEIS oder WVERWEIS verwenden:
```
=SVERWEIS(Suchbegriff; Matrix; VERGLEICH(SuchbegriffSpalte; Spaltenüberschrift; 0); FALSCH)
```

Häufige Fehler und Lösungen

Falsche Parameter: Überprüfe, ob die Parameter in deinen Formeln korrekt gesetzt sind. Insbesondere der letzte Parameter sollte auf FALSCH gesetzt werden, um eine exakte Übereinstimmung zu gewährleisten.
Daten nicht sortiert: Wenn du WAHR für die letzte Option in SVERWEIS oder WVERWEIS verwendest, stelle sicher, dass deine Daten sortiert sind, sonst erhältst du möglicherweise falsche Ergebnisse.
Falsche Matrixangaben: Achte darauf, dass die angegebene Matrix den richtigen Bereich umfasst. Ein häufiges Problem ist, dass der Bereich nicht die benötigten Daten enthält.

Alternative Methoden

Eine effektive Methode, um SVERWEIS oder WVERWEIS zu ersetzen, ist die Verwendung von INDEX in Kombination mit VERGLEICH. Diese Methode bietet mehr Flexibilität:

=INDEX(Matrix; VERGLEICH(SuchbegriffZeile; Suchbereich; 0); VERGLEICH(SuchbegriffSpalte; Spaltenüberschrift; 0))

Diese Formel gibt dir den Wert zurück, der sich an der Schnittstelle der gefundenen Zeile und Spalte befindet.

Praktische Beispiele

Hier ist ein Beispiel, das die Verwendung von SVERWEIS und VERGLEICH in Excel verdeutlicht:

Tabelle erstellen: Stelle sicher, dass deine Daten gut strukturiert sind.

Beispiel-Daten in Tabelle:

A       | B      | C
-----------------------
Produkt | Preis  | Menge
Apfel   | 1,00   | 100
Banane  | 0,50   | 200

Formel verwenden: Um den Preis einer Banane zu finden, kannst du folgende Formel nutzen:
```
=SVERWEIS("Banane"; A2:C4; 2; FALSCH)
```

Tipps für Profis

Verwendung von absoluten und relativen Bezügen: Wenn du Formeln kopierst, achte darauf, wo du absolute und relative Bezüge verwendest, um die gewünschten Ergebnisse zu erzielen.
Namen für Bereiche verwenden: Du kannst benannte Bereiche erstellen, um deine Formeln übersichtlicher zu gestalten.
Fehlerüberprüfung: Nutze die WENNFEHLER-Funktion, um Fehler in deinen SVERWEIS oder WVERWEIS-Formeln abzufangen:
```
=WENNFEHLER(SVERWEIS(...); "Nicht gefunden")
```

FAQ: Häufige Fragen

1. Was ist der Unterschied zwischen SVERWEIS und WVERWEIS?
SVERWEIS sucht in der ersten Spalte einer Matrix, während WVERWEIS in der ersten Zeile sucht. Du solltest wählen, welche Funktion für deine Datenstruktur am besten geeignet ist.

2. Wann benutzt man WVERWEIS und wann SVERWEIS?
Verwende SVERWEIS, wenn deine Suchkriterien in der ersten Spalte stehen. WVERWEIS ist sinnvoll, wenn deine Suchkriterien in der ersten Zeile angeordnet sind.

3. Kann ich SVERWEIS auch mit mehreren Kriterien verwenden?
Ja, dazu kannst du die INDEX- und VERGLEICH-Funktionen kombinieren, um flexiblere Abfragen zu erstellen.

Beliebteste Forumthreads (12 Monate)

SVERWEIS oder WVERWEIS mit VERGLEICH

Forumthread: SVERWEIS oder WVERWEIS mit VERGLEICH

3 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Infobox / Tutorial

SVERWEIS oder WVERWEIS mit VERGLEICH

Schritt-für-Schritt-Anleitung

Häufige Fehler und Lösungen

Alternative Methoden

Praktische Beispiele

Tipps für Profis

FAQ: Häufige Fragen

Beliebteste Forumthreads (12 Monate)

3
Beiträge zum Forumthread

Beiträge zu diesem Forumthread