Excel mit Outlook Synchronisieren

Kim · 2016-01-03T14:03:52+00:00

Hallo, ich hatte in der Vergangenheit schon einmal geschrieben. Leider war ich damals in Gedanken und habe statt Excel Access geschrieben. Später konnte ich die Idee nicht weiter verfolgen. Es geht darum, dass ich nach einer Idee suche, dass Excel die Aufgaben von Outlook Synchronisiert. Ich weiss in Outlook würde das reichen, aber ich bin Projektmanager und würde auch die Ergebnisse gerne dokumentieren und eine Übersicht haben, was ich in diesem Kalenderjahr alle bearbeitet habe. Ich könnte dann auch die Zeiten zu den jeweiligen Projekten direkt in einer Datei bearbeiten und als Diagramm darstellen etc. Ich habe bereits mehrere Fachbücher durchgelesen und finde leider keinen Hinweis ob man per VBA die Aufgaben abgleichen kann. Es ist möglich, dass es gar nicht geht, aber ein Import würde evtl. auch schon reichen. Hier bin ich für jeden Hinweis dankbar. Vielen Dank

Hallo, :-)
so der Spur nach:

Option Explicit
Sub Main()
Dim objOutMail As Object
Dim objTask As Object
Dim strTMP As String
Dim lngTMP As Long
On Error GoTo Fin
lngTMP = 1
Set objOutMail = CreateObject("Outlook.Application") _
.GetNamespace("MAPI").GetDefaultFolder(olFolderTasks)
For Each objTask In objOutMail.Items
With Tabelle1
.Cells(lngTMP, 1) = objTask.Subject
.Cells(lngTMP, 2) = objTask.CreationTime
.Cells(lngTMP, 3) = objTask.StartDate
.Cells(lngTMP, 4) = objTask.DueDate
.Cells(lngTMP, 5) = objTask.ReminderTime
Select Case objTask.Status
Case olTaskComplete: strTMP = "Erledigt"
Case olTaskDeferred: strTMP = "Zurückgestellt"
Case olTaskInProgress: strTMP = "In Bearbeitung"
Case olTaskNotStarted: strTMP = "Noch nicht begonnen"
Case olTaskWaiting: strTMP = "Noch wartend"
End Select
.Cells(lngTMP, 6) = strTMP
lngTMP = lngTMP + 1
strTMP = ""
End With
Next objTask
Fin:
Set objOutMail = Nothing
If Err.Number  0 Then MsgBox "Error: " & _
Err.Number & " " & Err.Description
End Sub

Servus
Case

Hallo Jens, :-)
Danke für den Hinweis. Da waren noch ein paar andere Konstanten aus Outlook auch nicht deklariert. :-[

Option Explicit
Sub Main()
Const olTaskInProgress = 1
Const olTaskNotStarted = 0
Const olFolderTasks = 13
Const olTaskComplete = 2
Const olTaskDeferred = 4
Const olTaskWaiting = 3
Dim objOutMail As Object
Dim objTask As Object
Dim strTMP As String
Dim lngTMP As Long
On Error GoTo Fin
lngTMP = 1
Set objOutMail = CreateObject("Outlook.Application") _
.GetNamespace("MAPI").GetDefaultFolder(olFolderTasks)
For Each objTask In objOutMail.Items
With Tabelle1
.Cells(lngTMP, 1) = objTask.Subject
.Cells(lngTMP, 2) = objTask.CreationTime
.Cells(lngTMP, 3) = objTask.StartDate
.Cells(lngTMP, 4) = objTask.DueDate
.Cells(lngTMP, 5) = objTask.ReminderTime
Select Case objTask.Status
Case olTaskComplete: strTMP = "Erledigt"
Case olTaskDeferred: strTMP = "Zurückgestellt"
Case olTaskInProgress: strTMP = "In Bearbeitung"
Case olTaskNotStarted: strTMP = "Noch nicht begonnen"
Case olTaskWaiting: strTMP = "Noch wartend"
End Select
.Cells(lngTMP, 6) = strTMP
lngTMP = lngTMP + 1
strTMP = ""
End With
Next objTask
Fin:
Set objOutMail = Nothing
If Err.Number  0 Then MsgBox "Error: " & _
Err.Number & " " & Err.Description
End Sub

Servus
Case

Excel mit Outlook Synchronisieren

Forumthread: Excel mit Outlook Synchronisieren

8
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Infobox / Tutorial