Monat finden nach min/max wert

Forumthread: Monat finden nach min/max wert

19.12.2007 20:49:05

Karel

Hallo Forum.
Habe eine Sheet mit 2 Tabelle sehe beispiel
https://www.herber.de/bbs/user/48551.xls
in Tabelle 1 zeitraum von 12 Monaten mit min/max werten
1) in Tabelle 2 habe ich auswertung mit uber sverweis eingelesene Daten mit min/max
mochte gerne in zelle daneben die Monat ausgegeben bekommen welche monat als erste min wert hat und welche Monat der Max wert hat.
2) Kan men min/max wert auch direkt in Tabelle 2 bekomen ohne hilfsspalte in Tabelle 1
viele Gruße
Karel

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Monat finden nach min/max wert

19.12.2007 21:15:00

Josef

Hallo Karel,
Zu 1:
Bedarfsermittlung

	B	C	D	E	F	G	H	I	J	K	L
8		Bezeichnung	wert		wert
9	Item no.		Min	Monat	Max	Monat
10		Sverweis	Sverweis		Sverweis
11	10578	a	1	Nov 07	285	Apr 07
12	10603	b	1	Feb 07	43	Apr 07
13	14698	c	1	Feb 07	7	Mai 07
14	12962	d	11	Mai 07	69	Mrz 07
15	14839	e	21	Nov 07	176	Sep 07
16	14985	g	1	Feb 07	131	Apr 07
17	10668	h	2	Sep 07	11	Jan 07
18	12963	i	2	Feb 07	60	Nov 07
19	10599	j	1	Feb 07	76	Apr 07
20	15675	k	4	Dez 06	63	Apr 07
21	10600	l	1	Dez 06	42	Apr 07
22	16455	m	3	Apr 07	35	Jul 07

Formeln der Tabelle

Zelle	Formel
C11	=WENN(B11="";"";SVERWEIS(B11;ABC_XYZ;2;FALSCH))
D11	=WENN(B11="";"";SVERWEIS(B11;ABC_XYZ;16;FALSCH))
E11	=INDEX(ABC_XYZ!$D$2:$O$2;VERGLEICH(D11;BEREICH.VERSCHIEBEN(ABC_XYZ!$C$3;VERGLEICH(B11;ABC_XYZ!$B$4:$B$15;0); 1;1;12); 0))
F11	=WENN(B11="";"";SVERWEIS(B11;ABC_XYZ;17;FALSCH))
G11	=INDEX(ABC_XYZ!$D$2:$O$2;VERGLEICH(F11;BEREICH.VERSCHIEBEN(ABC_XYZ!$C$3;VERGLEICH(B11;ABC_XYZ!$B$4:$B$15;0); 1;1;12); 0))

Namen in Formeln

Zelle	Name	Bezieht sich auf
C11	ABC_XYZ	=ABC_XYZ!$B:$S
D11	ABC_XYZ	=ABC_XYZ!$B:$S
F11	ABC_XYZ	=ABC_XYZ!$B:$S

Namen verstehen

Excel Tabellen im Web darstellen Excel Jeanie HTML
Zu 2:
Geht, aber wenn die Hilfspalte nicht stört, würde ich es dabei belassen.

Gruß Sepp

AW: Monat finden nach min/max wert

19.12.2007 22:20:30

Karel

Hallo Sepp,
Sehr schon, genau so sollte es sein danke dir.
hilfssparte stört daten Tabelle 1 geht über 10.000 Zeilen sehr dynamisch komen manchmal Spalte dazu
Daten Tabelle 2 nur max 200 Zeilen andert sich nicht
viele grusse und Danke
Karel

AW: Monat finden nach min/max wert

19.12.2007 22:20:00

Karel

AW: Monat finden nach min/max wert

19.12.2007 22:33:49

Josef

Hallo Karel,
bei 10.000 Zeilen wird das mit Matrixformeln aber eine Weile rechnen.
Bedarfsermittlung

	B	C	D	E	F	G	H	I	J	K	L
8		Bezeichnung	wert		wert
9	Item no.		Min	Monat	Max	Monat
10		Sverweis	Sverweis		Sverweis
11	10578	a	1	Nov 07	285	Apr 07
12	10603	b	1	Feb 07	43	Apr 07
13	14698	c	1	Feb 07	7	Mai 07
14	12962	d	11	Mai 07	69	Mrz 07
15	14839	e	21	Nov 07	176	Sep 07
16	14985	g	1	Feb 07	131	Apr 07
17	10668	h	2	Sep 07	11	Jan 07
18	12963	i	2	Feb 07	60	Nov 07
19	10599	j	1	Feb 07	76	Apr 07
20	15675	k	4	Dez 06	63	Apr 07
21	10600	l	1	Dez 06	42	Apr 07
22	16455	m	3	Apr 07	35	Jul 07

Formeln der Tabelle

Zelle	Formel
C11	=WENN(B11="";"";SVERWEIS(B11;ABC_XYZ;2;FALSCH))
D11	{=MIN(WENN(BEREICH.VERSCHIEBEN(ABC_XYZ!$C$3;VERGLEICH(B11;ABC_XYZ!$B$4:$B$15;0); 1;1;12)<>0;BEREICH.VERSCHIEBEN(ABC_XYZ!$C$3;VERGLEICH(B11;ABC_XYZ!$B$4:$B$15;0); 1;1;12)))}
E11	=INDEX(ABC_XYZ!$D$2:$O$2;VERGLEICH(D11;BEREICH.VERSCHIEBEN(ABC_XYZ!$C$3;VERGLEICH(B11;ABC_XYZ!$B$4:$B$15;0); 1;1;12); 0))
F11	=MAX(BEREICH.VERSCHIEBEN(ABC_XYZ!$C$3;VERGLEICH(B11;ABC_XYZ!$B$4:$B$15;0); 1;1;12))
G11	=INDEX(ABC_XYZ!$D$2:$O$2;VERGLEICH(F11;BEREICH.VERSCHIEBEN(ABC_XYZ!$C$3;VERGLEICH(B11;ABC_XYZ!$B$4:$B$15;0); 1;1;12); 0))

