AW: CSV Datei per Macro Aktualisieren
09.03.2021 13:04:43
Nepumuk
Hallo,
so besser?
Option Explicit
Public Sub ImportCSV()
Dim objFileDialog As FileDialog
Dim objWorkbook As Workbook
Dim strFilePath As String
Set objFileDialog = Application.FileDialog(fileDialogType:=msoFileDialogOpen)
With objFileDialog
.AllowMultiSelect = False
.FilterIndex = 6
.InitialFileName = "H:\210308\oraculix\" ' Anpassen !!!
.Title = "Importdatei auswählen"
If .Show Then strFilePath = .SelectedItems(1)
End With
Set objFileDialog = Nothing
If strFilePath <> vbNullString Then
Set objWorkbook = Workbooks.Open(Filename:=strFilePath)
Call objWorkbook.Worksheets(1).Columns("A:J").Copy( _
Destination:=ThisWorkbook.ActiveSheet.Cells(1, 1))
Call objWorkbook.Close(SaveChanges:=False)
Set objWorkbook = Nothing
If ActiveSheet.ListObjects.Count = 1 Then _
Call ActiveSheet.ListObjects(1).Unlist
With Columns
.AutoFit
.ClearFormats
End With
ActiveSheet.ListObjects.Add(SourceType:=xlSrcRange, _
Source:=Range(Cells(1, 1), Cells(Rows.Count, 10).End(xlUp)), _
XlListObjectHasHeaders:=xlYes, _
TableStyleName:="TableStyleMedium15").Name = "Tabelle1"
End If
End Sub
Gruß
Nepumuk