Thema: Datenkombinationen per Makro ermitteln | Herbers Excel-Forum

Hallo Forum
Ich möchte per Makro Werte aus einer Spalte allen unterschiedlichen Werte aus einer anderen Spalte zuordnen.
Die Tabelle besteht aus Spalte A und B.
In Spalte A und B stehen Zahlen, die mehrmals an sich sowie als Kombination vorkommen.
Nun sollen in einer zweiten Tabelle die Werte aus Spalte A mit allen unterschiedlichen Werten aus Spalte B gelistet werden.
Die Auflistung soll so sein, dass die Werte aus Spalte A einmalig in der anderen Tabelle untereinander geschrieben werden, während alle gefundenen Werte aus Spalte B in der entsprechenden Zeile geschrieben werden.
So eine Art von Transportieren.
Zur Verdeutlichung ein Beispiel:
https://www.herber.de/bbs/user/65891.xlsm
Kennt jemand die Lösung für das Problem ?
Vielen Dank im Voraus.
Gruß Volker

HAllo Volker
Versuch dazu mal diesen Code:
Option Explicit


Public Sub test()
Dim MyDic As Object
Dim L As Long
Dim Arr As Variant
Dim K As Variant
Dim spl As Variant
Arr = Sheets("DAten").Range("A1").CurrentRegion.Value
Set MyDic = CreateObject("Scripting.dictionary")
'Unikate sammeln
For L = LBound(Arr) To UBound(Arr)
    If Not MyDic.exists(Arr(L, 1)) Then
        MyDic(Arr(L, 1)) = Arr(L, 2)
        Else:
        MyDic(Arr(L, 1)) = MyDic(Arr(L, 1)) & "####" & Arr(L, 2)
    End If
Next
'Ausgeben
K = MyDic.keys
For L = LBound(K) To UBound(K)
    With Sheets("Ergebnis")
        .Cells(L + 1, 1) = K(L)
        spl = Split(MyDic(K(L)), "####")
        .Cells(L + 1, 2).Resize(1, UBound(spl) + 1) = spl
    End With
Next
End Sub

ransi

Hallo ransi
Vielen Dank für Deine Mühe.
Das sieht schon sehr gut aus, es werden jedoch Mehrfachtreffer in die Zeilen geschrieben.
Kann man das ausschließen, oder gleiche Einträge in Zeilen löschen ?
Gruß Volker

Hi
probier mal das Makro hier:

Sub Test1()
Dim Arr
Dim ze As Long
Dim sp As Long
Dim i As Long
Sheets("Ergebnis").Cells.Clear
With Sheets("Daten")
'leere Spalte für Hilfsspalten finden
sp = .UsedRange.SpecialCells(xlCellTypeLastCell).Column + 2
'--- Doppelte Einträge eleminieren
.Range("A:B").AdvancedFilter xlFilterCopy, , .Cells(1, sp), True
'--- Erste Spalte ohne Duplikate erstellen
.Columns(sp).AdvancedFilter xlFilterCopy, , Sheets("Ergebnis").Cells(1, 1), True
'--- Werte ohne Duplikate in Array einlesen
Arr = Range(.Cells(2, sp), .Cells(Rows.Count, sp + 1).End(xlUp)).Value2
.Columns(sp).Resize(, 2).Clear
End With
'--- Ergebnis schreiben
With Sheets("Ergebnis")
For i = 1 To UBound(Arr, 1)
ze = .Columns(1).Find(what:=Arr(i, 1), lookat:=xlWhole).Row
.Cells(ze, .Columns.Count).End(xlToLeft).Offset(0, 1).Value = Arr(i, 2)
Next
End With
End Sub

Die Duplikate werden durch den Spezialfilter entfernt.
Gruß, Daniel

Hallo Daniel
Auch Dir vielen Dank, es läuft.
Schönen Sonntag noch.
Gruß Volker