Enthält Matrixformel:
Umrandende { } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!

Matrix verstehen

Namen in Formeln

Zelle	Name	Bezieht sich auf
C11	ABC_XYZ	=ABC_XYZ!$B:$S

Namen verstehen

Excel Tabellen im Web darstellen Excel Jeanie HTML

Gruß Sepp

AW: Monat finden nach min/max wert ot

21.12.2007 12:41:06

Karel

Hallo Sepp
Danke
Karel

Infobox / Tutorial

Schritt-für-Schritt-Anleitung

Daten vorbereiten: Stelle sicher, dass deine Daten in zwei Tabellen organisiert sind:
- Tabelle 1 enthält die Monate und die entsprechenden Werte.
- Tabelle 2 ist für die Auswertung mit den min/max Werten.
Min/Max Werte finden:
- Um das Minimum zu finden, kannst du die Formel =MIN(Bereich) in die gewünschte Zelle in Tabelle 2 eingeben.
- Für das Maximum verwendest du =MAX(Bereich).
Monat zu den Min/Max Werten zuordnen:
- Für das Minimum: Nutze die Formel =INDEX(Tabelle1!A:A,VERGLEICH(MIN(Bereich);Tabelle1!B:B;0)), um den entsprechenden Monat anzuzeigen.
- Für das Maximum: Verwende =INDEX(Tabelle1!A:A,VERGLEICH(MAX(Bereich);Tabelle1!B:B;0)).
Formeln in die entsprechenden Zellen einfügen: Füge die Formeln in die Zellen neben den Min/Max Werten in Tabelle 2 ein.
Hilfspalte vermeiden: Falls du die Hilfspalte in Tabelle 1 nicht nutzen möchtest, kannst du die obigen Formeln direkt in Tabelle 2 verwenden.

Häufige Fehler und Lösungen

Fehler: "#NV" in den Formeln: Dieser Fehler tritt auf, wenn die Werte nicht gefunden werden können. Überprüfe, ob die Bereiche korrekt angelegt sind.
Fehler: Falsche Monate: Stelle sicher, dass die Datensätze in Tabelle 1 und die Suchkriterien in Tabelle 2 übereinstimmen.

Alternative Methoden

Verwendung von Matrixformeln: Du kannst auch Matrixformeln verwenden, um die Min/Max Werte und die entsprechenden Monate zu berechnen:
```
=MIN(WENN(Bereich<>0;Bereich))
=INDEX(Monate;VERGLEICH(MIN(WENN(Bereich<>0;Bereich));Bereich;0))
```
Beachte, dass Matrixformeln mit STRG + SHIFT + ENTER eingegeben werden müssen.

Praktische Beispiele

Angenommen, du hast in Tabelle 1 folgende Daten:

Monat	Wert
Jan 2022	100
Feb 2022	200
Mär 2022	50
Apr 2022	300

Um den Monat mit dem Minimum (50) zu finden, kannst du die Formel in Tabelle 2 verwenden:

=INDEX(Tabelle1!A:A;VERGLEICH(MIN(Tabelle1!B:B);Tabelle1!B:B;0))

Tipps für Profis

Dynamische Bereichsnamen: Verwende dynamische Bereichsnamen für eine flexiblere Handhabung der Daten. So bleibt deine Formel auch bei Änderungen in der Datentabelle gültig.
Datenüberprüfung: Setze Datenüberprüfung ein, um sicherzustellen, dass nur gültige Werte in die relevanten Zellen eingegeben werden.

FAQ: Häufige Fragen

1. Frage: Kann ich auch mehrere Min/Max Werte gleichzeitig anzeigen?
Antwort: Ja, du kannst ähnliche Formeln für jeden gewünschten Wert erstellen, indem du die Bereiche entsprechend anpasst.

2. Frage: Funktionieren diese Formeln in allen Excel-Versionen?
Antwort: Die meisten Formeln sind in Excel 2010 und späteren Versionen verfügbar. Bei älteren Versionen kann es Einschränkungen geben.

Beliebteste Forumthreads (12 Monate)

Forumthread: Monat finden nach min/max wert

5
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Infobox / Tutorial

Monat nach min/max Wert in Excel finden

Schritt-für-Schritt-Anleitung

Häufige Fehler und Lösungen

Alternative Methoden

Praktische Beispiele

Tipps für Profis

FAQ: Häufige Fragen

Beliebteste Forumthreads (12 Monate)

Monat finden nach min/max wert

Forumthread: Monat finden nach min/max wert

5 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Infobox / Tutorial

Monat nach min/max Wert in Excel finden

Schritt-für-Schritt-Anleitung

Häufige Fehler und Lösungen

Alternative Methoden

Praktische Beispiele

Tipps für Profis

FAQ: Häufige Fragen

Beliebteste Forumthreads (12 Monate)

5
Beiträge zum Forumthread

Beiträge zu diesem Forumthread