Microsoft Excel

Herbers Excel/VBA-Archiv

Problemchen mit Summenprodukt-Formel

Betrifft: Problemchen mit Summenprodukt-Formel von: BEN10
Geschrieben am: 04.08.2014 09:51:15

Hallo,

in meiner Tabelle habe ich eine Summenprodukt-Formel eingefügt:

=SUMMENPRODUKT(TEILERGEBNIS(9;INDIREKT("X"&ZEILE(6:1401)))*(H$6:H$1401=$H1426))

Das "X" gibt ja an, dass die Werte aus Spalte X kommen, doch nun wollte ich die Formel nach rechts weiterkopieren und musste feststellen, dass sich das "X" beim kopieren nicht verändert.

Wie muss die Formel aussehen, damit sich der Bezug auf die Spalte beim kopieren mit verschiebt??

Also von X nach Y nach Z nach AA usw....

Wer weiß Rat....?

Gruß BEN

  

Betrifft: AW: Problemchen mit Summenprodukt-Formel von: Daniel
Geschrieben am: 04.08.2014 10:06:42

Hi

Probiere mal

INDIREKT("Z"&ZEILE(6:1401)&"S"&SPALTE(x1);Falsch)
In der z1S1-Schreibweise für Zelladressen sind auch die Spalten Nummern und damit einfacher zu berechnen.

Gruß Daniel


  

Betrifft: AW: Problemchen mit Summenprodukt-Formel von: BEN10
Geschrieben am: 04.08.2014 10:31:15

So sieht die Formel jetzt aus und auf den ersten Blick funktioniert sie auch:

=SUMMENPRODUKT(TEILERGEBNIS(9;INDIREKT("Z"&ZEILE($6:$1401)&"S"&SPALTE(Z1);FALSCH))*($H$6:$H$1401=$H1416))

Aber vielleicht mal zum Verständnis:

Warum kommt hier ein "S" in der Formel vor????


  

Betrifft: Syntax der Funktion in der Z1S1 Schreibweise ... von: neopa C (paneo)
Geschrieben am: 04.08.2014 10:51:57

Hallo Ben,

... erfordert dies so. Dazu siehe einfach die Onlinehilfe.

Gruß Werner
.. , - ...


  

Betrifft: AW: Problemchen mit Summenprodukt-Formel von: Daniel
Geschrieben am: 04.08.2014 10:55:38

Excel kennt zwei Schreibweisen für Zelladressen:
a) A1-Schreibweise mit Spaltenbuchstabe + Zeilennummer
b) Z1S1-Schreibweise: hier folgt nach dem "Z" die Zeilennummer und nach dem "S" die Spaltennummer

ich verwende hier die Z1S1-Schreibweise aus dem schon genannten grund.
Das erkennst du daran, dass in in der Indirekt-Funktion der zweite Parameter = FALSCH ist (über diesen zweiten Parameter zeigt man Excel an, welche der beiden Schreibweisen man verwendet, WAHR oder weggelassen steht für A1)

die Z1S1-Schreibweise hat für die Indirekt-Funktion den Vorteil, dass auch die Spalte eine Zahl ist und damit einfacher berechnet werden kann und dass man relative Zellbezüge damit darstellen kann.

Gruß Daniel


  

Betrifft: AW: Problemchen mit Summenprodukt-Formel von: BEN10
Geschrieben am: 04.08.2014 11:48:22

Aha, jetzt ist es schon ein wenig einleuchtender was ich da nun mache ^^

BESTEN DANK ! ! !

Gruß BEN


  

Betrifft: oder mittels ADRESSE() ... von: neopa C (paneo)
Geschrieben am: 04.08.2014 10:08:13

Hallo Ben,

...so: =SUMMENPRODUKT(TEILERGEBNIS(9;INDIREKT(WECHSELN(ADRESSE(1;SPALTE(X1);4);1;"")&ZEILE(6:1401)))*(I$6:I$1401=$H1426))

Gruß Werner
.. , - ...