Microsoft Excel

Herbers Excel/VBA-Archiv

Zugriff auf Ordner

Betrifft: Zugriff auf Ordner von: Markus
Geschrieben am: 25.08.2014 15:26:38

Hallo Excel-Forum,

ich hänge an fogenden Problem:
In einer Zusammenfassung sollen Informationen aus einer zu wählenden Exceldatei (immer verschiedene Namen aber gleich aufgebauter Inhalt) geholt werden.
Dies habe ich unten versucht. Klappt leider nicht ganz. Die Daten werden aus der Zusammenfassung gelesen nicht aus der neu geöffneten, aktiven Datei (gleicher Tabellenname).

Sub RefCalcSum() 'Zusammenfassung der Referenzteilkalkulation in Spalte M
Dim i As Integer, j As Integer, n As Integer
Dim strPfad As String
Dim wkbRef As Workbook, wkbTarget As Workbook


Set wkbTarget = Workbooks("Zusammenfassung.xlsm") 
i = 5

strPfad = "\Ordner1\Ordner2\Speicherordner\"  'Speicherort der Datenquellen

Application.Dialogs(xlDialogOpen).Show strPfad 'Auswählen und Öffnen der Quelle
Set wkbRef = ActiveWorkbook                    
j = Cells(Rows.Count, 12).End(xlUp).Row

'Ab hier soll in der Quelle die Spalte L  _
durchsucht werden und jeder Wert soll in die Zusammenfassung Tabelle 2 in Spalte M  _
untereinander geschrieben werden.

With wkbRef.Worksheets("Tabelle1")           
For n = i To j
    If .Cells(n, 12) <> "" Then
        wkbTarget.Worksheets("Tabelle2").Cells(Rows.Count, 13).End(xlUp).Offset(1, 0) = .Cells(  _
_
n, 10)
    End If
Next n

End With
End Sub
Gruß
Markus

  

Betrifft: AW: Zugriff auf Ordner von: Rudi Maintaire
Geschrieben am: 25.08.2014 16:09:07

Hallo,
teste mal:

Sub RefCalcSum() 'Zusammenfassung der Referenzteilkalkulation in Spalte M
  Dim i As Integer, n As Integer
  Dim strPfad As String
  Dim wksRef As Worksheet, wksTarget As Worksheet
  '
  Set wksTarget = Workbooks("Zusammenfassung.xlsm").Sheets("Tabelle2")
  i = 5
  strPfad = "\Ordner1\Ordner2\Speicherordner\"  'Speicherort der Datenquellen
  '
  With Application.Dialogs(xlDialogOpen)
    If .Show(strPfad) = -1 Then 'Auswählen und Öffnen der Quelle
      Set wksRef = ActiveWorkbook.Sheets("Tabelle1")
      
      'Ab hier soll in der Quelle die Spalte L _
        durchsucht werden und jeder Wert soll in die Zusammenfassung Tabelle 2 in Spalte M _
        untereinander geschrieben werden.
      
      With wksRef
        For n = i To .Cells(.Rows.Count, 12).End(xlUp).Row
          If .Cells(n, 12) <> "" Then
            wksTarget.Cells(wksTarget.Rows.Count, 13).End(xlUp).Offset(1) = .Cells(n, 10)
          End If
        Next n
      End With
      'wksRef.Parent.Close False
    End If
  End With
End Sub

Gruß
Rudi


  

Betrifft: AW: Zugriff auf Ordner von: Markus
Geschrieben am: 26.08.2014 08:53:49

Hallo Rudi,

danke für die Hilfe. Ich habe den Code getestet und nun geht es einwandfrei.

Gruß
Markus


 

Beiträge aus den Excel-Beispielen zum Thema "Zugriff auf Ordner"